中国DOS联盟

对其用Tab好点
算空格太累..

每行固定输出80字符 就对齐了吧

我也来个简单的：

@echo off&color 02

:loop

for /l %%i in (1,1,26) do (

call set/a var=%%random%%%%%%2&call set/p=  %%var%%<nul

)

echo.

if %random% lss 1000 echo                 数                   码                     雨

for /l %%i in (1,1,200) do ver>nul

goto loop

[ Last edited by WANKOILZ on 2008-5-27 at 03:35 PM ]

WANKOILZ
高效简洁，棒极了！

学习中，楼主厉害

怎么实现向下滚动的呢？

@echo off&color 02
set n=1
:loop
set var=
for /l %%i in (1,1,26) do (call set/a r=%%random%%%%%%2&call set "var=%%var%% %%r%%")
set "len%n%=%var%"
set/a n=(n-1+24)%%24,m=n
for /l %%b in (1,1,24) do (call :sub)
cls
echo.%var%
for /l %%i in (1,1,300) do ver>nul
goto loop
:sub
set/a m=(m+1)%%24
call set var=%%var%% %%len%m%%%

[ Last edited by netbenton on 2009-2-9 at 18:43 ]

部分代码借18楼的办法，改动一下成往下掉的。
真正的“雨”下来咯！^_^

@echo off&color 02
set len= 数 码 雨 来 咯 ！
:loop
set var=
for /l %%i in (1,1,26) do (call set/a r=%%random%%%%%%2&call set "var=%%var%% %%r%%")
set len=%var% %len:~0,1838%
cls
echo.%len%
for /l %%i in (1,1,300) do ver>nul
goto loop

@echo off&color 02
set len= 数 码 雨 来 咯 ！ 16H By Benton
set str=fedcba9876543210
:loop
set var=
for /l %%i in (1,1,26) do (call set/a r=%%random%%%%%%16&call call set "var=%%var%% %%%%str:~%%r%%,1%%%%")
set len=%var% %len:~0,1838%
cls
echo.%len%
for /l %%i in (1,1,300) do ver>nul
goto loop

哈哈,还真挺好玩的呢!

不错的bat

@echo off&color 02
if defined len goto :sub
SETLOCAL ENABLEDELAYEDEXPANSION
set len= 数 码 雨 来 咯 ！ By Benton
start /b %~n0.bat
title 数码雨 By Benton 按任意键退出
set str= 0 1 2 3 4 5 6 7 89ABCDEFG
:loop
set var=
for /l %%i in (1,1,26) do (set/a r=!random!%%32&call set "var=!var! %%str:~!r!,1%%")
set len=!var! !len:~0,1838!
cls
echo !len!
for /l %%i in (1,1,300) do ver>nul
goto loop
:sub
pause>nul
TASKKILL /FI "WINDOWTITLE ne 数码雨 By Benton" >nul

::黑客数码雨双向移动，超逼真
::还支持按键退出

@echo off&color 0a

if defined lins goto :sub

set "lins=  0  1  2  3  4  5  6  7  8  9 10 11 12 13 14 15 16 17 18 19 20 21 22"

setlocal enabledelayedexpansion

start /b %~n0.bat

title 数码雨  By Benton 按任意键退出

set str=fedcbag h i j k l m n o p q r s t u v w x y z9876543210ABCDEFG H I J K L M N O P Q R S T U V W X Y Z

for %%i in (%lins%) do (

	for /l %%j in (1,1,8) do (

		set "m%%i=!m%%i!          "

		set "n%%i=!n%%i!          "

	)

)

set n=0

set m=1

::预处理结束





:::::::::::::::循环体:::::::::::::::

:loop

set var=  %%str:~!random:~0,2!,1%%

for /l %%i in (1,1,2) do (

call set "var=!var!  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%"

)

set/a n=^(n+22^)%%23,m=^(m+22^)%%23

set m%m%=!var!

set n%n%=!var!

set lins=!lins:~-3!!lins:~0,-3!



set tem=!n0!

for %%a in (a b) do (

for /l %%i in (22,-1,0) do (

set tem1=!n%%i!

set n%%i=!tem!

set tem=!tem1!))



set ll=0

