China DOS Union

Chinese translation see post 18 (Moderation by HAT @ 2009-01-04)

Originally at #27, corrected to #18 (Administrator note 2009-1-5)

This page shows how to read specific lines from a text file. There are many ways to have the for /f command read the input file, for instance:-

for /f "delims=" %%a in (input.txt) do ...

for /f "delims=" %%a in ('type input.txt') do ...

for /f "delims=" %%a in ('more ^< input.txt') do ...

However, only the last method (using the more command) will give consistent results across Windows NT, 2000, XP and 2003. The first method does not recognise unicode files. Also, the usebackq switch must be used if the input filename contains spaces. The second method, using the type command, also fails to recognise unicode files on Windows 2000, XP and 2003 if the input file does not begin with a bit order mark (BOM).

In all the examples, assume the contents of of the file numbers.txt to be:-

one
two
three
four
five
six
seven
eight
nine
ten

Displaying the first line

This example prints one.

@echo off & setlocal ENABLEEXTENSIONS
set "first="
for /f "delims=" %%a in ('more ^< numbers.txt') do (
if not defined first set first=%%a
)
echo/%first%

Displaying the first X lines

This example prints one, two and three.

@echo off & setlocal ENABLEEXTENSIONS
set "lines=3"
set i=-1
set "ok="
for /f "delims=" %%a in ('more ^< numbers.txt') do (
set/a i+=1 & for /f %%z in ('echo/%%i%%') do (
if "%%z"=="%lines%" set ok=1
)
if not defined ok echo/%%a
)

Displaying the last line

This example prints ten.

@echo off & setlocal ENABLEEXTENSIONS
for /f "delims=" %%a in ('more ^< numbers.txt') do set "last=%%a"
echo/%last%

Displaying the last X lines

This example prints nine and ten.

@echo off & setlocal ENABLEEXTENSIONS
set "lines=2"
for /f %%a in ('find/c /v "" ^< numbers.txt') do set/a skip=%%a-lines
for /f "delims=" %%a in ('more/e +%skip% ^< numbers.txt') do (
echo/%%a
)

Displaying the Nth line

This example prints three. Note that instead of using the more command's /e switch, the skip option could have been used with the for /f command, however, this fails is it is set to any number less than one.

@echo off & setlocal ENABLEEXTENSIONS
set LineNo=3
set "line="
set/a LineNo-=1
for /f "delims=" %%a in ('more/e +%LineNo% ^< numbers.txt') do (
if not defined line set "line=%%a"
)
echo/%line%

Displaying the Nth line plus X number of lines

This example prints five and six.

@echo off & setlocal ENABLEEXTENSIONS
set start=5
set "lines=2"
set/a i=-1,start-=1
set "ok="
for /f "delims=" %%a in ('more/e +%start% ^< numbers.txt') do (
set/a i+=1 & for /f %%z in ('echo/%%i%%') do (
if "%%z"=="%lines%" set ok=1
)
if not defined ok echo/%%a
)

对于我们这些新手来说太难了，如果有中文说明就好了。

（注：原句“对一我们新鸟来说太难,要是有中文说明就好了.”中“对一”应为“对于”的笔误，已按正确表述翻译）

Indeed, just like what the second floor said, it's too profound. I can't understand it.

Can the poster specifically explain?

There is no Chinese explanation, and I can only understand part of it.

The number of English words is not too many. If you don't know, you can check it with Baidu Dictionary. Also, if you don't know batch processing, you should mention which part you don't understand. That way it's easier to explain. If you can't understand the whole passage, then you may not be suitable for reading this article. You can take a look at this e-book in my signature. It should be helpful to you.

Too profound, can't understand it

It's pretty good. I really didn't notice before that the more command has so many parameters.

The usage of more is really powerful. In the future, there will be a pattern to follow when displaying the content of specified lines. Hehe, not bad, not bad.

A bit messy

Originally posted by namejm at 2006-7-27 05:51:
The usage of more is really powerful. In the future, there will be a pattern to apply when displaying the content of a specified line. Hehe, not bad not bad.

I feel the same way, extremely admiring~:)
Fun posts shouldn't sink~:)

Really confused, the path from ÷ in the signature is wrong

Great people, I admire them completely, but there are no Chinese explanations, and I'm completely confused! Alas, please experts guide us novices what kind of DOS technical books we should read!

Flood

[ Last edited by ccwan on 2007-1-20 at 09:24 PM ]

Let me explain