中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net  论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客:  注册 | 登录 | 命令行 | 搜索 | 上传 | 帮助 »
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » p-mailsend_4.0.cmd(命令行发送邮件,群发\多附件\匿名)
<   <<   [1] [2] [3] [4] [5] [6] [7] [8] [9]  >>   >
作者:
标题: p-mailsend_4.0.cmd(命令行发送邮件,群发\多附件\匿名) 上一主题 | 下一主题
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 16 楼』:  

今天早上分析了一下 vkill兄的代码; 在这里解析下;以便于新手学习; 整体的流程是: 1.检查文件完整性 or下载 2.检查参数 3.测试登陆 4.写全配置文件 5.nc 灌入 发送邮件


2007-4-26 01:24
查看资料  发送邮件  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 17 楼』:  

看了下;发现些小问题;下面提出些建议; 为了避免只使用一次/x建议在开头把user等初始化 :发信程序最后漏写了个goto :eof 这一处错误会导致 :发信程序 执行后会紧接着执行 :判断登陆成功否; 在 call :判断登陆成功否后面加一句 if errorlevel 1 goto :del_ 否则无论是否登陆成功都继续发信; 在call :判断发送成功否 会出现些其它不必要的信息;而且发送不成功的话;发送不成功提示会出现两次; 而且最后还会echo 全部信件发送完毕; 建议在 call :del echo 全部信件发送完毕 上加 cls if errorlevel 1 echo 发信不成功 & goto del_ 在:交互模式中 if not defined user (set/p=用户名:<nul&set/p "user= ") 完全可以简写为:if not defined user (set/p "user=用户名: ") 依次类推 for /f "tokens=2 delims=[]" %%? in ('ping -n 1 smtp.163.com ^|findstr /i "^Pinging"') do (set "ip=%%?") 建议把pinging改为ping否则vista无法成功找到ip vista回显为:
正在 Ping smtp.163.split.netease.com [220.181.12.13] 具有 32 字节的数据: 来自 220.181.12.13 的回复: 字节=32 时间=35ms TTL=51 220.181.12.13 的 Ping 统计信息: 数据包: 已发送 = 1，已接收 = 1，丢失 = 0 (0% 丢失)， 往返行程的估计时间(以毫秒为单位): 最短 = 35ms，最长 = 35ms，平均 = 35ms
应该把help下的if "%1"=="vkill" goto :eof提到help前;否则则失去了他应有的作用;


2007-4-26 01:27
查看资料  发送邮件  发短消息  网志   编辑帖子
wudixin96
银牌会员





积分 1928
发帖 931
注册 2007-1-6
状态 离线
『第 18 楼』:  

好东西。不过还是要借助vbs？！


2007-4-26 01:33
查看资料  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 19 楼』:  

