中国DOS联盟

@ECHO OFF

:TOP

SETLOCAL ENABLEDELAYEDEXPANSION

SET A_X=9

SET B_Y=9

SET C_Z=9

SET BOOT=1

SET BASE=%RANDOM%

CALL :CRY

IF NOT "%CRY%" == "" SET BOOT=0&&CALL :IN

SET DIC=abcdefghijklmnopqrstuvwxyz0123456789@ABCDEFGHIJKLMNOPQRSTUVWXYZ



CALL :LOS %DIC%

SET DL=%LOS%&&SET /A IDE=%LOS%%%9

IF %LOS% GTR 120 CLS&&ECHO 字典超长....&&GOTO END

IF NOT "%IDE%" == "0" ECHO 字典设置错误&&GOTO END

:inp

IF "%BOOT%" == "1" (

SET MSG0=开始创建新密码...&&SET MSG=请输入新密码&&SET MSG9=密码创建中.

) ELSE SET MSG0=本文档存在密码保护...&&SET MSG=请输入&&SET MSG9=密码验证中.

ECHO.

ECHO   密码字典为(密码长度不能超过40位，字典长度不超过120位):&&ECHO   %DIC%

ECHO   对大小字敏感，不能设置除字典外的字符或空格&&ECHO.

ECHO %MSG0%

:inp1

SET /P PWS="%MSG% PWS:>"

ECHO %PWS%|findstr /r "">nul&&GOTO INP

IF "%BOOT%" == "1" (

SET /P FWS="再输入一次 PWS:>"

IF NOT "%PWS%" == "!FWS!" (

SET MSG=两次输入不同 请输入新密码

GOTO INP1)

)

SET/P=%MSG9%<nul

CALL :LOS %PWS%

SET PL=%LOS%&&IF %LOS% GTR 40 ECHO 密码长度不能越过40&&pause&&CLS&&GOTO TOP

SET NPL=%PL%



:calc

IF %NPL% GEQ %DL% SET /A NPL=%NPL%-%DL%&&GOTO CAL

SET /A HPL=%DL%-%NPL%

CALL :CONVERSE 0 %NPL% %NPL% %HPL%

CALL :CONVERSE -%NPL% %NPL% 0 -%NPL%



SET /A HDL=(%DL%-%DL%%%2)/2

SET ADL=!NDIC:~0,%HDL%!&&SET BDL=!NDIC:~%HDL%!&&SET NDIC=

FOR /L %%i IN (0,1,%HDL%) DO SET NDIC=!NDIC!!BDL:~%%i,1!!ADL:~%%i,1!



FOR /L %%z IN (0,1,%C_Z%) DO (

    FOR /L %%y IN (0,1,%B_Y%) DO (

        FOR /L %%x IN (0,1,%A_X%) DO (

        SET /a WD=1%%x%%y%%z%%%DL%

        CALL :TEXT !WD!

        SET _d_%%x%%y%%z=!TEXT!)

)

SET/P=.<nul)

::set _d_>1.txt&&goto chk





:create

FOR /L %%i IN (0,1,%NNPL%) DO (

FOR /F "tokens=2,3 delims=_=" %%a IN ('SET _d_^|find "=!PWS:~%%i,1!"') DO (

SET /A FF=!FF!+1

SET S!FF!=%%a

)

SET /A CF=%BASE%%%!FF!+1

CALL :OUT !CF!

SET/P=.<nul)

SET NCRY=%BASE%-%JG%

IF "%BOOT%" == "1" (

ECHO.>>"%~dpnx0"&&ECHO SET CRY=%NCRY%>>"%~dpnx0"

ECHO 密码设置成功

GOTO END

) ELSE  IF "%NCRY%" == "%BASE%-%CRY%" (

ECHO 验证成功&&GOTO NEXT

) ELSE (

ECHO 密码错误&&pause&&GOTO ENDSET)



GOTO END

:los

SET STR=%1

FOR /L %%i IN (0,1,128) DO if "!STR:~%%i,1!" == "" SET LOS=%%i&&GOTO :EOF

GOTO :EOF



:text

SET TEXT=!NDIC:~%1,1!

GOTO :EOF



:converse

SET /A NNPL=%NPL%-1

SET _tmp2=

SET _tmp1=!DIC:~%1,%2!

FOR /L %%i IN (%NNPL%,-1,0) DO SET _tmp2=!_tmp2!!_tmp1:~%%i,1!

SET NDIC=%_tmp2%!DIC:~%3,%4!

GOTO :EOF



:out

SET JG=!JG!!S%1!&&SET FF=

GOTO :EOF



:in

FOR /F "tokens=1,2 delims=-" %%i IN ("%CRY%") DO SET BASE=%%i&&SET CRY=%%j

CALL :LOS %CRY%

SET HCRY=%LOS%&&SET /A CHK=%LOS%%%3

