中国DOS联盟

@echo off&goto start&rem 数字排序

a.txt 中为一行一个数字

可以对任何 200 位以内的整数进行排序。（包括负数、正数、0、及重复的数字）

缺点： 对于0开头的数字，结果会忽略首位的0

::by 26933062 2007-11-25

:start

setlocal EnableDelayedExpansion

for /l %%a in (1 1 200) do set lin=0!lin!

for /f %%a in (a.txt) do (

   set "str=%%a"

   if "!str:~0,1!"=="-" (set fus=a&set str=!str:~1!&set zf=_) else set zf=+

   set str=!lin!!str!

   set !zf!!str:~-200! !random!!random!!random!!random!!random!!random!!random!=a

)

if defined fus call :sort _ /r

call :sort +

pause&exit

:sort

for /f "tokens=1,2 delims=_+= " %%a in ('set %1^|sort %2') do (

   for /f "tokens=* delims=0" %%i in ("%%a") do (

      if "%1"=="_" (set fuhao=-) else set "fuhao="

      if "%%i"=="" (echo !fuhao!0) else echo !fuhao!%%i

   )

)

goto :eof

Hehe, didn't expect that number sorting actually caused the second storm in the union. It's lively.

Also post a piece of previous code to add some fun
:

@echo off&goto start&rem 数字排序

Numbers are in a.txt, one per line

Can sort any integer within 200 digits. (Including negative numbers, positive numbers, 0, and repeated numbers)

Disadvantage: For numbers starting with 0, the leading 0 will be ignored in the result

::by 26933062 2007-11-25

:start

setlocal EnableDelayedExpansion

for /l %%a in (1 1 200) do set lin=0!lin!

for /f %%a in (a.txt) do (

   set "str=%%a"

   if "!str:~0,1!"=="-" (set fus=a&set str=!str:~1!&set zf=_) else set zf=+

   set str=!lin!!str!

   set !zf!!str:~-200! !random!!random!!random!!random!!random!!random!!random!=a

)

if defined fus call :sort _ /r

call :sort +

pause&exit

:sort

for /f "tokens=1,2 delims=_+= " %%a in ('set %1^|sort %2') do (

   for /f "tokens=* delims=0" %%i in ("%%a") do (

      if "%1"=="_" (set fuhao=-) else set "fuhao="

      if "%%i"=="" (echo !fuhao!0) else echo !fuhao!%%i

   )

)

goto :eof

@echo off

setlocal enabledelayedexpansion

set str= %random% %random% -%random% %random% %random% -%random% %random% -%random% %random% %random%

::对于 a.txt 中为一行一个数字采用下一行方式读取，上一行不要

::上一行set str= %random%...的数前面必需要有一个空格

::for /f %%i in (a.txt) do set str=!str! %%i

echo 排序前数组为: %str:~1%



:sort

    set num=m

    for %%i in (%str%) do if %%i lss !num! set num=%%i

    set ret=%ret% %num%

    set str=!str: %num%=!

    if not "%str%" == "" goto sort



echo 排序后数组为: %ret:~1%

pause

exit

It can range from negative numbers to positive numbers, and it will remove duplicate numbers. It cannot correctly handle numbers that start with 0.

@echo off

setlocal enabledelayedexpansion

set str= %random% %random% -%random% %random% %random% -%random% %random% -%random% %random% %random%

:: For a line - by - line number in a.txt, use the next line to read, and do not need the previous line

:: The number before the previous line set str= %random%... must have a space in front

::for /f %%i in (a.txt) do set str=!str! %%i

echo The array before sorting is: %str:~1%



:sort

    set num=m

    for %%i in (%str%) do if %%i lss !num! set num=%%i

    set ret=%ret% %num%

    set str=!str: %num%=!

    if not "%str%" == "" goto sort



echo The array after sorting is: %ret:~1%

pause

exit

@echo off&setlocal enabledelayedexpansion

set/p str=输入数字(用空格隔开)

for %%i in (%str%) do (

    set str=0000000000%%i

    set .!str:~-10! !random!=%%i

)

for /f "tokens=2 delims==" %%i in ('set .') do set/p=%%i <nul

pause>nul

Simplify the terse scheme, and we can modify it if there are deficiencies.

@echo off&setlocal enabledelayedexpansion

set/p str=Enter a number (separated by spaces)