给vkill兄的代码 根据上面的建议稍微修改了下 并稍微写了点注释 代码如下
  1. @echo off&setlocal ENABLEDELAYEDEXPANSION
  2. set "t_=test.conf"
  3. set "server=163.com"
  4. set "port=25"
  5. set "最大附件大小=15000000"
  6. set "tools_url=http://www.vkill.net/netbar/网吧所需exe/"
  7. set "tools_name=nc.exe;rar.exe;base64.exe"
  9. rem ================检查文件完整性=====================
  10. :down_tools
  11. set "down_ok=y"
  12. if not "%tools_name%*"=="*" (
  13. for %%? in (%tools_name%) do (
  14. if *%%~$PATH:?==* if not exist %%? (
  15. set "down_ok=n"
  16. echo 程序所依赖文件%%?缺失,已自动开始下载
  17. if not exist iget.vbs call :iget.vbs_
  18. iget.vbs "%tools_url%%%?" "%%?"
  19. ::move "%%?" %windir%>nul 2>nul
  20. echo 文件%%?下载完毕
  21. )
  22. )
  23. )
  24. del /f/q iget.vbs>nul 2>nul
  25. if [%down_ok%]==[n] goto down_tools
  26. rem ==================结束==============================
  29. rem ===============分析参数=============================
  30. for %%? in (/? -? /h -h --h) do (if "%1"=="%%?" goto help)
  31. if "%1"=="" goto help
  32. :loop_ap
  33. set/a n+=1
  34. if not "%1"=="" (
  35. if "%1"=="/x" goto 交互模式
  36. if "%1"=="/u" set "user=%~2"
  37. if "%1"=="/p" set "pass=%~2"
  38. if "%1"=="/t" set "to=%~2"
  39. if "%1"=="/s" set "subject=%~2"
  40. if "%1"=="/c" set "content=%~2"
  41. if "%1"=="/a" set "accessories=%~2"
  42. shift&shift
  43. goto loop_ap
  44. )
  45. for %%? in (user pass to subject) do (if not defined %%? goto 参数错误)
  46. goto start
  48. rem ===================结束===============================
  50. :交互模式
  51. call :help vkill
  52. if not defined user (set/p "user=用户名: ")
  53. if not defined pass (set/p "pass=密码: ")
  54. if not defined to (set/p "to=收件人: ")
  55. if not defined subject (set/p "subject=主题<hello>: ")
  56. if not defined content (set/p "content=内容: ")
  57. if not defined accessories (set/p "accessories=附件: ")
  59. rem :::::开始写配置文件:::::
  60. :start
  61. ::写单个发送配置文件
  62. for /l %%? in (1,1,7) do (>%%? cd.)
  64. >>1 echo helo vkill
  65. >>1 echo AUTH LOGIN
  67. rem ===================1文件的内容==========================
  68. rem helo vkill
  69. rem AUTH LOGIN
  70. rem ====================结束================================
  72. for %%? in (%user%;%pass%) do (
  73. set/p=%%?^<nul|base64>"!t_!"
  74. set/p v=<"!t_!"
  75. >>2 echo !v!
  76. del /f/q !t_!
  77. )
  79. rem [*第一次改写 test.conf 做为一个中介用来把用户名密码的base64编码写入文件2*]
  81. rem =================2文件的内容=============================
  82. rem 用户名和密码的base64编码
  83. rem =====================结束================================
  86. rem [*改写test.conf利用nc 灌入服务器25端口的回显判断是否能够成功登陆*]
  87. >8 echo quit
  90. rem =================8文件的内容============================
  91. rem quit
  92. rem ====================结束================================
  95. copy 1+2+8 "!t_!" >nul 2>nul
  97. rem ::判断能否登陆::
  98. rem 第二次改写test.conf 以用来 验证能否登陆服务器 nc -nvv IP Port <test.conf
  99. rem =================test.conf文件的内容=====================
  100. rem helo vkill
  101. rem AUTH LOGIN
  102. rem 用户名base64编码
  103. rem 密码base64编码
  104. rem quit
  105. rem ====================结束================================
  106. call :发信程序
  107. cls
  108. call :判断登陆成功否
  109. if errorlevel 1 goto :del_
  111. rem ::判断结束::
  112. >>3 echo mail from: ^<%user%@%server%^>
  114. rem ===================3文件的内容=============================
  115. rem mail from: <%user%@163.com>
  116. rem =======================结束================================
  120. >>5 echo data
  121. >>5 echo From: %user%@%server%
  122. >>5 echo To: %to%
  123. >>5 echo Subject: %subject%
  124. >>5 echo X-mailer: p-163ms 2.0 [cn]
  125. >>5 echo Mime-Version: 1.0
  126. >>5 echo Content-Type: multipart/mixed;
  127. >>5 echo boundary="=====vkill====="
  128. >>5 echo.
  129. if defined content (
  130. >>5 echo --=====vkill=====
  131. >>5 echo Content-Type: text/plain;
  132. >>5 echo charset="gb2312"
  133. >>5 echo Content-Transfer-Encoding: 7bit
  134. >>5 echo.
  135. dir !content! >nul 2>nul &&(type "!content!">>5) ||(>>5 echo !content!)
  136. )
  139. rem ====================5文件的内容=============================
  140. rem data
  141. rem From: %user%@163.com
  142. rem To: %to%
  143. rem Subject: %subject%
  144. rem X-mailer: p-163ms 2.0 [cn]
  145. rem Mime-Version: 1.0
  146. rem Content-Type: multipart/mixed;
  147. rem boundary="=====vkill====="
  148. rem 如果有内容的话
  149. rem --=====vkill=====
  150. rem Content-Type: text/plain;
  151. rem charset="gb2312"
  152. rem Content-Transfer-Encoding: 7bit
  153. rem
  154. rem 内容
  155. rem ======================结束================================
  157. echo 压缩编码文件中...
  158. if defined accessories for %%? in (%accessories%) do (call :压缩编码附件 "%%?")
  160. >>7 echo --=====vkill=====--
  161. >>7 echo .
  162. >>7 echo quit
  164. rem ===================7文件的内容============================
  165. rem --=====vkill=====--
  166. rem
  167. rem quit
  168. rem ======================结束================================
  170. ::发信
  171. for %%? in (%to%) do (
  172. echo 给%%?发信中...
  173. ::合并单个发送配置文件
  174. >4 echo rcpt to: ^<%%?^>
  175. del /f/q "!t_!"
  176. copy 1+2+3+4+5+6+7 "!t_!" >nul 2>nul
  177. call :发信程序
  178. call :判断发送成功否
  179. )
  181. rem ====================4文件的内容=============================
  182. rem rcpt to:<%to%>
  183. rem =======================结束================================
  185. rem 第三次改写 test.conf文件.合并1-7个文件;内容如下;也是最关键的东西.
  186. rem ===================test.conf文件的内容==========================
  187. rem helo vkill
  188. rem AUTH LOGIN
  189. rem 用户名base64编码
  190. rem 密码base64编码
  191. rem mail from: <%user%@163.com>
  192. rem rcpt to: <%to%@163.com>
  193. rem data
  194. rem From: %user%@163.com
  195. rem To: %to%@163.com
  196. rem Subject: %subject%
  197. rem X-mailer: p-163ms 2.0 [cn]
  198. rem Mime-Version: 1.0
  199. rem Content-Type: multipart/mixed;
  200. rem boundary="=====vkill====="
  201. rem
  202. rem --=====vkill=====
  203. rem Content-Type: text/plain;
  204. rem charset="gb2312"
  205. rem Content-Transfer-Encoding: 7bit
  206. rem
  207. rem %content%
  208. rem --=====vkill=====
  209. rem Content-Type: application/octet-stream;
  210. rem name="附件名称_.rar"
  211. rem Content-Transfer-Encoding: base64
  212. rem Content-Disposition: attachment;
  213. rem filename="附件名称_.rar"
  214. rem
  215. rem 附件压缩文件的base64编码
  216. rem
  217. rem --=====vkill=====--
  218. rem .
  219. rem quit
  220. rem ====================结束================================
  221. rem ::::写配置文件结束::::
  222. cls
  223. if errorlevel 1 echo 发信不成功 & goto del_
  224. call :del_
  225. echo 全部信件发送完毕
  226. ping -n 3 127.1>nul 2>nul
  227. goto :eof
  229. :del_
  230. for /l %%? in (1,1,8) do (del /f/q %%?>nul 2>nul)
  231. del /f/q "%t_%">nul 2>nul
  232. del /f/q p-163ms.log>nul 2>nul
  233. goto :eof
  235. :help
  236. if "%1"=="vkill" goto :eof
  237. echo ____help________________________________________________________________________
  238. echo.
  239. echo p-163ms v2.0 by:vkill
  240. echo Copyright (C) 2006-2008 www.vkill.net
  241. echo.
  242. echo Usage: p-163ms.cmd [/x] /u 用户名 /p 密码 /t 收件人 /s 主题 [/c 内容] [/a 附件]
  243. echo.
  244. echo /x 交互模式,当使用此参数时别的参数全部无效
  245. echo /t 收件人:(多收件人中间用,隔开;多附件时用""引住)
  246. echo /c 内容:(文字/写好内容的文本文件路径)
  247. echo /a 附件:(绝对路径/相对路径,多附件中间用,隔开;多附件时用""引住)
  248. echo.
  249. echo 示例:
  250. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com" /s hello
  251. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com" /s hello /c 123 /a "d:\00.txt"
  252. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com,yx127@yx127.com" /s hello /c 123 /a "d:\00.txt,c:\00.bat"
  253. echo.
  254. echo ________________________________________________________________________________
  255. goto :eof
  257. :压缩编码附件
  258. dir %~1 >nul 2>nul &&(call :压缩文件 "%~1" "rar.exe -r")||(call :压缩文件 "%~1" rar.exe)
  259. call :判断文件大小 "%~n1_.rar"
  260. >>6 echo --=====vkill=====
  261. >>6 echo Content-Type: application/octet-stream;
  262. >>6 echo name="%~n1_.rar"
  263. >>6 echo Content-Transfer-Encoding: base64
  264. >>6 echo Content-Disposition: attachment;
  265. >>6 echo filename="%~n1_.rar"
  266. >>6 echo.
  267. base64.exe -i "%~n1_.rar">>6
  268. >>6 echo.
  269. del /f/q "%~n1_.rar" >nul 2>nul
  270. goto :eof
  272. rem ==================6文件的内容===================================
  273. rem --=====vkill=====
  274. rem Content-Type: application/octet-stream;
  275. rem name="%~n1_.rar"
  276. rem Content-Transfer-Encoding: base64
  277. rem Content-Disposition: attachment;
  278. rem filename="%~n1_.rar"
  279. rem
  280. rem 附件的base64编码
  281. rem
  282. rem ====================结束======================================
  284. :压缩文件
  285. %~2 a "%~n1_.rar" "%~1" >nul 2>nul||(goto 压缩文件错误)
  286. goto :eof
  288. :判断文件大小
  289. set/a z+=%~z1
  290. ::判断附件大小
  291. if not !z! lss %最大附件大小% (goto 附件大小超出)
  292. goto :eof
  294. :发信程序
  295. for /f "tokens=2 delims=[]" %%? in ('ping -n 1 smtp.163.com ^|findstr /i "^Ping"') do (set "ip=%%?")
  296. nc -nvv !ip! %port%<"!t_!">p-163ms.log
  297. goto :eof
  299. :判断登陆成功否
  300. for /f "tokens=1-2 delims=:" %%a in ('findstr /N . p-163ms.log') do (set "%%a=%%b")
  301. echo !5!|findstr "^235" >nul 2>nul ||(goto 登陆不成功)
  302. goto :eof
  304. :判断发送成功否
  305. for /f "tokens=1-2 delims=:" %%a in ('findstr /N . p-163ms.log') do (set "%%a=%%b")
  306. if not defined 10 (call :发信不成功)
  307. echo !9!|findstr "^250" >nul 2>nul ||(goto 发信不成功)
  308. goto :eof
  310. :iget.vbs_
  311. >iget.vbs echo x=LCase(WScript.Arguments(1))
  312. >>iget.vbs echo y=LCase(WScript.Arguments(0))
  313. >>iget.vbs echo Set xPost=CreateObject("Microsoft.XMLHTTP")
  314. >>iget.vbs echo xPost.Open "GET",y,0
  315. >>iget.vbs echo xPost.Send()
  316. >>iget.vbs echo Set sGet=CreateObject("ADODB.Stream")
  317. >>iget.vbs echo sGet.Mode=3
  318. >>iget.vbs echo sGet.Type=1
  319. >>iget.vbs echo sGet.Open()
  320. >>iget.vbs echo sGet.Write(xPost.responseBody)
  321. >>iget.vbs echo sGet.SaveToFile x,2
  322. goto :eof
  324. :::::::::::::::::::::所有错误start::::::::::::::::::::::
  325. :参数错误
  326. echo 参数错误,用户名\密码\收件人\主题中某一项缺少
  327. goto :eof
  329. :压缩文件错误
  330. echo 压缩文件失败
  331. goto :eof
  333. :附件大小超出
  334. echo 附件大小超出
  335. goto :eof
  337. :登陆不成功
  338. echo 登陆不成功
  339. goto :eof
  341. :发信不成功
  342. echo 发信不成功
  343. goto :eof
  344. :::::::::::::::::::::所有错误end::::::::::::::::::::::
