China DOS Union

set UDAY=0
for /L %%i in (1971,1,%YEAR%) do (
set /a temp1="%%i%%4"
::Remainder when divided by 4
set /a temp2="%%i%%100"
::Remainder when divided by 100
set /a temp3="%%i%%400"
::Remainder when divided by 400
if %temp1%==0 if not %temp2%==0 set /a UDAY="%UDAY%+366"&set TAG=r else if %temp3%==0 set /a UDAY="%UDAY%+366"&set TAG=r else set /a UDAY="%UDAY%+365"&set TAG=p)

::The code is to determine whether it is a leap year and accumulate days
It seems that the tempx is not calculated, and I can't figure it out. Great guys, please give me some pointers, thank you very much!

[ Last edited by hhl on 2006-11-1 at 10:32 PM ]

There is a problem with the use of variables in the `if` condition. In the `if` statement, when using variables like `%temp1%`, `%temp2%`, `%temp3%`, since it's in a loop, you should use delayed expansion. The corrected code should be like this (assuming delayed expansion is enabled):

```batch
@echo off
setlocal enabledelayedexpansion
set UDAY=0
set YEAR=2023
for /L %%i in (1971,1,%YEAR%) do (
set /a temp1=%%i%%4
::Remainder when divided by 4
set /a temp2=%%i%%100
::Remainder when divided by 100
set /a temp3=%%i%%400
::Remainder when divided by 400
if!temp1!==0 (
if not!temp2!==0 (set /a UDAY=!UDAY!+366&set TAG=r) else if!temp3!==0 (set /a UDAY=!UDAY!+366&set TAG=r) else (set /a UDAY=!UDAY!+365&set TAG=p))
else (set /a UDAY=!UDAY!+365&set TAG=p)
)
endlocal
```

The main issue was that without delayed expansion, the variables `temp1`, `temp2`, `temp3` couldn't get the correct values in the `if` condition during the loop iteration.

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set UDAY=0
for /L %%i in (1971,1,%YEAR%) do (
set/a temp1=%%i%%4
set/a temp2=%%i%%100
set/a temp3=%%i%%400
echo !temp1! !UDAY!
if !temp1!==0 if not !temp2!==0 (set /a UDAY=!UDAY!+366&set TAG=r) else (if !temp3!==0 (set /a UDAY=!UDAY!+366&set TAG=r) else (set /a UDAY=!UDAY!+365&set TAG=p)))

Ask the super moderator:

What does SETLOCAL ENABLEDELAYEDEXPANSION mean?

What does the echo !temp1! !UDAY! sentence mean?

Why do the tempx and UDAY variables need to be enclosed in !!?

Search the forum for "variable delay".

Originally posted by hhl at 2006-11-1 22:40:
Ask the super moderator:
What does SETLOCAL ENABLEDELAYEDEXPANSION mean?
What does the echo !temp1! !UDAY! mean?
Why do the tempx and UDAY variables need to be enclosed in !!?

The echo !temp1! !UDAY! is for debugging.
You can enter:
for/?
at the command line to know why the tempx and UDAY variables need to be enclosed in !!
But your code still has some problems, let's modify it again:

SETLOCAL ENABLEDELAYEDEXPANSION

set UDAY=0

set YEAR=2000

for /L %%i in (1971,1,%YEAR%) do (

set/a temp1=%%i%%4

set/a temp2=%%i%%100

set/a temp3=%%i%%400

if !temp1!==0 (if not !temp2!==0 (set /a UDAY=!UDAY!+366&set TAG=r) else (if !temp3!==0 (set /a UDAY=!UDAY!+366&set TAG=r) else (set /a UDAY=!UDAY!+365&set TAG=p))) else set /a UDAY=!UDAY!+365&set TAG=p)

[ Last edited by 不得不爱 on 2006-11-1 at 10:57 PM ]

Originally posted by hhl at 2006-11-1 22:25:
::Algorithm, copied from the C language book, a leap year is a year divisible by 4 but not by 100; a year divisible by 400 is also a leap year...

　　In my impression, as long as a year is divisible by 4, it is a leap year. Why is the algorithm in C so complicated and seems to be against the definition of a leap year?

Thanks, everyone upstairs, very grateful. Hehe, I'm a new CMD user, and I don't know many grammars and operators clearly.

Hehe, Moderator namejm, please refer to Tan Haoqiang's classic C book.

Originally posted by namejm at 2006-11-1 23:04:

In my impression, as long as the year is divisible by 4, it is a leap year. Why is the algorithm in C so complicated and seems a bit inconsistent with the definition of a leap year?

Haven't you studied the calendar?
Leap every 4 years
Leap less every 100 years
Leap more every 400 years
The reason is that each year is 365.2422 days

Hehe, I don't know much about the calendar. The concept of leap years even came from the math textbook in primary school. Please forgive me.

Haha, I didn't know that originally either. I just knew that those divisible by 4 are leap years. Now I know, thanks!

The conditions for determining a leap year are:
1. Divisible by 4 but not divisible by 100.
2. Divisible by 100 and also divisible by 400.

C language is really powerful, and the simplest way to determine a leap year is completed by logical operations. It's a pity that batch processing doesn't have such an operation type. I wonder if more complex CMD code can be used to simulate logical operations.

@echo off

set /p year=Please enter the year:

set /a x=%year%%%4

set /a y=%year%%%100

set /a z=%year%%%400

if %x%==0 (

    if %y%==0 (

        if %z%==0 (

            set term=1

        ) else (

            set term=0

        )

    ) else ( 

        set term=1

    )

) else (

    set term=0

)

if %term%==1 (

    echo %year% is a leap year.

) else (

    echo %year% is not a leap year.

)

pause

@echo off

SETLOCAL ENABLEDELAYEDEXPANSION

for /l %%i in (1971,1,2008) do (

    set /a x=%%i%%4

    set /a y=%%i%%100

    set /a z=%%i%%400

    if !x!==0 (

        if !y!==0 (

            if !z!==0 (

                set term=1

            ) else (

                set term=0

            )

        ) else ( 

            set term=1

        )

    ) else (

        set term=0

    )

    if !term!==1 (

        set /a uday+=366

    ) else (

        set /a uday+=365

    )

)

echo The total number of days from 1971 to 2008 is:%uday%

pause

[ Last edited by pengfei on 2006-11-2 at 04:26 AM ]

```@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
for /l %%i in (1971,1,2008) do (
set /a x=%%i%%4
set /a y=%%i%%100
set /a z=%%i%%400
if !x!==0 if !y!==0 (if !z!==0 set/a t+=1) else set/a t+=1)
set/a t=(2008-1971+1)*365+t
echo The total number of days from 1971 to 2008 is: %t%
pause
```