China DOS Union

The problem is like this. There is a text file with the following content:

/lib/AdaptiveMQ.jar
/lib/AdaptiveMQ.jar
/lib/FIX.jar

How can I put it into another file whose content is:

/lib/AdaptiveMQ.jar ;/lib/AdaptiveMQ.jar ;/lib/FIX.jar

These days I'm also compiling some batch scripts and have learned some simple ones.

@echo off
setlocal EnableDelayedExpansion
set N=1
for /f %%a in (original text.txt) do (set New!N!=%%a
set /a N=!N! + 1)

echo %New1% ;%New2% ;%New3%>new text.txt

Among them, %New1%～%NewN% increase incrementally according to the number of lines

If I don't know how many lines the original text has? What to do? Urgent, thanks.

```batch
@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in (原文件.txt) do (
if not defined a (set a=%%a) else (set a=!a!;%%a)
)
echo %a%>生成文件.txt
```

It can be determined that if the file length is too large, it will definitely not work, because there are certain requirements for the SET setting variable in cmd. Also, please ask the expert to think about how to write this batch processing... The owner can try the above code. If it doesn't work, it means the file length is too large

Let me know the result after the test is completed.

[ Last edited by bagpipe on 2006-7-19 at 15:07 ]

Hehe, bagpipe has made another move.

What does "defined" mean in the sentence "if not defined a (set a=%%a) else (set a=!a!;%%a)"? I'm seeing this usage for the first time. Can you explain this code?

Well, it's done. I haven't used DOS for a long time and have almost forgotten it all. Thanks for bagpipe's help.

Originally posted by namejm at 2006-7-19 15:05:
　　Hehe, bagpipe has made a move again.

　　What does "defined" mean in the sentence "if not defined a (set a=%%a) else (set a=!a!;%%a)"? I've never seen this usage before. Can you explain this code...

It means that if a is not defined, then execute set a=%%a. If it is defined, then execute the statement after else!

@echo off
setlocal EnableDelayedExpansion
set N=1
for /f "delims=" %%a in (original file.txt) do (set New!N!=%%a
set /a N=!N! + 1)
set /a N=%N%-1

echo echo %%New1%%>Temp.bat
if %N% LEQ 1 goto End
set M=2

:len
for /f "delims=" %%a in (Temp.bat) do set X=%%a
echo %X% ;%%New%M%%%^>new file.txt>Temp.bat
set /a M=%M%+1
if %M% GTR %N% goto End
goto len

:End
call Temp.bat
del Temp.bat

Tried with 400 lines and it was okay, but had an error with 500 lines. It seems like the for loop didn't continue. It didn't even execute to Temp.bat. The efficiency is worse than bagpipe's, but the SET variable setting isn't as large as bagpipe's
[ Last edited by zxcv on 2006-7-19 at 18:54 ]

In the practical application of batch processing, it is suggested not to use too many variables.

for /f "delims=" %i in (source file.txt) do @set /p "var=%i;" <nul >> target file.txt

Run it in the command prompt. If you want to write it into a script, change %i to %%i. There is no error handling for the situation where quotes appear in the text.

Still, the version of moderator 3742668 is powerful. The 500 lines of mine and bagpipe's hung up, but the 1200 lines of moderator 3742668 are still okay.

I didn't expect that SET /P can also continuously connect text content. I feel inferior..............

@sed -e :a -e "N;$!ba;s/ *\n/ ;/g;s/*$//" test.txt

Referenced the relevant code of Bamboo Wu Nai He and made modifications, applicable for over 3600 lines.

[ Last edited by amao on 2007-2-3 at 02:58 PM ]

```vbscript
set fso=createobject("scripting.filesystemobject")
set file=fso.opentextfile("a.txt")
do while file.atendofstream<>true
s=s & file.readline & " ;"
loop
file.close
set file=fso.createtextfile("b.txt")
file.write left(s,len(s)-1)
file.close
msgbox "Operation successful",4096
```