IF NOT "%CHK%" == "0" ECHO 密文被破坏！&&GOTO END

GOTO :EOF



:endset

ENDLOCAL&cls

GOTO TOP



:next

ECHO OK..

GOTO END



:chk

::check label:calc matrix

for /l %%j in (0,1,62) do (

set /a sh=0

for /f "tokens=2 delims==" %%i in (1.txt) do (

if "!DIC:~%%j,1!" == "%%i" set /a sh=!sh!+1)

echo !DIC:~%%j,1! !sh! >>sh.txt)



:end

rem copyright:12232-530502-12000-046006035061035000002030034

PAUSE>nul

EXIT



:cry

::SET /A NDL=%DL%-1

::FOR /L %%i IN (0,1,%NDL%) DO ECHO %PWS%|find "!NDIC:~%%i,1!">nul&&SET BIY=!BIY!!NDIC:~%%i,1!

SET CRY=7304-552511527557551535939937543939547

### Reference Materials
Batch Code for Calculating String Length to Check for Errors

Hehe, see who can figure out the password. The last line is the password. You can delete this line and then execute it to create your own password.

@ECHO OFF

:TOP

SETLOCAL ENABLEDELAYEDEXPANSION

SET A_X=9

SET B_Y=9

SET C_Z=9

SET BOOT=1

SET BASE=%RANDOM%

CALL :CRY

IF NOT "%CRY%" == "" SET BOOT=0&&CALL :IN

SET DIC=abcdefghijklmnopqrstuvwxyz0123456789@ABCDEFGHIJKLMNOPQRSTUVWXYZ



CALL :LOS %DIC%

SET DL=%LOS%&&SET /A IDE=%LOS%%%9

IF %LOS% GTR 120 CLS&&ECHO Dictionary too long....&&GOTO END

IF NOT "%IDE%" == "0" ECHO Dictionary setting error&&GOTO END

:inp

IF "%BOOT%" == "1" (

SET MSG0=Start creating new password...&&SET MSG=Please enter new password&&SET MSG9=Creating password.

) ELSE SET MSG0=This document has password protection...&&SET MSG=Please enter&&SET MSG9=Verifying password.

ECHO.

ECHO   Password dictionary (password length cannot exceed 40 characters, dictionary length not exceed 120 characters):&&ECHO   %DIC%

ECHO   Case-sensitive, cannot set characters or spaces other than in the dictionary&&ECHO.

ECHO %MSG0%

:inp1

SET /P PWS="%MSG% PWS:>"

ECHO %PWS%|findstr /r "">nul&&GOTO INP

IF "%BOOT%" == "1" (

SET /P FWS="Enter again PWS:>"

IF NOT "%PWS%" == "!FWS!" (

SET MSG=The two entries are different. Please enter new password

GOTO INP1)

)

SET/P=%MSG9%<nul

CALL :LOS %PWS%

SET PL=%LOS%&&IF %LOS% GTR 40 ECHO Password length cannot exceed 40&&pause&&CLS&&GOTO TOP

SET NPL=%PL%



:calc

IF %NPL% GEQ %DL% SET /A NPL=%NPL%-%DL%&&GOTO CAL

SET /A HPL=%DL%-%NPL%

CALL :CONVERSE 0 %NPL% %NPL% %HPL%

CALL :CONVERSE -%NPL% %NPL% 0 -%NPL%



SET /A HDL=(%DL%-%DL%%%2)/2

SET ADL=!NDIC:~0,%HDL%!&&SET BDL=!NDIC:~%HDL%!&&SET NDIC=

FOR /L %%i IN (0,1,%HDL%) DO SET NDIC=!NDIC!!BDL:~%%i,1!!ADL:~%%i,1!



FOR /L %%z IN (0,1,%C_Z%) DO (

    FOR /L %%y IN (0,1,%B_Y%) DO (

        FOR /L %%x IN (0,1,%A_X%) DO (

        SET /a WD=1%%x%%y%%z%%%DL%

        CALL :TEXT !WD!

        SET _d_%%x%%y%%z=!TEXT!)

)

SET/P=.<nul)

::set _d_>1.txt&&goto chk





:create

FOR /L %%i IN (0,1,%NNPL%) DO (

FOR /F "tokens=2,3 delims=_=" %%a IN ('SET _d_^|find "=!PWS:~%%i,1!"') DO (

SET /A FF=!FF!+1

SET S!FF!=%%a

)

SET /A CF=%BASE%%%!FF!+1

CALL :OUT !CF!

SET/P=.<nul)

SET NCRY=%BASE%-%JG%

IF "%BOOT%" == "1" (

ECHO.>>"%~dpnx0"&&ECHO SET CRY=%NCRY%>>"%~dpnx0"

ECHO Password set successfully

GOTO END

) ELSE  IF "%NCRY%" == "%BASE%-%CRY%" (

ECHO Verification successful&&GOTO NEXT

) ELSE (

ECHO Password error&&pause&&GOTO ENDSET)



