China DOS Union

Suddenly I want to use batch processing to sort numbers. Previously, we compared several numbers respectively and arranged them in order, but when the number of numbers is small, if the number exceeds 10, the code will be very lengthy and the efficiency is relatively low.

If batch processing had the concept of array types like high-level languages, it would be great, but unfortunately. In batch processing, manually constructing an array can solve this problem.

So I wrote the following code, which can sort N numbers in descending or ascending order. Just change "lss" or "gtr" in the IF statement.

@echo off



setlocal enabledelayedexpansion



set num=0



:input



set /a num+=1



cls



set /p num%num%=Please enter a group of numbers, terminate by directly pressing Enter :



if not "!num%num%!"=="" goto input



set /a num-=1



set /a num_=num-1



cls



echo Former sort:



for /l %%k in (1,1,%num%) do (



    set /p ii=!num%%k!  <nul



)



for /l %%i in (1,1,%num_%) do (



    set /a n=num-%%i



    for /l %%j in (1,1,!n!) do (



        set x=%%j



        set /a y=x+1



        call :go

    )

)



echo.



echo.



echo Sorted after:



for /l %%k in (1,1,%num%) do (



    set /p ii=!num%%k!  <nul



)



echo.



pause >nul



goto :eof



:go



if !num%x%! gtr !num%y%! (



    set i=!num%x%!



    set num%x%=!num%y%!



    set num%y%=!i!



)



goto :eof

Test code:

@echo off



setlocal enabledelayedexpansion



for /l %%l in (1,1,10) do (



    set t=%%l



    call :start



)



set /a num_=num-1



echo Former sort:



for /l %%k in (1,1,%num%) do (



    set /p ii=!num%%k!  <nul



)



for /l %%i in (1,1,%num_%) do (



    set /a n=num-%%i



    for /l %%j in (1,1,!n!) do (



        set x=%%j



        set /a y=x+1



        call :go

    )

)



echo.



echo.



echo Sorted after:



for /l %%k in (1,1,%num%) do (



    set /p ii=!num%%k!  <nul



)



echo.



pause >nul



goto :eof



:go



if !num%x%! lss !num%y%! (



    set i=!num%x%!



    set num%x%=!num%y%!



    set num%y%=!i!



)



goto :eof



:start



set j=!RANDOM:~0,1!



set num%t%=!RANDOM:~0,%j%!



set /a num+=1



goto :eof

[ Last edited by pengfei on 2006-11-15 at 06:54 AM ]

You can first determine the number of bits, which should be more efficient.

RE: vkill

The code not only has the function of judging the number of bits, but also has precise control over the number of times the loop runs, and the execution efficiency is relatively ideal.

[ Last edited by pengfei on 2006-11-20 at 08:48 AM ]

Nice

Let's take a look at the test code of our "genius" moderator (it seems like 37.....moderator):

@echo off
setlocal enabledelayedexpansion
set numbers=%random% %random% %random% %random% %random% %random% %random% %random%
echo The array before sorting is: %numbers%
call :sort %numbers%
echo The array after sorting is: %ret%
pause
goto :eof

:sort
set num=%1
set str=%*
for %%i in (%str%) do if !num! gtr %%i set num=%%i
set ret=%ret% %num%
if not "!str:%num%=!" == "" call :sort !str:%num%=!
goto :eof

Is it more efficient! For decimal/

The following is the "applied" code improved from the above code:
@echo off
color 1f
if "%1"=="" goto :instruction
setlocal enabledelayedexpansion
for %%i in (%1 %2 %3 %4 %5 %6 %7 %8 %9) do (
if not "%%i"=="" set number=!number! %%i)
call :sort %number%
echo.
echo The above numbers are in descending order as follows:
echo.
echo %str%
pause>nul

:instruction
cls
echo.
echo Number Sorting
echo.
echo ============================================================
echo Instructions:
echo This program can only be said to basically meet the requirements; no filtering of numbers;
echo Currently only supports sorting of up to 9 numbers!
echo.
echo Usage is as follows: [%~nx0] [%%1] [%%2] [%%3] [%%4] ........
echo =============================================================
echo.
cmd /k

:sort
set var=%1
set var_=%*
for %%i in (%var_%) do (
if !var! leq %%i set var=%%i)
set str=!str! !var!
set var_=!var_:%var%=!
if not "%var_%"=="" call :sort %var_%

Re youxi01:
To solve the limitation of 9 parameters, you can try using shift.
Of course, a better method is to replace the for statement under setlocal enabledelayedexpansion in your code with: set "number=%*"

After looking at the code of moderator 3742668, I am really impressed...

Obviously, this method of constructing an array by arranging numbers with spaces in between is simpler. Then, read each array element one by one through the for /f command for comparison.

Not only is it faster, but the code is also concise. I have learned something...