BJSH发表于： 2007-04-25 13:20
[ Last edited by bjsh on 2007-4-25 at 01:34 PM ]


   此帖被 +16 点积分     点击查看详情   
评分人：【 lxmxn 】分数： +8  时间：2007-4-26 02:30
评分人：【 vkill 】分数： +8  时间：2007-4-26 07:35


2007-4-26 01:35
查看资料  发送邮件  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 20 楼』:  

根据vkill兄的代码;我重新写了一下; 直接生成 test 和 post文件; 避免了9个文件的加和和复制; 稍微容易理解些: 代码如下:
  1. @echo off&setlocal ENABLEDELAYEDEXPANSION
  2. set "t_=test.conf"
  3. set "server=163.com"
  4. set "port=25"
  5. set "最大附件大小=15000000"
  6. set "tools_url=http://www.vkill.net/netbar/网吧所需exe/"
  7. set "tools_name=nc.exe;rar.exe;base64.exe"
  8. set "user="
  9. set "pass="
  10. set "to="
  11. set "subject="
  12. set "content="
  13. set "accessories="
  14. :down_tools
  15. set "down_ok=y"
  16. if not "%tools_name%*"=="*" (
  17. for %%? in (%tools_name%) do (
  18. if *%%~$PATH:?==* if not exist %%? (
  19. set "down_ok=n"
  20. echo 程序所依赖文件%%?缺失,已自动开始下载
  21. if not exist iget.vbs call :iget.vbs_
  22. iget.vbs "%tools_url%%%?" "%%?"
  23. echo 文件%%?下载完毕
  24. )
  25. )
  26. )
  27. del /f/q iget.vbs>nul 2>nul
  28. if [%down_ok%]==[n] goto down_tools
  29. for %%? in (/? -? /h -h --h) do (if "%1"=="%%?" goto help)
  30. if "%1"=="" goto help
  31. :loop_ap
  32. set/a n+=1
  33. if not "%1"=="" (
  34. if "%1"=="/x" goto 交互模式
  35. if "%1"=="/u" set "user=%~2"
  36. if "%1"=="/p" set "pass=%~2"
  37. if "%1"=="/t" set "to=%~2"
  38. if "%1"=="/s" set "subject=%~2"
  39. if "%1"=="/c" set "content=%~2"
  40. if "%1"=="/a" set "accessories=%~2"
  41. shift&shift
  42. goto loop_ap
  43. )
  44. for %%? in (user pass to subject) do (
  45. if not defined %%? echo 参数错误参数错误,用户名\密码\收件人\主题中某一项缺少 & goto :eof
  46. )
  47. goto start
  49. :交互模式
  50. call :help vkill
  51. if not defined user (set/p "user=用户名: ")
  52. if not defined pass (set/p "pass=密码: ")
  53. if not defined to (set/p "to=收件人: ")
  54. if not defined subject (set/p "subject=主题<hello>: ")
  55. if not defined content (set/p "content=内容: ")
  56. if not defined accessories (set/p "accessories=附件: ")
  58. :start
  59. echo helo vkill >test
  60. echo AUTH LOGIN >>test
  61. set /p"=%user%"<nul|base64>"!t_!"
  62. set /p v=<"!t_!"
  63. >>test echo !v!
  64. set /p"=%pass%"<nul|base64>"!t_!"
  65. set /p v=<"!t_!"
  66. >>test echo !v!
  67. del /f /q !t_!
  68. echo quit>>test
  69. call :发信程序 test
  70. cls
  71. for /f "tokens=1-2 delims=:" %%a in ('findstr /N . p-163ms.log') do (set "%%a=%%b")
  72. echo !5!|findstr "^235" >nul 2>nul ||(echo 登陆不成功)
  73. if errorlevel 1 goto :del_
  74. if exist post del /f /q post
  75. for /f "delims=" %%a in (test) do if not "%%a"=="quit" echo %%a >>post
  76. del /f /q test
  77. >>post echo mail from: ^<%user%@%server%^>
  78. >>post echo rcpt to: ^<%to%^>
  79. >>post echo data
  80. >>post echo From: %user%@%server%
  81. >>post echo To: %to%
  82. >>post echo Subject: %subject%
  83. >>post echo X-mailer: p-163ms 2.0 [cn]
  84. >>post echo Mime-Version: 1.0
  85. >>post echo Content-Type: multipart/mixed;
  86. >>post echo boundary="=====vkill====="
  87. >>post echo.
  88. if defined content (
  89. >>post echo --=====vkill=====
  90. >>post echo Content-Type: text/plain;
  91. >>post echo charset="gb2312"
  92. >>post echo Content-Transfer-Encoding: 7bit
  93. >>post echo.
  94. dir !content! >nul 2>nul &&(type "!content!">>post) ||(>>post echo !content!)
  95. )
  96. echo 压缩编码文件中...
  97. if defined accessories for %%? in (%accessories%) do (call :压缩编码附件 "%%?")
  98. echo 给%to%发信中...
  99. call :发信程序 post
  100. cls
  101. for /f "tokens=1-2 delims=:" %%a in ('findstr /N . p-163ms.log') do (set "%%a=%%b")
  102. if not defined 10 echo.
  103. echo !9!|findstr "^250" >nul 2>nul ||echo.
  104. cls
  105. if errorlevel 1 echo 发信不成功 & goto del_
  106. call :del_
  107. echo 全部信件发送完毕
  108. ping -n 3 127.1>nul 2>nul
  109. goto :eof
  110. :del_
  111. del /f /q test >nul 2>nul
  112. del /f /q post >nul 2>nul
  113. del /f /q p-163ms.log>nul 2>nul
  114. goto :eof
  115. :发信程序
  116. for /f "tokens=2 delims=[]" %%? in ('ping -n 1 smtp.163.com ^|findstr /i "^Ping"') do (set "ip=%%?")
  117. nc -nvv !ip! %port%<%1>p-163ms.log
  118. goto :eof
  119. :压缩编码附件
  120. dir %~1 >nul 2>nul &&(call :压缩文件 "%~1" "rar.exe -r")||(call :压缩文件 "%~1" rar.exe)
  121. call :判断文件大小 "%~n1_.rar"
  122. >>post echo --=====vkill=====
  123. >>post echo Content-Type: application/octet-stream;
  124. >>post echo name="%~n1_.rar"
  125. >>post echo Content-Transfer-Encoding: base64
  126. >>post echo Content-Disposition: attachment;
  127. >>post echo filename="%~n1_.rar"
  128. >>post echo.
  129. base64.exe -i "%~n1_.rar">>post
  130. >>post echo.
  131. del /f/q "%~n1_.rar" >nul 2>nul
  132. >>post echo --=====vkill=====--
  133. >>post echo .
  134. >>post echo quit
  135. goto :eof
  136. :压缩文件
  137. %~2 a "%~n1_.rar" "%~1" >nul 2>nul||(echo 压缩文件错误)
  138. goto :eof
  139. :判断文件大小
  140. set/a z+=%~z1
  141. ::判断附件大小
  142. if not !z! lss %最大附件大小% (echo 附件大小超出)
  143. goto :eof
  144. :help
  145. if "%1"=="vkill" goto :eof
  146. echo ____help________________________________________________________________________
  147. echo.
  148. echo p-163ms v2.0 by:vkill
  149. echo Copyright (C) 2006-2008 www.vkill.net
  150. echo.
  151. echo Usage: p-163ms.cmd [/x] /u 用户名 /p 密码 /t 收件人 /s 主题 [/c 内容] [/a 附件]
  152. echo.
  153. echo /x 交互模式,当使用此参数时别的参数全部无效
  154. echo /t 收件人:(多收件人中间用,隔开;多附件时用""引住)
  155. echo /c 内容:(文字/写好内容的文本文件路径)
  156. echo /a 附件:(绝对路径/相对路径,多附件中间用,隔开;多附件时用""引住)
  157. echo.
  158. echo 示例:
  159. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com" /s hello
  160. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com" /s hello /c 123 /a "d:\00.txt"
  161. echo p-163ms.cmd /u 123 /p abc /t "122755990@qq.com,yx127@yx127.com" /s hello /c 123 /a "d:\00.txt,c:\00.bat"
  162. echo.
  163. echo ________________________________________________________________________________
  164. goto :eof
  165. :iget.vbs_
  166. >iget.vbs echo x=LCase(WScript.Arguments(1))
  167. >>iget.vbs echo y=LCase(WScript.Arguments(0))
  168. >>iget.vbs echo Set xPost=CreateObject("Microsoft.XMLHTTP")
  169. >>iget.vbs echo xPost.Open "GET",y,0
  170. >>iget.vbs echo xPost.Send()
  171. >>iget.vbs echo Set sGet=CreateObject("ADODB.Stream")
  172. >>iget.vbs echo sGet.Mode=3
  173. >>iget.vbs echo sGet.Type=1
  174. >>iget.vbs echo sGet.Open()
  175. >>iget.vbs echo sGet.Write(xPost.responseBody)
  176. >>iget.vbs echo sGet.SaveToFile x,2
  177. goto :eof