GOTO END

:los

SET STR=%1

FOR /L %%i IN (0,1,128) DO if "!STR:~%%i,1!" == "" SET LOS=%%i&&GOTO :EOF

GOTO :EOF



:text

SET TEXT=!NDIC:~%1,1!

GOTO :EOF



:converse

SET /A NNPL=%NPL%-1

SET _tmp2=

SET _tmp1=!DIC:~%1,%2!

FOR /L %%i IN (%NNPL%,-1,0) DO SET _tmp2=!_tmp2!!_tmp1:~%%i,1!

SET NDIC=%_tmp2%!DIC:~%3,%4!

GOTO :EOF



:out

SET JG=!JG!!S%1!&&SET FF=

GOTO :EOF



:in

FOR /F "tokens=1,2 delims=-" %%i IN ("%CRY%") DO SET BASE=%%i&&SET CRY=%%j

CALL :LOS %CRY%

SET HCRY=%LOS%&&SET /A CHK=%LOS%%%3

IF NOT "%CHK%" == "0" ECHO Ciphertext damaged！&&GOTO END

GOTO :EOF



:endset

ENDLOCAL&cls

GOTO TOP



:next

ECHO OK..

GOTO END



:chk

::check label:calc matrix

for /l %%j in (0,1,62) do (

set /a sh=0

for /f "tokens=2 delims==" %%i in (1.txt) do (

if "!DIC:~%%j,1!" == "%%i" set /a sh=!sh!+1)

echo !DIC:~%%j,1! !sh! >>sh.txt)



:end

rem copyright:12232-530502-12000-046006035061035000002030034

PAUSE>nul

EXIT



:cry

::SET /A NDL=%DL%-1

::FOR /L %%i IN (0,1,%NDL%) DO ECHO %PWS%|find "!NDIC:~%%i,1!">nul&&SET BIY=!BIY!!NDIC:~%%i,1!

SET CRY=7304-552511527557551535939937543939547

Last edited by everest79 on 2006-12-31 at 05:06 AM ]

%RANDOM%
How is it possible to be reversed calculated???

Is it reverse enumeration????

Originally posted by tghksj at 2006-12-31 03:28 PM:
%RANDOM%
How is it possible to be reversed?

Is it reverse enumeration?????

When the password exists, the assigned %random% is replaced. Take a closer look at the IN section

Originally posted by Michale at 2006-12-31 04:04 PM:
Let's try~~

Come on, this password can indeed be calculated by a very simple method
Because of the calculation time issue, I deleted one part of the encryption, otherwise it would take a lot of time

DOSlianmeng

The password is

DOSlianmeng

The biggest loophole in this encryption is that the password length is the key to calculation. As long as you enumerate password lengths from 1 to 40, you can obtain the encryption matrix, then reverse look up the ciphertext, and divide it into segments of three characters each to get the password.

The theoretical value is very high, but the practical value is not high.

Batch processing code is very easy to be modified, so it is not suitable for use as a password verification program.

It can indeed be used for text encryption, but the efficiency is worrying.

Moreover, the fact that this algorithm does not require a key for decryption also reduces security.

Last edited by qzwqzw on 2007-1-1 at 12:56 PM ]

Originally posted by qzwqzw at 2007-1-1 12:47 PM:
Theoretical value is very high, but practical value is not high

Batch processing code is easy to be modified, so it is not suitable for use as a password verification program

It can be used for text encryption, but the efficiency is worrying

And this calculation ...

These days I've been thinking about how this encryption can perform deep calculations without taking a long time. I post it just hoping everyone can have their own opinions. The envisioned application object is to encrypt the batch processing itself. Actually, it can't be regarded as real encryption because it's impossible to achieve the one-into-three integration of encryption standards. It's just setting an additional hurdle, increasing a bit of difficulty while adding more fun at the same time

@echo off

SETLOCAL ENABLEDELAYEDEXPANSION

SET A_X=9

SET B_Y=9

SET C_Z=9

SET DIC=abcdefghijklmnopqrstuvwxyz0123456789@ABCDEFGHIJKLMNOPQRSTUVWXYZ

set error=    密文格式错误。

CALL :LOS %DIC%

SET DL=%LOS%

cls

:TOP



set NCRY=

set/p NCRY=请输入密文：

if not defined NCRY goto :top

for /f "tokens=1,2 delims=-" %%i in ("%NCRY%") do set BASE=%%i&set JG=%%j

if not defined BASE echo %error% & goto :top

if not defined JG echo %error% & goto :top

call :los %JG%

set/a NPL=%LOS%/3

set/a MPL=%LOS%%%3

if not %MPL%==0 echo %error% & goto :top



