China DOS Union

It's not encryption, but encoding/decoding. The method to transmit binary files with plain text—Base64

There are really many talented people, keep it up!

Bitwise operations reversed are indeed complicated.

Wonderful and great post, appreciate it~ :）

Must take a good look at the pick-up lines...
Haha!!

At this time there should not be ]==[0].

Post an example of encoding and decoding, which has great limitations. Because I don't know how to convert the decoded numbers back to the original characters. This example simply determines a few character numbers by looking up a table, and Chinese characters are not possible. Also, I don't know how to handle special characters, so there will be many errors when there are special characters (of course, when there are special characters).
If using echo when generating a file, it can reduce some errors when inputting special characters, but it still has to judge the two numbers 0D0A (carriage return and line feed), whatever.

::code by 0401



@echo off

setlocal

set ASCII= !"#$%%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ^_`abcdefghijklmnopqrstuvwxyz{|}~

setlocal enabledelayedexpansion

set B64CODE=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/=

set str=

set/p "str=Please enter the string to be encoded: "

if not defined str exit/b



call :enc

call :dec

exit/b



:enc

rem The two file names for comparison are:  

rem Put the string in a file for comparison (fc) and find the length of the string

set/p=%str%<nul>.str

for %%f in (.str) do set strlen=%%~zf

echo The length of the original string is: %strlen% bytes



rem Generate the file for fc to compare with the string

for /l %%l in (0,1,%strlen%) do >>.cmp set/p=　<nul



rem Store the 16进制 of the compared string into a variable

for /f "tokens=3" %%i in ('fc/b .cmp .str^|find "A1"') do (set strhex=!strhex!%%i)

del .cmp .str

echo The converted hexadecimal is: %strhex%



:encloop

if not defined strhex goto :encbreak

set chr1=0x!strhex:~0,2!

set chr2=0x!strhex:~2,2!

set chr3=0x!strhex:~4,2!

set strhex=%strhex:~6%

for %%i in (chr1 chr2 chr3) do if "!%%i!"=="0x" set %%i=0

set/a enc1=%chr1%">>"2

set/a enc2=((%chr1%"&"3)"<<"4)"|"(%chr2%">>"4)

set/a enc3=((%chr2%"&"15)"<<"2)"|"(%chr3%">>"6)

set/a enc4=%chr3%"&"63

::echo The shifted data: %enc1% %enc2% %enc3% %enc4%

if %chr3% equ 0 if %chr2% equ 0 (set enc4=64& set enc3=64) else (set enc4=64)

::echo The shifted data is encoded as:!B64CODE:~%enc1%,1!!B64CODE:~%enc2%,1!!B64CODE:~%enc3%,1!!B64CODE:~%enc4%,1!

set encstr=!encstr!!B64CODE:~%enc1%,1!!B64CODE:~%enc2%,1!!B64CODE:~%enc3%,1!!B64CODE:~%enc4%,1!

goto :encloop

:encbreak

echo The string  encoded data is 

goto :eof



:dec

rem And find the length of the encoded string

set/p=%encstr%<nul>.str

for %%f in (.str) do set strlen=%%~zf

echo The length of the encoded string is: %strlen% bytes

del .str



rem Find the number of offsets during encoding from the encoded string encstr

set str=

for /l %%l in (0,1,%strlen%) do (

	for /l %%m in (0,1,64) do (

		if "!encstr:~%%l,1!"=="!B64CODE:~%%m,1!" (

			set str=!str!/%%m

		)

	)

)

set a=1&set b=4



:decloop

if %strlen% equ 0 goto :decbreak

for /f "tokens=%a%-%b% delims=/" %%i in ("%str%") do set enc1=%%i&set enc2=%%j&set enc3=%%k&set enc4=%%l

::echo The offsets of the 4 bytes are respectively: %enc1% %enc2% %enc3% %enc4%

set/a a+=4&set/a b+=4

set/a strlen-=4

set/a chr1=((%enc1%"<<"2)"|"(%enc2%">>"4))-32

set/a chr2=(((%enc2%"&"15)"<<"4)"|"(%enc3%">>"2))-32

set/a chr3=(((%enc3%"&"3)"<<"6)"|"%enc4%)-32

::echo The decimal after decoding the 4 bytes and subtracting 32 is: %chr1% %chr2% %chr3%

if %enc4% equ 64 if %enc3% equ 64 (set chr3=107&set chr2=107) else (set chr3=107)

::echo The decoded data is:!ASCII:~%chr1%,1!!ASCII:~%chr2%,1!!ASCII:~%chr3%,1!

set decstr=!decstr!!ASCII:~%chr1%,1!!ASCII:~%chr2%,1!!ASCII:~%chr3%,1!

goto :decloop



:decbreak

echo The encoded data  decoded is 

