China DOS Union

Four months ago, we discussed the method of randomly obtaining file names together and found that the best code is:
A question about randomly obtaining file names
The code from moderator Wunaihe on floor 24:

@echo off

if "%1" NEQ "$" (

        for /f "tokens=1,2 delims=:" %%a in ('"%~0" $^|sort') do @echo %%b

) else for /f "delims=" %%i in ('dir /b /a-d *.mp3') do @call :sub %%i

goto :EOF



:sub

echo %random%:%*

goto :EOF

And the codes modified by everyone later

Tonight, inspired by the "set ." special usage (sorting) from redtek on floor 15 in:

@echo off

setlocal EnableDelayedExpansion

for /f "delims=" %%i in ('dir/a-d/b *.mp3') do set $!random!!random!$%%i=$

for /f "tokens=1,2* delims=$=" %%i in ('set $') do echo %%j

pause

Brother, your code is concise and wonderful. I appreciate it.

Got up in the morning and thought of the application of call (without using delay variables ):

@echo off

for /f "delims=" %%i in ('dir/a-d/b *.mmf') do call set $%%random%%$%%i=$

for /f "tokens=1,2* delims=$=" %%i in ('set $') do echo %%j

pause

Haha... This call was played beautifully~ :)

Strong, the code above can be slightly modified to scan for specified (type) files on the hard drive and perform related operations. For example, some time ago when the Viking virus was encountered, a batch file could be created and placed in the C drive:

@echo off
for /f "delims=" %%i in ('dir /a/b/s desktop.ini') do call set $%%random%%$%%i=$
for /f "tokens=1,2* delims=$=" %%i in ('set $') do echo %%j >>c:\deleted_virus_files.txt
pause

This will find all _desktop.ini files and perform the deletion operation.

Originally posted by HUNRYBECKY at 2006-12-10 00:45:
Powerful, the code above can be slightly modified to scan for specified (type) files on the hard drive and perform related operations. For example, some time ago, the Viking virus was infected. You can create a batch file and place it in the C drive:
...

　　The main file of the Viking virus is _desktop.ini, and if you do this, all desktop.ini files under the C drive will be deleted, which may affect some system properties.