BJSH发表于： 2007-04-25 14:59


2007-4-26 04:12
查看资料  发送邮件  发短消息  网志   编辑帖子
vkill
金牌会员





积分 4103
发帖 1744
注册 2006-1-20
来自 甘肃.临泽
状态 离线
『第 21 楼』:  

bjsh 兄 我用copy + + 完全是为了多方发送，因为多方发送的时候只是修改了rcpt to: ，其他的完全没有变，我用copy ++ 你发信的时候试试 start nc -nvv ...看看那样更快，呵呵 19楼的解释太精彩了，佩服 在:交互模式中 if not defined user (set/p=用户名:<nul&set/p "user= ") 完全可以简写为:if not defined user (set/p "user=用户名: ") 依次类推 我刚刚试了set/p "user=用户名: " 和set/p=用户名:<nul&set/p "user= "一样，谢谢兄指点


2007-4-26 07:41
查看资料  发送邮件  访问主页  发短消息  网志   编辑帖子
vkill
金牌会员





积分 4103
发帖 1744
注册 2006-1-20
来自 甘肃.临泽
状态 离线
『第 22 楼』:  

还有看来bjsh 兄这么有意研究这个，再说说吧！ >>post echo mail from: ^<%user%@%server%^> >>post echo rcpt to: ^<%to%^> mail from:可以把这去掉，也可以写别的邮箱，应该也可以写文字之类的，类似匿名，哈哈 rcpt to: 可以把这去掉，这样别人就看不到你同时都给谁发了，我相信到mail.163.com是做不到这样的


