I worked overtime last night to improve the multiplication script. It can calculate integers and floating-point numbers, and works for all kinds of cases. Because it involves a large amount of digit-extraction operations, the efficiency isn't very high, so I'll optimize it properly when I have time.
Everyone is welcome to test it...
@echo off
if not %1*==* set M=%1 & set N=%2 & goto jmp
:input
cls
set M=
set N=
set /p M= input primary number :
set /p N=input number two number :
:jmp
set sign=
if "%M:~0,1%"=="-" (
if "%N:~0,1%"=="-" (
set M=%M:~1%
set N=%N:~1%
goto begin
)
)
if "%M:~0,1%"=="-" (
set M=%M:~1%
set sign=-
goto begin
)
if "%N:~0,1%"=="-" (
set N=%N:~1%
set sign=-
)
:begin
echo %M% | find "." >nul || set M=%M%.0
echo %N% | find "." >nul || set N=%N%.0
if "%M:~-1%"=="." set M=%M%0
if "%N:~-1%"=="." set N=%N%0
if "%M:~0,1%"=="." set M=0%M%
if "%N:~0,1%"=="." set N=0%N%
call :jerque "%M%"
call :jerque "%N%"
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=." %%i in ("%M%") do (
set X=%%i
set X_=%%j
)
for /f "tokens=1,2 delims=." %%i in ("%N%") do (
set Y=%%i
set Y_=%%j
)
call :front %X%
set X=%front_%
call :front %Y%
set Y=%front_%
call :rear %X_%
set X_=%rear_%
call :rear %Y_%
set Y_=%rear_%
call :count %X_%
set jlxs=%count_%
call :count %Y_%
set /a jlxs=%count_%+%jlxs%
set son=@%Y%%Y_%
set result=0
set append=
:boss
if not "%son:~-1%"=="@" (
set xx=!son:~-1!
set son=!son:~0,-1!
call :under
call :plus
set result=!ll!
set append=0!append!
goto boss
)
if "%jlxs%"=="0" goto end
set result=!result:~0,-%jlxs%!.!result:~-%jlxs%!
call :rear %result%
set result=%rear_%
if "%result:~-1%"=="." set result=%result:~0,-1%
if "%result:~0,1%"=="." set result=0%result%
:end
cls
echo ============
echo 运算结果^^^!
echo ============
echo.
echo.
echo %M%*%N%=%sign%%result%
pause >nul
exit
:plus
set weave=%single:~0,-1%%weave:~0,-1%
call :count %weave%%append%
set num1=%count_%
call :count %result%
set num2=%count_%
set /a num=%num1%-%num2%
call :join %num% %result%
set result=%join_%
set lx=@%weave%%append%
set ly=@%result%
set ln=0
set ll=
:plus_
set /a lz=%lx:~-1%+%ly:~-1%+%ln%
set/a ln=0%lz:~0,-1%
set ll=%lz:~-1%%ll%
set lx=%lx:~0,-1%
set ly=%ly:~0,-1%
if "%lx%"=="@" (
if "%ln%"=="1" (
set ll=1%ll%
goto :eof
) else (
goto :eof
)
)
goto plus_
:under
set father=@%X%%X_%
set single=0
set weave=
:under_
set note=%single:~0,-1%
if "%note%"=="" set note=0
set weave=%single:~-1%%weave%
if not "%father:~-1%"=="@" (
set yy=!father:~-1!
set /a yy=!yy!
set father=!father:~0,-1!
call :op
)
goto :eof
:op
set part=!xx!
set part_=!yy!
set /a single=%part%*%part_%+!note!
goto under_
:front
set front_=%1
:front1
if "%front_:~0,1%"=="0" (
set front_=%front_:~1%
goto front1
)
goto :eof
:rear
set rear_=%1
:rear1
if "!rear_:~-1!"=="0" (
set rear_=!rear_:~0,-1!
goto rear1
)
goto :eof
:count
set count2=%1@
set count_=0
:count1
if not "!count2:~0,1!"=="@" (
set /a count_+=1
set count2=!count2:~1!
goto count1
)
goto :eof
:join
set margin=%1
set join_=%2
:join1
if not "%margin%"=="0" (
set /a margin-=1
set join_=0!join_!
goto join1
)
goto :eof
:jerque
for /f "tokens=1* delims=." %%i in (%1) do (
echo %%i%%j|findstr "^*$">nul || goto error
)
goto :eof
:error
cls
echo ======================
echo 运算数不符合要求^^!
echo ======================
echo.
echo.
echo 请按任意键重新输入...
pause >nul
goto input
[
Last edited by pengfei on 2006-10-15 at 09:35 ]
Attachments
无限制乘法运算脚本.rar (1.25 KiB, Credits to download 1 pts, Downloads: 20)
DigestI