goto :eof

Brother 0401 is very powerful, admired

Brother 0401, impressive

Learned.
I tried to modify the code of 0401, and used DEBUG to write the obtained hexadecimal results into a file.
Then the original characters can be obtained.

I also included another batch file for decimal to hexadecimal conversion for 0401.
There is a length limit for this decoding. I am not familiar with DEBUG.
This part of DEBUG is copied from redtek's batch file for QQ password to PwdHash.

::code by 0401



@echo off

setlocal

setlocal enabledelayedexpansion

set B64CODE=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/=

set str=

set/p "str=Please enter the string to be encoded: "

if not defined str exit/b



call :enc

call :dec

exit/b



:enc

rem The two comparison file names are:  

rem Put the string in the file for comparison (fc) and find the length of the string

set/p=%str%<nul>.str

for %%f in (.str) do set strlen=%%~zf

echo The original string length is: %strlen% bytes

set str_len=%strlen%



rem Generate the file for fc to compare with the string

for /l %%l in (0,1,%strlen%) do >>.cmp set/p=　<nul



rem Store the hexadecimal of the compared string into a variable

for /f "tokens=3" %%i in ('fc/b .cmp .str^|find "A1"') do (set strhex=!strhex!%%i)

del .cmp .str

echo The converted hexadecimal is: %strhex%



:encloop

if not defined strhex goto :encbreak

set chr1=0x!strhex:~0,2!

set chr2=0x!strhex:~2,2!

set chr3=0x!strhex:~4,2!

set strhex=%strhex:~6%

for %%i in (chr1 chr2 chr3) do if "!%%i!"=="0x" set %%i=0

set/a enc1=%chr1%">>"2

set/a enc2=((%chr1%"&"3)"<<"4)"|"(%chr2%">>"4)

set/a enc3=((%chr2%"&"15)"<<"2)"|"(%chr3%">>"6)

set/a enc4=%chr3%"&"63

::echo The data after shifting is: %enc1% %enc2% %enc3% %enc4%

if %chr3% equ 0 if %chr2% equ 0 (set enc4=64& set enc3=64) else (set enc4=64)

::echo The encoded data after shifting is:!B64CODE:~%enc1%,1!!B64CODE:~%enc2%,1!!B64CODE:~%enc3%,1!!B64CODE:~%enc4%,1!

set encstr=!encstr!!B64CODE:~%enc1%,1!!B64CODE:~%enc2%,1!!B64CODE:~%enc3%,1!!B64CODE:~%enc4%,1!

goto :encloop

:encbreak

echo The encoded data of the string  is 

goto :eof



:dec

rem And find the length of the encoded string

set/p=%encstr%<nul>.str

for %%f in (.str) do set strlen=%%~zf

echo The length of the encoded string is: %strlen% bytes

del .str



rem Find the number of offsets during encoding from the encoded string encstr

set str=

for /l %%l in (0,1,%strlen%) do (

        for /l %%m in (0,1,64) do (

                if "!encstr:~%%l,1!"=="!B64CODE:~%%m,1!" (

                        set str=!str!/%%m

                )

        )

)

set a=1&set b=4



:decloop

if %strlen% equ 0 goto :decbreak

for /f "tokens=%a%-%b% delims=/" %%i in ("%str%") do set enc1=%%i&set enc2=%%j&set enc3=%%k&set enc4=%%l

::echo The offsets of the 4 bytes are respectively: %enc1% %enc2% %enc3% %enc4%

set/a a+=4&set/a b+=4

set/a strlen-=4

set/a chr1=((%enc1%"<<"2)"|"(%enc2%">>"4))

set/a chr2=(((%enc2%"&"15)"<<"4)"|"(%enc3%">>"2))

set/a chr3=(((%enc3%"&"3)"<<"6)"|"%enc4%)

::echo The decimal obtained by decoding the 4 bytes and then subtracting 32 is: %chr1% %chr2% %chr3%

call :_d2h chr1 %chr1%

call :_d2h chr2 %chr2%

call :_d2h chr3 %chr3%

::echo The decimal obtained by decoding the 4 bytes and then subtracting 32 is: %chr1% %chr2% %chr3%

::if %enc4% equ 64 if %enc3% equ 64 (set chr3=107&set chr2=107) else (set chr3=107)

::echo The decoded data is:!ASCII:~%chr1%,1!!ASCII:~%chr2%,1!!ASCII:~%chr3%,1!

set decstr=!decstr! %chr1% %chr2% %chr3%

goto :decloop



:decbreak

pause

set /a str_len+=1

echo exit|%ComSpec%/kprompt e 100 $_%decstr%$_rcx$_%str_len%$_n tmp.tmp$_w$_q$_|debug>nul

chcp 936>nul