SET /A HPL=%DL%-%NPL%

CALL :CONVERSE -%NPL% %NPL% 0 -%NPL%



SET /A HDL=(%DL%-%DL%%%2)/2

SET ADL=!NDIC:~0,%HDL%!&&SET BDL=!NDIC:~%HDL%!&&SET NDIC=

FOR /L %%i IN (0,1,%HDL%) DO SET NDIC=!NDIC!!BDL:~%%i,1!!ADL:~%%i,1!



FOR /L %%z IN (0,1,%C_Z%) DO (

    FOR /L %%y IN (0,1,%B_Y%) DO (

        FOR /L %%x IN (0,1,%A_X%) DO (

        SET /a WD=1%%x%%y%%z%%%DL%

        CALL :TEXT !WD!

        SET _d_%%x%%y%%z=!TEXT!)

)

SET/P=.<nul)



set /a enpl=nnpl*3



echo.密码为：

for /l %%i in (0,3,!enpl!) do (

	for /f "tokens=2 delims==" %%j in ('set _d_^|find "!JG:~%%i,3!"') do (

		set/p=%%j<nul

	)

)

echo. & pause>nul

EXIT/B





:converse

SET /A NNPL=%NPL%-1

SET _tmp2=

SET _tmp1=!DIC:~%1,%2!

FOR /L %%i IN (%NNPL%,-1,0) DO SET _tmp2=!_tmp2!!_tmp1:~%%i,1!

SET NDIC=%_tmp2%!DIC:~%3,%4!

GOTO :EOF



:text

SET TEXT=!NDIC:~%1,1!

GOTO :EOF



:los

SET STR=%1

FOR /L %%i IN (0,1,128) DO if "!STR:~%%i,1!" == "" SET LOS=%%i&&GOTO :EOF

GOTO :EOF

Decryption P processing. Directly copied from the building block code of the original poster.

@echo off

SETLOCAL ENABLEDELAYEDEXPANSION

SET A_X=9

SET B_Y=9

SET C_Z=9

SET DIC=abcdefghijklmnopqrstuvwxyz0123456789@ABCDEFGHIJKLMNOPQRSTUVWXYZ

set error=    Incorrect ciphertext format.

CALL :LOS %DIC%

SET DL=%LOS%

cls

:TOP



set NCRY=

set/p NCRY=Please enter ciphertext:

if not defined NCRY goto :top

for /f "tokens=1,2 delims=-" %%i in ("%NCRY%") do set BASE=%%i&set JG=%%j

if not defined BASE echo %error% & goto :top

if not defined JG echo %error% & goto :top

call :los %JG%

set/a NPL=%LOS%/3

set/a MPL=%LOS%%%3

if not %MPL%==0 echo %error% & goto :top



SET /A HPL=%DL%-%NPL%

CALL :CONVERSE -%NPL% %NPL% 0 -%NPL%



SET /A HDL=(%DL%-%DL%%%2)/2

SET ADL=!NDIC:~0,%HDL%!&&SET BDL=!NDIC:~%HDL%!&&SET NDIC=

FOR /L %%i IN (0,1,%HDL%) DO SET NDIC=!NDIC!!BDL:~%%i,1!!ADL:~%%i,1!



FOR /L %%z IN (0,1,%C_Z%) DO (

    FOR /L %%y IN (0,1,%B_Y%) DO (

        FOR /L %%x IN (0,1,%A_X%) DO (

        SET /a WD=1%%x%%y%%z%%%DL%

        CALL :TEXT !WD!

        SET _d_%%x%%y%%z=!TEXT!)

)

SET/P=.<nul)



set /a enpl=nnpl*3



echo.Password is:

for /l %%i in (0,3,!enpl!) do (

	for /f "tokens=2 delims==" %%j in ('set _d_^|find "!JG:~%%i,3!"') do (

		set/p=%%j<nul

	)

)

echo. & pause>nul

EXIT/B





:converse

SET /A NNPL=%NPL%-1

SET _tmp2=

SET _tmp1=!DIC:~%1,%2!

FOR /L %%i IN (%NNPL%,-1,0) DO SET _tmp2=!_tmp2!!_tmp1:~%%i,1!

SET NDIC=%_tmp2%!DIC:~%3,%4!

GOTO :EOF



:text

SET TEXT=!NDIC:~%1,1!

GOTO :EOF



:los

SET STR=%1

FOR /L %%i IN (0,1,128) DO if "!STR:~%%i,1!" == "" SET LOS=%%i&&GOTO :EOF

GOTO :EOF

Last edited by 0401 on 2007-1-3 at 08:27 AM ]

Originally posted by everest79 at 2007-1-1 23:16:

Come on, this password can indeed be calculated through a very simple method
Because of the calculation time issue, I deleted one part of the encryption, otherwise it would take a lot of time

Can the owner of the post post the complete version?