实数加减运算脚本已更新, 功能更加强大.
1. 可以进行多种加减法运算, 如:(X+Y, X-Y, -X+Y, -X-Y).
2. 加入了错误输入的检测.
3. 运算数不受位数限制, 理论上可以运算N位的范围.
可以替代计算器进行加减法运算. 却不用受位数的限制. 这是该脚本最大的优势.
由于时间关系没有进行全面测试, 不足的地方请指正, 大家一起探讨, 研究~~~!
@echo off
title 实数加减运算脚本
color 27
if not %1*==* set num1=%1 & set num2=%2 & goto jmp
:input
cls
echo ╭──────────────╮
echo │ │
echo ╭─────────┤ 实 数 加 减 运 算 脚 本 ├──────────╮
echo │ │ │ │
echo │ ╰──────────────╯ │
echo │ 该脚本理论上可以对N位的实数进行加减运算。 │
echo │ │
echo │ 运算规则: │
echo │ 输入两个运算数、，程序将自动计算。运算数与默认为加法 │
echo │ 运算。、的默认值为正, 也可在前面加"-"号。例：、 │
echo │ │
echo │ + 加法运算请输入第1个运算数后按回车键。接着输入第2个运算数 │
echo │ 回车即可. 例: │
echo │ - 减法运算请输入第1个运算数后按回车键。接着输入第2个运算数 │
echo │ 注意: 第2个运算数前必须加"-"号. 例: │
echo │ 更多的运算表达式: 、 │
echo │ │
echo │ 注意: 除阿拉伯数字外, 第一位允许输入符号"-", 以及最多一个"."号, │
echo │ 不允许输入其他字符。否则, 都将视为错误输入... │
echo │ │
echo │ author:pengfei@www.cn-dos.net │
echo ╰───────────────────────────────────╯
setlocal enabledelayedexpansion
set num1=
set num2=
set /p num1= input primary number :
set /p num2= input number two number :
:jmp
set numx=%num1%
set numy=%num2%
set auto=
set less=+
set less_=+
set adding=+
set norm=1
set sign=
set sign_=
if "%num1:~0,1%"=="-" (
if "%num2:~0,1%"=="-" (
set num1=!num1:~1!
set num2=!num2:~1!
set adding=
set sign=-
goto start
)
)
if "%num1:~0,1%"=="-" (
set num1=!num1:~1!
set auto=::
set less=-
set less_=-
set norm=2
set sign=-
set sign_=
goto start
)
if "%num2:~0,1%"=="-" (
set num2=!num2:~1!
set auto=::
set less=-
set less_=-
set adding=
set norm=2
set sign_=-
goto start
)
:start
echo %num1% | find "." >nul || set num1=%num1%.0
echo %num2% | find "." >nul || set num2=%num2%.0
if "%num1:~-1%"=="." set num1=%num1%0
if "%num2:~-1%"=="." set num2=%num2%0
if "%num1:~0,1%"=="." set num1=0%num1%
if "%num2:~0,1%"=="." set num2=0%num2%
call :jerque "%num1%"
call :jerque "%num2%"
set num=0
for %%a in (%num1% %num2%) do (
set /a num+=1
for /f "tokens=1,2 delims=." %%i in ("%%a") do (
if "!num!"=="1" (set one=%%i) else (set one_=%%i)
if "!num!"=="1" (set two=%%j) else (set two_=%%j)
)
)
call :omit %one%
set one=%want%
call :omit %one_%
set one_=%want%
call :raze %two%
set two=%want_%
call :raze %two_%
set two_=%want_%
if "%one%"=="" set one=0
if "%one_%"=="" set one_=0
call :go %one%
set countx=%wish%
call :go %one_%
set countx_=%wish%
if "%two%"=="" set two=0
if "%two_%"=="" set two_=0
call :go %two%
set county=%wish%
call :go %two_%
set county_=%wish%
set after=
set front=0
if %countx% lss %countx_% (
set /a result=%countx_%-%countx%
call :fine !result! %one%
set one=!incept!
) else (
set /a result=%countx%-%countx_%
call :fine !result! %one_%
set one_=!incept!
)
set after=0
set front=
if %county% lss %county_% (
set /a result=%county_%-%county%
call :fine !result! %two%
set two=!incept!
) else (
set /a result=%county%-%county_%
call :fine !result! %two_%
set two_=!incept!
)
if "%norm%"=="2" (
call :how %one%%two% %one_%%two_%
)
:recur
if "%mu%"=="2" call :meet
set outcome_=0
call :scale %two% %two_%
set decimal=%numeral:~0,-1%
call :scale %one% %one_%
if "%note%"=="0" (
set integer=%numeral:~0,-1%
) else (
set integer=1%numeral:~0,-1%
)
call :raze %decimal%
set decimal=%want_%
call :omit %integer%
set integer=%want%
if "%integer%"=="" set integer=0
if "%integer%"=="0" if "%decimal%"=="" set sign=
if "%decimal%"=="" (set dot=) else (set dot=.)
if "%numx:~0,1%"=="." set numx=0%numx%
if "%numy:~0,1%"=="." set numy=0%numy%
if "%numx:~-1%"=="." set numx=%numx:~0,-1%
if "%numy:~-1%"=="." set numy=%numy:~0,-1%
if "%numx%"=="" set numx=0
if "%numx%"=="-" set numx=-0
if "%numy%"=="-" set numy=-0
cls
echo =============
echo 运算结果^^!
echo =============
echo.
echo.
echo %numx%%adding%%numy%=%sign%%integer%%dot%%decimal%
pause >nul
exit
:scale
set value=@%1
set value_=@%2
set numeral=
:repeat
set outcome=%outcome_%
if "%outcome_:~0,-1%"=="-" (
set /a outcome=10%outcome_%
set note=1
) else (
set note=0
)
set numeral=%outcome:~-1%%numeral%
%auto%set note=0%outcome:~0,-1%
if not "%value:~-1%"=="@" (
set xx=!value:~-1!
set value=!value:~0,-1!
)
if not "%value_:~-1%"=="@" (
set yy=!value_:~-1!
set value_=!value_:~0,-1!
call :operation !xx! !yy!
)
goto :eof
:operation
set refer=%1
set refer_=%2
set /a outcome_=%refer%%less%%refer_%%less_%%note%
goto repeat
:go
set remove=%1@
set wish=0
:go_
if not "!remove:~0,1!"=="@" (
set /a wish+=1
set remove=!remove:~1!
goto go_
)
goto :eof
:fine
set take=%1
set incept=%2
:fine_
if not "%take%"=="0" (
set /a take-=1
set incept=%front%!incept!%after%
goto fine_
)
goto :eof
:omit
set want=%1
:omit_
if "%want:~0,1%"=="0" (
set want=%want:~1%
goto omit_
)
goto :eof
:raze
set want_=%1
:raze_
if "!want_:~-1!"=="0" (
set want_=!want_:~0,-1!
goto raze_
)
goto :eof
:how
set first=%1@
set second=%2@
:how_
if not "%first:~0,1%"=="@" (
set first_=!first:~0,1!
set first=!first:~1!
)
if not "%second:~0,1%"=="@" (
set second_=!second:~0,1!
set second=!second:~1!
call :judg
)
goto :eof
:judg
if !first_! gtr !second_! (
set mu=1
goto recur
) else (
if !first_! lss !second_! (
set mu=2
goto recur
)
)
goto how_
:meet
set middle=%one%
set one=%one_%
set one_=!middle!
set middle_=%two%
set two=%two_%
set two_=!middle_!
set sign=%sign_%
goto :eof
:jerque
for /f "tokens=1* delims=." %%i in (%1) do (
echo %%i%%j|findstr "^*$">nul || goto error
)
goto :eof
:error
cls
echo ======================
echo 运算数不符合要求^^!
echo ======================
echo.
echo.
echo 请按任意键重新输入...
pause >nul
goto input
今天中秋节, 祝联盟所有朋友中秋快乐, 学习进步, 天天开心~~~! 送大家一个礼物"浮点数加减运算脚本".
代码刚写出来, 还有很多不足的地方, 大家一起探讨!
先前的代码有一个致使的缺陷, 现已修正. 请测试...
该脚本实现的功能:
1. 可以对浮点数进行加减运算, 有较好的容错性, 如过滤一些不正常输入.
2. 解决了批处理脚本在读取数值时遇到的进制问题, 详情请看下面"关于数值运算时的进制问题"的帖子.
3. 格式输出运算结果, 更加美观.
4. 该脚本可以在CMD下接收变量输入, 也可以直接运行批处理接收运算字符.
感谢qwe1234567版主提供建议和测试脚本!
@echo off
title 浮点数加减运算
mode con: cols=80 lines=25
color 27
echo ╭───────────────╮
echo │ │
echo ╭─────────┤ 浮 点 数 加 减 运 算 脚 本 ├─────────╮
echo │ │ │ │
echo │ ╰───────────────╯ │
echo │ │
echo │ 该脚本可以对浮点数进行加减法运算: │
echo │ │
echo │ +加法运算请输入第1个运算数后按回车键. 接着输入第2个运算数 │
echo │ 回车即可. │
echo │ │
echo │ -减法运算请输入第1个运算数后按回车键. 接着输入第2个运算数 │
echo │ 第2个运算数前必须加"-"号. │
echo │ │
echo │ 注意: │
echo │ 1．整数位最多可运算9位数, 小数位最多可运算8位数. │
echo │ 2．小数位整数位加起来最多可运算17位数 │
echo │ 否则，将会溢出或数值无效! │
echo │ │
echo │ author:pengfei@www.cn-dos.net │
echo │ │
echo ╰───────────────────────────────────╯
if not %1*==* (
set num1=%1
set num2=%2
goto jmp
)
set /p num1= input primary number:
set /p num2= input number two number:
:jmp
setlocal enabledelayedexpansion
set numx=%num1%
set numy=%num2%
set adding=+
set tack=1
set tack_=1
set norm=
if "%num2:~0,1%"=="-" (
set num2=!num2:~1!
set less=-
set less_=-
set adding=-
set tack=3
set tack_=1
set norm=
)
echo %num1% | find "." >nul || set num1=%num1%.0
echo %num2% | find "." >nul || set num2=%num2%.0
if "%num1:~-1%"=="." set num1=%num1%0
if "%num2:~-1%"=="." set num2=%num2%0
if "%num1:~0,1%"=="." set num1=0%num1%
if "%num2:~0,1%"=="." set num2=0%num2%
for %%a in (%num1% %num2%) do (
set /a num+=1
for /f "tokens=1,2 delims=." %%i in ("%%a") do (
if "!num!"=="1" (set one=%%i) else (set one_=%%i)
if "!num!"=="1" (set two=%%j) else (set two_=%%j)
)
)
call :raze %two%
set two=%rear%
call :raze %two_%
set two_=%rear%
call :omit %one%
set one=%want%
call :omit %one_%
set one_=%want%
call :go %two%
set count=%wish%
call :go %two_%
set count_=%wish%
if %count% lss %count_% (
set /a result=%count_%-%count%
call :fine !result! %two%
set two=!incept!
) else (
set /a result=%count%-%count_%
call :fine !result! %two_%
set two_=!incept!
)
if "%norm%"==" " (
if 1%one% lss 1%one_% call :metathesis
if 1%one% equ 1%one_% (
if 1%two% lss 1%two_% call :metathesis
)
)
if "%one%"=="" set one=0
if "%one_%"=="" set one_=0
set /a integer=%one%+%less%%one_%
set /a decimal=%tack%%two%+%less_%%tack_%%two_%
if "%decimal:~0,1%"=="2" (
set decimal=!decimal:~1!
) else (
set decimal=!decimal:~1!
set /a integer%adding%=1
)
if "%decimal%"=="" (set dot=) else (set dot=.)
if "%adding%"=="-" set adding=
if "%numx:~0,1%"=="." set numx=0%numx%
if "%numy:~0,1%"=="." set numy=0%numy%
if "%numx:~-1%"=="." set numx=%numx:~0,-1%
if "%numy:~-1%"=="." set numy=%numy:~0,-1%
cls
echo =============
echo 运算结果^^!
echo =============
echo.
echo %numx%%adding%%numy%=%sign%%integer%%dot%%decimal%
pause >nul
goto :eof
:go
set remove=%1
set wish=0
:go_
if not "!remove:~0,1!"=="~" (
for /l %%c in (0,1,9) do (
if "!remove:~0,1!"=="%%c" (
set /a wish+=1
set remove=!remove:~1!
goto go_
)
)
)
goto :eof
:fine
set take=%1
set incept=%2
:fine_
if not "%take%"=="0" (
set /a take-=1
set incept=!incept!0
goto fine_
)
goto :eof
:omit
set want=%1
:again
if "%want:~0,1%"=="0" (
set want=%want:~1%
goto again
)
goto :eof
:raze
set rear=%1
:raze_
if "!rear:~-1!"=="0" (
set rear=!rear:~0,-1!
goto raze_
)
goto :eof
:metathesis
set middle=%one%
set one=%one_%
set one_=!middle!
set middle_=%two%
set two=%two_%
set two_=!middle_!
set sign=-
goto :eof
相关讨论:
［共同参与］［挑战思路］［批处理处理浮点运算］
关于数值时的进制问题!
Last edited by namejm on 2006-10-19 at 00:39 ]
