中国DOS联盟

@echo off
for /f "tokens=1-5 delims=._" %%a in ('dir /b *.jpg') do (call :111 %%a %%b %%c %%d %%e)
ren *.jpp *.jpg
pause
exit
:111
set d=%4
set e=%5
:222
if %d:~0,1%==0 (set d=%d:~1% &goto 222)
set /a d+=1
set d=000000%d%
set d=%d:~-6%
:333
if %e:~0,1%==0 (set e=%e:~1% &goto 333)
set /a e+=1
set e=0000%e%
set e=%e:~-4%
ren %1_%2_%3_%4_%5.jpg %1_%2_%3_%d%_%e%.jpp

按照那种格式在我的电脑上试了一下可以的用我的代码

@echo off&&setlocal enabledelayedexpansion
for /f "delims=_. tokens=4,5" %%b in ('dir /b') do (
set x=%%b
set y=%%c
set /a x+=1
set /a y+=1
ren *%%b_%%c.jpg *!x!_!y!.jpg
)

严重感谢33楼 以及所有为此给予帮助,给予代码,给予提示的大侠们,再次谢谢你们了,问题解决了!!!

高兴中~~~~~~

不知什么时候我才能达到这种水准!! ~~~~

abcd的代码我更是看不懂了,连路径放哪都不知道了,完全摸不着门了~~~

我看变更3楼的就可以解决0开头问题
@echo off
for /f "delims=" %%i in ('dir /b /a-d D:\A\*.jpg') do (
for /f "delims=_. tokens=1-5" %%a in ("%%i") do (
set x=%%d
set y=%%e
call set/a x=1%%x%%+1
call set/a y=1%%Y%%+1
call set x=%%x:~1%%
call set y=%%y:~1%%
call ren "%%i" "%%a_%%b_%%c_%%x%%_%%y%%.jpg"
)
)
pause

Last edited by terse on 2008-3-28 at 05:18 PM ]

Originally posted by terse at 2008-3-28 05:13 PM:
我看变更3楼的就可以解决0开头问题
@echo off
for /f "delims=" %%i in ('dir /b /a-d D:\A\*.jpg') do (
for /f "delims=_. tokens=1-5" %%a in ("%%i") d ...

的确是可行的.呵呵~~~

哈，还有这么个插曲。

@echo off&&setlocal enabledelayedexpansion

:: 这里是路径。

set "lj=d:\a"

for /f "delims=" %%i in ('dir/b "%lj%\*.jpg"') do (

  for /f "tokens=1-5 delims=_." %%a in ("%%i") do (

    set /a x=1%%d+1,y=1%%e+1

    ren "%lj%\%%~nxi" "%%a_%%b_%%c_!x:~1!_!y:~1!.jpg"

))

pause

厉害呀。好多都看不懂，要努力学习。，