China DOS Union

Originally posted by chainliq at 2006-11-19 19:07:
Hehe, I actually find this quite interesting. May I ask how to fix its display speed?

　　To modify its display speed, you can change the ping statement in the code. You can increase the value of the -n parameter or add the -w timeout parameter, depending on personal preference.

Good stuff. Download and test it.

lxmxn's post on floor 6 has a good code, but there are the following drawbacks:
1. Because the variable delay function is enabled, it will replace the exclamation marks in the text with empty;
2. Because the ordinary for statement ignores the lines starting with semicolons, this code will not be able to extract the content of these lines;
3. The :end in the if statement cannot be called as a label by other statements, that is, when the goto end part in other statements is executed, an error will occur and it cannot jump here;
4. The quotes in SET A="%1" are redundant, because when calling, %1 has been forcibly given quotes, so the sentence if "%A%"=="" goto end will never be executed;

Based on this code, the following code is obtained:

Version 1:

@echo off

:: Replace half-width double quotes with spaces, replace equal signs with 〓, compatible with other special characters

:: Can handle lines starting with semicolons, but will ignore blank lines

:: Can be compatible with unicode - formatted text

:: Display with a blank line between each line

for /f "delims= eol=" %%i in ('type %1') do (

    set "str=%%i"

    call set "str=%%str:"= %%"

    call :pickup

)

pause

goto :eof



:pickup

ping -n 1 127.1>nul

if "%str:~0,1%"=="=" set "str=〓%str:~1%"

set /p "=%str:~0,1%"<nul

set "str=%str:~1%"

if defined str goto pickup

echo.&echo.

goto :eof

Version 2:

@echo off

:: Several differences from version 1:

::　　 1. Cannot handle unicode text

:: 　　2. No longer forcibly add blank lines between each line, and can display blank lines as they are

for /f "delims= eol=" %%i in ('findstr /n .* %1') do (

    set "str=%%i"

    call set "str=%%str:"= %%"

    call set "str=%%str:*:=%%"

    call :pickup

)

echo.

pause

goto :eof



:pickup

if not defined str echo.&goto :eof

if "%str:~0,1%"=="=" set "str=〓%str:~1%"

set /p "=%str:~0,1%"<nul

ping -n 1 127.1>nul

set "str=%str:~1%"

if defined str goto pickup

echo.

goto :eof

[ Last edited by namejm on 2007 - 2 - 2 at 02:06 PM ]

It's really wonderful. Both lx and jm are all experts

Support

According to the discussion results of the post Maximize the original output of the specified line content containing special characters, the following code is obtained, which can perfectly solve the problem of original display of special characters. It is sent out for everyone to test:

@echo off



:: Read the text line by line and display the text content as it is

:: ① In order to display all the content of the text, the for+findstr sentence pattern is used

:: ② In order to be able to display the text as it is, variable delay is used and the delay is terminated at the appropriate position

:: ③ In order to correctly display quotes and equal signs, in the statement set /p= !str:~0,1!<nul, there is a space after the equal sign, and the backspace key is used



for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set "str=%%i"

    setlocal enabledelayedexpansion

    set str=!str:*:=!

    call :pickup

    endlocal

)

pause

goto :eof



:pickup

ping -n 1 127.1>nul

if defined str (

    set /p= !str:~0,1!<nul

    set str=!str:~1!

    goto pickup

)

echo.

goto :eof

Hehe... Everyone is a great person here.... I also need to study hard ing

How to input the backspace key, can anyone tell me, thank you!

Collected.. Indeed classic

After listening to the moderator's hint, I directly went to floor 21 for testing. What a great person!

All are experts! Give a thumbs up!

All are experts! Let's learn...

This really is pretty good!

Not bad

Great experts, we are extremely admiring. Collected...