set/p=The decoded data of the encoded data  is:<nul

type tmp.tmp

del tmp.tmp>nul

echo.

pause

goto :eof



:_d2h

set hex=

set hexstr=0 1 2 3 4 5 6 7 8 9 A B C D E F

set d=0

for %%i in (%hexstr%) do (set d!d!=%%i&set/a d+=1)

set scanf=%2

set tscanf=

call :d2h

if not defined hex set hex=0

set %1=%hex%

goto :eof



:d2h

if %scanf% equ 0 goto :eof

set/a tscanf=%scanf%"&"15

set/a scanf">>="4

set hex=!d%tscanf%!!hex!

goto :d2h

Hehe, nice. The discussion has made progress again. But I'm also unfamiliar with Debug, it seems I need to catch up.

Post another relatively perfect one.
Next, modify this a bit more and it can be made into a tool for encoding/decoding specified files with BASE64.

The code can probably be further streamlined.

1. ::code by 0401
   
2. ::chenall modified on 2007.01.25
   
3. @echo off
   
4. setlocal
   
5. setlocal enabledelayedexpansion
   
6. set B64CODE=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/=
   
7. set str=
   
8. set/p "str=Please enter the string to be encoded: "
   
9. if not defined str exit/b
   
10. 
    
11. call :enc
    
12. call :dec
    
13. exit/b
    
14. 
    
15. :enc
    
16. rem The two file names for comparison are:
    
17. rem Put the string in a file for comparison (fc) and find the length of the string
    
18. set/p=%str%<nul>.str
    
19. for %%f in (.str) do set strlen=%%~zf
    
20. echo The length of the original string is: %strlen% bytes
    
21. set str_len=%strlen%
    
22. 
    
23. rem Generate the file for fc to compare with the string
    
24. del _*.cmp 2>nul
    
25. for /l %%l in (1,1,%strlen%) do (
    
26. >>_a.cmp set/p=a<nul
    
27. >>_b.cmp set/p=b<nul
    
28. )
    
29. fc/b _a.cmp .str|find ":">tmp.str
    
30. fc/b _b.cmp .str|find ":">>tmp.str
    
31. sort tmp.str>_a.cmp
    
32. 
    
33. rem Store the 16 - bit hexadecimal of the compared string into a variable
    
34. for /f "tokens=1,3" %%i in (_a.cmp) do (
    
35. if not "!n!"=="%%i" set strhex=!strhex!%%j
    
36. set n=%%i
    
37. )
    
38. ::for /f "tokens=3" %%i in ('fc/b .cmp .str^|find ":"') do (set strhex=!strhex!%%i)
    
39. del *.cmp *.str 2>nul
    
40. echo The converted hexadecimal is: %strhex%
    
41. 
    
42. :encloop
    
43. if not defined strhex goto :encbreak
    
44. set chr1=0x!strhex:~0,2!
    
45. set chr2=0x!strhex:~2,2!
    
46. set chr3=0x!strhex:~4,2!
    
47. set strhex=%strhex:~6%
    
48. for %%i in (chr1 chr2 chr3) do if "!%%i!"=="0x" set %%i=0
    
49. set/a enc1=%chr1%">>"2
    
50. set/a enc2=((%chr1%"&"3)"<<"4)"|"(%chr2%">>"4)
    
51. set/a enc3=((%chr2%"&"15)"<<"2)"|"(%chr3%">>"6)
    
52. set/a enc4=%chr3%"&"63
    
53. ::echo The data after shifting is: %enc1% %enc2% %enc3% %enc4%
    
54. if %chr3% equ 0 if %chr2% equ 0 (set enc4=64& set enc3=64) else (set enc4=64)
    
55. ::echo The encoded data after shifting is:!B64CODE:~%enc1%,1!!B64CODE:~%enc2%,1!!B64CODE:~%enc3%,1!!B64CODE:~%enc4%,1!
    
56. set encstr=!encstr!!B64CODE:~%enc1%,1!!B64CODE:~%enc2%,1!!B64CODE:~%enc3%,1!!B64CODE:~%enc4%,1!
    
57. ::for %%i in (enc1 enc2 enc3 enc4) do (
    
58. :: if !%%i! lss 10 (set/p=0!%%i!<nul>>tmp.bb) else (set/p=!%%i!<nul>>tmp.bb)
    
59. ::)
    
60. goto :encloop
    
61. :encbreak
    
62. echo The encoded data of the string [%str%] is [%encstr%]
    
63. ::echo 字符串编码后的数据为 >>tmp.aa
    
64. goto :eof
    
65. 
    
66. :dec
    
67. rem And find the length of the encoded string
    
68. set/p=%encstr%<nul>.str
    
69. for %%f in (.str) do set strlen=%%~zf
    
70. echo The length of the encoded string is: %strlen% bytes
    
