中国DOS联盟

Wait for you all experts to solve it, and then I'll learn slowly. I'm too bad at CMD batch processing, just started learning.

@echo off

set num=0

for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set /a num+=1

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo 第 !num! 行： !str:*:=!

    endlocal

)

pause

Originally posted by lxmxn at 2006-12-12 00:50:

　　There is another problem. If there are blank lines (just pressing Enter) in a.txt, then an error will occur, and the batch file prompts:
　　The maximum setlocal recursion level has been reached.
　　I don't know how to solve this problem?

　　Actually, it is not caused by blank lines, but by the number of lines exceeding the limit of setlocal. According to testing, when setlocal is used nestedly, a single setlocal statement can handle at most 15 lines of content. If it exceeds 15 lines, the maximum recursion level will be exceeded. The solution is to add the statement endlocal to terminate the environment variable localization at an appropriate position.

　　Inspired by brother 3742668's code in 12F, based on the code in 11F, the following code is obtained. The following code can be fully compatible with exclamation marks, connection symbols, redirection symbols, semicolons at the beginning of lines, colons at the beginning of lines, solves the problem of setlocal recursion level, and can count blank lines (previous codes all ignored blank lines):

@echo off

set num=0

for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set /a num+=1

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo Line !num!: !str:*:=!

    endlocal

)

pause

Last edited by namejm on 2006-12-12 at 09:50 AM ]

Brother namejm, after I tried it, I found that the first 30 lines are okay, and errors start from line 31:
Line!num!:!str:*:=!
Maximum setlocal recursion level reached.

After removing the redundant setlocal statements, the problem of the maximum recursion level no longer occurs. The 17F code has been corrected, please test again.

Hehe! Indeed beautiful!
I have benefited a lot from brother namejm!
I will give you points when my cooling-off period is over! ^_^

Great, learning.
Hehe
Always gain something every time I come

@echo off

(for /f "delims=" %%i in ('more ^< "%~f1" ^| findstr /n .*') do (

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo;!str:*:=!

    endlocal

))>test.out

fc "%~f1" test.out

pause

Still can't handle Unicode text. Adding more before findstr can solve it.
A little modification was made in order to redirect to a file.
Still has problems: The original file is Unicode, and the target is still ANSI, so fc will definitely not pass.

@echo off

(for /f "delims=" %%i in ('more ^< "%~f1" ^| findstr /n .*') do (

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo;!str:*:=!

    endlocal

))>test.out

fc "%~f1" test.out

pause

Last edited by qzwqzw on 2006-12-13 at 10:28 AM ]

　　I don't know if the person upstairs tested your code? It seems there is a problem.

@echo off

if "%1"=="" %0 "%~f0"

(for /f "delims=" %%i in ('more ^< %1 ^| findstr /n .*') do (

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo;!str:*:=!

    endlocal

))>test.tmp

type test.tmp

echo ---------

more < %1 > %1.tmp

fc %1.tmp test.tmp

pause

Just a test code, it's normal to have issues.

But in the future, when reporting issues, please state what the issue is and under what circumstances it occurs.

Naturally, I didn't encounter any unexpected issues before I sent out the code.

I made a slight change to the above code to make it convenient for myself and others to test.

By the way, it solved the issue with fc and unicode.

@echo off

if "%1"=="" %0 "%~f0"

(for /f "delims=" %%i in ('more ^< %1 ^| findstr /n .*') do (

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo;!str:*:=!

    endlocal

))>test.tmp

type test.tmp

echo ---------

more < %1 > %1.tmp

fc %1.tmp test.tmp

pause

Last edited by qzwqzw on 2006-12-13 at 12:06 PM ]

Whether running directly by double-clicking, or dragging and dropping files to run, or running in the command line, all report errors, prompting that "and" should not be here at this time.

This is obviously related to the test text, please post it and have a look.

　　Tested for a long time and found the problem.

　　At the beginning, double-clicking directly will show the error prompt "There should be no and at this time". After carefully analyzing the brother's code, I found that there is a section of "if "%1"=="" %0 "%~f0"" at the beginning of the brother's code. The extended function of this %~f0 is that the first parameter becomes the full path, but my batch files are all tested in "C:\Documents and Settings\Administrator\Desktop\Files\Temp", so the first parameter becomes "C:\Documents" instead of "C:\Documents and Settings\Administrator\Desktop\Files\Temp\test.bat", which eventually leads to the error message. And dragging and dropping files directly will also show similar error prompts.

　　So when testing the above code in a path with spaces, it is easy to report an error. It is recommended to add a statement to handle the path with spaces in front of the code. I changed %~f0 to %~s0, and the problem was solved.

　　There is also a small problem, that is, it does not support file dragging and dropping well. I don't know if it's my problem or the code's problem.

The errors during drag-and-drop are the same. Also, there are issues during double-clicking. Only when specifying a relative path with parameters in the command line is it correct, all because of the problem of spaces in the path.

Another problem is that when double-clicking, it calls itself, and after returning, it doesn't exit.

Modified code from post 24:

1. @echo off
   
2. if "%~1"=="" (
   
3. %0 "%~f0"
   
4. goto :eof
   
5. )
   
6. (for /f "usebackq delims=" %%i in (`more ^< %1 ^| findstr /n .*`) do (
   
7. set "str=%%i"
   
8. setlocal enabledelayedexpansion
   
9. echo;!str:*:=!
   
10. endlocal
    
11. ))>"%~dp1test.tmp"
    
12. type "%~dp1test.tmp"
    
13. echo ------------------
    
14. more < "%~1" > "%~1.tmp"
    
15. fc "%~1.tmp" "%~dp1test.tmp"
    
16. pause
    

hxuan?表ｰ： 2006-12-13 18:28

There are no problems with drag-and-drop, double-clicking, and command line.

Last edited by hxuan999 on 2006-12-13 at 07:27 PM ]

@echo off

setlocal disabledelayedexpansion

set num=0

for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set /a num+=1

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo 第 !num! 行： !str:*:=!

    endlocal

)

pause

Also, it's best to add a line: setlocal disabledelayedexpansion in the code on floor 17. As follows:

@echo off

setlocal disabledelayedexpansion

set num=0

for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set /a num+=1

    set "str=%%i"

    setlocal enabledelayedexpansion

    echo Line !num!: !str:*:=!

    endlocal

)

pause

This can prevent the situation where the DelayedExpansion key value has been modified in the registry. (I was like this myself, ^&^, so I couldn't see the exclamation marks all the time, and it took me half a day to test it before I remembered.)

Last edited by hxuan999 on 2006-12-13 at 07:33 PM ]

Thank you, brother upstairs!

goto :eof is unnecessary, and there will be no return after %0 "%~f0"

usebackq can be omitted, and it's better to do so because it brings more hidden risks

The problem in the original code belongs to the path parameter handling issue, and the words of the upstairs are taken back

Because I always test under d:\test, and rarely pay attention to these issues, and get a lesson