for %%i in (%str%) do (

    set str=0000000000%%i

    set .!str:~-10! !random!=%%i

)

for /f "tokens=2 delims==" %%i in ('set .') do set/p=%%i <nul

pause>nul

@echo off & Setlocal EnableDelayedExpansion



for /L %%i in (1,1,5) do (

	set skip=.!skip!

	findstr /rc:"^^!skip!$" file.txt|sort

)

So lively, I'll also add a part. The drawback is that the efficiency is a bit low...

@echo off & Setlocal EnableDelayedExpansion



for /L %%i in (1,1,5) do (

	set skip=.!skip!

	findstr /rc:"^^!skip!$" file.txt|sort

)

In the for, 5 is specified according to the maximum number of digits. If you don't know, you can also write a for statement to calculate it. I omitted it here.

Originally posted by lxmxn at 2008-4-30 05:25 PM:
So lively, I'll also add one, the shortcoming is that the efficiency is a bit low...

@echo off & Setlocal EnableDelayedExpansion



for /L %%i in (1,1,5) do (

	set skip=.!skip!

	findstr /rc:"^^!ski ... 


I didn't understand the moderator's code, can you explain it?
It seems that negative number sorting is not supported

Originally posted by huahua0919 at 2008-4-30 18:02:

I didn't understand the moderator's code. Can you explain it?
It seems that negative numbers are not supported for sorting

It's simply to find numbers from 1-digit to 5-digit using findstr according to the number of digits, and then sort them with sort. But the premise is that the numbers are all positive integers and the maximum number of digits is known. Strictly speaking, this is not sorting~

Why add a long string of zeros in front of a number, and then when traversing in the environment variable, the zeros are truncated, and they can be automatically sorted? Please give your advice, great experts.

99
1
888

The sorting result is
1
888
99

If padding with zeros, the result is:

00001
00099
00888

……

Originally posted by MLQX at 2008-5-2 11:26 AM:
Thanks.
Last edited by MLQX on 2008-5-2 at 12:34 PM ]

Originally posted by zh159 at 2008-4-30 01:51 AM:
Used before, forgot where it came from

@echo off

setlocal enabledelayedexpansion

    set numbers=%random% %random% %random% %random% %random% %random% %random% %random%

    echo 排序前 ... 



Learned from this forum for 3 days, today I finally can understand this code.
In my eyes as a newbie, this way of thinking is very unique.
In other people's eyes, maybe not unique, but classic.

Originally posted by plp626 at 2008-4-29 11:59 PM:

if not %1.==. 

Is it an implicit end-of-file mark in a text file? Or is it a mark indicating the beginning or end of a line?

Last edited by MLQX on 2008-5-2 at 01:24 PM ]

@echo off&setlocal enabledelayedexpansion

set "str=101 20 14 13 19 18 16 11 5 -7"

for %%i in (%str%) do call,set var=!var! n%%i

for %%i in (%var%) do set a=%%i&call :lp

echo !var:n=!

pause>nul&goto :eof

:lp

for %%i in (!var!) do (

    set b=%%i

    if !b:~1! lss %a:~1% (

       set var=!var:%a% =!

       set var=!var:%%i=%%i %a%!

    )

)

&&Unexpectedly, a single stone stirs up thousands of waves. I haven't been to the forum for a few days, and this post has become an essence post and is so popular, which is really beyond my initial expectation. Today, I studied my original code again and have the following highly universal code:

@echo off&setlocal enabledelayedexpansion

set "str=101 20 14 13 19 18 16 11 5 -7"

for %%i in (%str%) do call,set var=!var! n%%i

for %%i in (%var%) do set a=%%i&call :lp

echo !var:n=!

pause>nul&goto :eof

:lp

for %%i in (!var!) do (

    set b=%%i

    if !b:~1! lss %a:~1% (

       set var=!var:%a% =!

       set var=!var:%%i=%%i %a%!

    )

)

@echo off&for /f "delims=" %%i in ('sort /+n c.txt') do echo %%i

If comparing three-digit numbers, change the n value to 3.

Originally posted by zw19750516 at 2008-5-3 22:19:
&&Unexpectedly, a single stone stirs up a thousand waves. I haven't been to the forum for a few days, and this post has become an essence post, and it's so popular. It's really beyond my original expectation. Today, I studied my original code again and have the following...

Not universal. You try set "str=1111 111 20 14 13 19 18 16 11 5 -7"