71. del .str
    
72. 
    
73. rem Find the number of offsets during encoding from the encoded string encstr
    
74. set str=
    
75. for /l %%l in (0,1,%strlen%) do (
    
76. for /l %%m in (0,1,64) do (
    
77. if "!encstr:~%%l,1!"=="!B64CODE:~%%m,1!" (
    
78. if %%m lss 10 (
    
79. set str=!str!0%%m
    
80. ) else (
    
81. set str=!str!%%m
    
82. )
    
83. )
    
84. )
    
85. )
    
86. set a=1&set b=4&set e=0
    
87. del debug.src 2>nul
    
88. 
    
89. :decloop
    
90. if not defined str goto :decbreak
    
91. set /a enc1=1!str:~0,2!-100
    
92. set /a enc2=1!str:~2,2!-100
    
93. set /a enc3=1!str:~4,2!-100
    
94. set /a enc4=1!str:~6,2!-100
    
95. set str=%str:~8%
    
96. for %%i in (enc1 enc2 enc3 enc3 enc4) do (
    
97. if !%%i! leq 0 set %%i=0
    
98. if !%%i! equ 64 set %%i=0
    
99. )
    
100. ::echo The offsets of the 4 bytes are respectively: %enc1% %enc2% %enc3% %enc4%
     
101. set/a chr1=((%enc1%"<<"2)"|"(%enc2%">>"4))
     
102. set/a chr2=(((%enc2%"&"15)"<<"4)"|"(%enc3%">>"2))
     
103. set/a chr3=(((%enc3%"&"3)"<<"6)"|"%enc4%)
     
104. ::echo The decimal obtained by subtracting 32 from the 4 bytes after decoding is: %chr1% %chr2% %chr3%
     
105. call :_d2h chr1 %chr1%
     
106. call :_d2h chr2 %chr2%
     
107. call :_d2h chr3 %chr3%
     
108. ::echo The hexadecimal obtained by subtracting 32 from the 4 bytes after decoding is: %chr1% %chr2% %chr3%
     
109. ::echo The decoded data is:!ASCII:~%chr1%,1!!ASCII:~%chr2%,1!!ASCII:~%chr3%,1!
     
110. set /a ee=0x100+3*e
     
111. call :_d2h ee %ee%
     
112. >>debug.src echo e %ee% %chr1% %chr2% %chr3%
     
113. ::set/p=%chr1%%chr2%%chr3%<NUL >>BB.TXT
     
114. set /a e+=1
     
115. goto :decloop
     
116. 
     
117. :decbreak
     
118. pause
     
119. set /a str_len+=1
     
120. >>debug.src echo rcx
     
121. >>debug.src echo %str_len%
     
122. >>debug.src echo n tmp.tmp
     
123. >>debug.src echo w
     
124. >>debug.src echo q
     
125. debug<debug.src
     
126. del debug.src
     
127. chcp 936>nul
     
128. echo The encoded data [%encstr%]
     
129. echo.
     
130. set/p=Decoded as:<nul
     
131. type tmp.tmp
     
132. del tmp.tmp>nul
     
133. echo.
     
134. pause
     
135. goto :eof
     
136. 
     
137. :_d2h
     
138. set hex=
     
139. set hexstr=0 1 2 3 4 5 6 7 8 9 A B C D E F
     
140. set d=0
     
141. for %%i in (%hexstr%) do (set d!d!=%%i&set/a d+=1)
     
142. set scanf=%2
     
143. set tscanf=
     
144. call :d2h
     
145. if not defined hex set hex=0
     
146. set %1=%hex%
     
147. goto :eof
     
148. 
     
149. :d2h
     
150. if %scanf% equ 0 goto :eof
     
151. set/a tscanf=%scanf%"&"15
     
152. set/a scanf">>="4
     
153. set hex=!d%tscanf%!!hex!
     
154. goto :d2h
     

chenall posted on: 2007-01-25 15:35

[ Last edited by chenall on 2007-1-26 at 04:37 AM ]

To brother chenall:

Indeed, a BASE64 encoding/decoding tool can already be written. I also have this plan, but I don't know if there will be time available. Hehe.

By the way, brother, in order to use fc to compare files, you used the fsutil file createnew command to create an equally sized file. But in this way, fsutil can only be used by members of the administrator group, which reduces the applicability to some extent. Why not try the method in floor 5, or use the f sub-command of debug to fill an equally sized file with all binary 0s.

-------------------------------------------------
Supplementary: If you use the f sub-command to fill, you also need to fill two files with different contents, because if you are dealing with a single file, it is not guaranteed that you will not encounter bytes with binary 0.

[ Last edited by 0401 on 2007-1-28 at 01:09 PM ]

The code has been modified by referring to the code on floor 5.