2007-4-26 07:44
查看资料  发送邮件  访问主页  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 23 楼』:  

bjsh 兄 我用copy + + 完全是为了多方发送，因为多方发送的时候只是修改了rcpt to: ，其他的完全没有变，我用copy ++ 你发信的时候试试 start nc -nvv ...看看那样更快，呵呵
原来如此啊!还真没想到多方发送;确实


2007-4-26 07:44
查看资料  发送邮件  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 24 楼』:  

我还想把他做成校内通用的; 可惜想了半天也没明白学校的邮件服务器用的是什么; 看了看似乎是80; 至于smtp完全是模仿你的; 至于含义真的是不懂; 有空真得去学学网络协议了; 如果vkill兄不嫌我郁闷; 帮我搞定学校内的邮件发送;真是感激不尽了;


2007-4-26 07:48
查看资料  发送邮件  发短消息  网志   编辑帖子
vkill
金牌会员





积分 4103
发帖 1744
注册 2006-1-20
来自 甘肃.临泽
状态 离线
『第 25 楼』:  

后面的完全就是mime了，blog.yx127.com/?action=show&am ...，这里讲的很详细 学校的那个你 telnet 上去看看，例子: telnet 192.168.0.1 25 help 看看出来什么 [ Last edited by vkill on 2007-4-26 at 07:52 AM ]