for %%i in (%lins%) do (

set "l!ll!=!m%%i:~0,3!!n%%i:~0,3!!m%%i:~3,3!!n%%i:~3,3!!m%%i:~6,3!!n%%i:~6,3!!m%%i:~9,3!!n%%i:~9,3!!m%%i:~12,3!!n%%i:~12,3!!m%%i:~15,3!!n%%i:~15,3!!m%%i:~18,3!!n%%i:~18,3!!m%%i:~21,3!!n%%i:~21,3!!m%%i:~24,3!!n%%i:~24,3!!m%%i:~27,3!!n%%i:~27,3!!m%%i:~30,3!!n%%i:~30,3!!m%%i:~33,3!!n%%i:~33,3!!m%%i:~36,3!!n%%i:~36,3!  "

set/a ll+=1

)

set len=!l0!!l1!!l2!!l3!!l4!!l5!!l6!!l7!!l8!!l9!!l10!!l11!!l12!!l13!!l14!!l15!!l16!!l17!!l18!!l19!!l20!!l21!!l22!!l23!

cls

echo !len:~0,1838!

for /l %%i in (1,1,1000) do echo.>nul

goto loop

::::::::::::::::::::::::::::::::::::



::外部控制子过程

:sub

pause>nul

TASKKILL /FI "WINDOWTITLE ne 数码雨"

::双向移动+左右文字滚动

@echo off&color 0a

if defined lins goto :sub

set "lins=  0  1  2  3  4  5  6  7  8  9 10 11 12 13 14 15 16 17 18 19 20 21 22 23"

setlocal enabledelayedexpansion

start /b %~n0.bat

title 数码雨  By Benton 按任意键退出

set str=fedcbag h i j k l m n o p q r s t u v w x y z9876543210ABCDEFG H I J K L M N O P Q R S T U V W X Y Z

for %%i in (%lins%) do (

        for /l %%j in (1,1,8) do (

                set "m%%i=!m%%i!          "

                set "n%%i=!n%%i!          "

        )

)

set n=2

set m=0

set k=0

set "in0=。。。。——《《欢迎来到黑客帝国》》——。。。。。"

set "im0=看到美女了吗？看到了，说明你已是黑客帝国的了。。。"



::预处理结束





:::::::::::::::循环体:::::::::::::::

:loop

set var=  %%str:~!random:~0,2!,1%%

for /l %%i in (1,1,2) do (

call set "var=!var!  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%  %%str:~!random:~0,2!,1%%"

)

set/a n=^(n+23^)%%24,m=^(m+23^)%%24

set m%m%=!var!

set n%n%=!var!

set lins=!lins:~-3!!lins:~0,-3!



set tem=!n0!

for %%a in (a b) do (

for /l %%i in (23,-1,0) do (

set tem1=!n%%i!

set n%%i=!tem!

set tem=!tem1!))



set ll=0

for %%i in (%lins%) do (

set "l!ll!=!m%%i:~0,3!!n%%i:~0,3!!m%%i:~3,3!!n%%i:~3,3!!m%%i:~6,3!!n%%i:~6,3!!m%%i:~9,3!!n%%i:~9,3!!m%%i:~12,3!!n%%i:~12,3!!m%%i:~15,3!!n%%i:~15,3!!m%%i:~18,3!!n%%i:~18,3!!m%%i:~21,3!!n%%i:~21,3!!m%%i:~24,3!!n%%i:~24,3!!m%%i:~27,3!!n%%i:~27,3!!m%%i:~30,3!!n%%i:~30,3!!m%%i:~33,3!!n%%i:~33,3!!m%%i:~36,3!!n%%i:~36,3!  "

set/a ll+=1

)



for %%i in (0 4 8 12 16 20) do (if %m%==%%i set/a k=^(k+25^)%%26)



        set in=!in0:~%k%!!in0:~0,%k%!

        set im=!im0:~-%k%!!im0:~0,-%k%!

        set l10=!l10:~0,25!!in:~0,15!!l10:~55!

        set l12=!l12:~0,25!!im:~0,15!!l12:~55!



set len=!l0!!l1!!l2!!l3!!l4!!l5!!l6!!l7!!l8!!l9!!l10!!l11!!l12!!l13!!l14!!l15!!l16!!l17!!l18!!l19!!l20!!l21!!l22!!l23!

cls

echo !len:~0,1888!

for /l %%i in (1,1,200) do echo.>nul

goto loop

::::::::::::::::::::::::::::::::::::



::外部控制子过程

:sub

pause>nul

TASKKILL /FI "IMAGENAME EQ cmd.exe" /FI "WINDOWTITLE EQ 数码雨*">nul

[ Last edited by netbenton on 2009-4-17 at 22:32 ]

新人路过，学习了