2007-4-26 07:51
查看资料  发送邮件  访问主页  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 26 楼』:  

25端口不开的; 问了学校的一些人 说smtp和pop3都不开放的;


2007-4-26 08:00
查看资料  发送邮件  发短消息  网志   编辑帖子
vkill
金牌会员





积分 4103
发帖 1744
注册 2006-1-20
来自 甘肃.临泽
状态 离线
『第 27 楼』:  

bjsh 兄 可否有意一起写那？我想写为 p-mailsend ,支持更多的邮箱，最起码我想支持现在几个大站的，163 yahoo qq hotmail gmail 56 sina sohu 21cn == Usage: p-163ms.cmd [/x] /u 用户名@服务器 /p 密码 /t 收件人 /s 主题 [/c 内容] [/a 附件]


2007-4-26 08:01
查看资料  发送邮件  访问主页  发短消息  网志   编辑帖子
vkill
金牌会员





积分 4103
发帖 1744
注册 2006-1-20
来自 甘肃.临泽
状态 离线
『第 28 楼』:  

Originally posted by bjsh at 2007-4-26 08:00: 25端口不开的; 问了学校的一些人 说smtp和pop3都不开放的;
这个不开放那用telnet就没有办法了，用foxmail OE ==也不可以，只有通过网页形式发了，你可以用vbs写个登陆邮箱发邮件的，呵呵，量体财衣了


2007-4-26 08:03
查看资料  发送邮件  访问主页  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 29 楼』:  

他的端口只有这些 80(HTTP) 21(FTP Control) 3306(MYSQL) 22(SSH) 389(LDAP) 确实得用vbs了; 五一写


2007-4-26 08:14
查看资料  发送邮件  发短消息  网志   编辑帖子
bjsh
银牌会员





积分 2000
发帖 621
注册 2007-1-1
状态 离线
『第 30 楼』:  

Originally posted by vkill at 2007-4-25 07:01 PM: bjsh 兄 可否有意一起写那？我想写为 p-mailsend ,支持更多的邮箱，最起码我想支持现在几个大站的，163 yahoo qq hotmail gmail 56 sina sohu 21cn == Usage: p-163m ...
好啊! 这样就可以和兄学习到好东西了;呵呵


2007-4-26 08:15
查看资料  发送邮件  发短消息  网志   编辑帖子
<   <<   [1] [2] [3] [4] [5] [6] [7] [8] [9]  >>   >
请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。


可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题



论坛跳转:  



[ 联系联盟系统管理团队 - 中国DOS联盟 ]

Sponsored by ifanr Inc | © 2001-2023