中国DOS联盟

文本中的内容是：

2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100

输入5个数字，如52559，则计算第5位+第(5+2)位+第(5+2+5)位+第(5+2+5+5)位+第(5+2+5+5+9)位的结果

2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100

Last edited by tireless on 2008-1-7 at 04:34 AM ]

试试这个：
（修正数据超出范围出错）

@echo off

set "Test=2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100"



set/p input=input:



call :loop _ %Test%

echo -----

echo =%sss%

pause

exit



:loop

  set n=0

:shiftloop

  if "%1" == "" goto :eof

  set/a n+=1

  if %n% leq %input:~0,1% shift&&goto shiftloop

  set/a sss=%sss%+%1

  echo +%1

  set "input=%input:~1%"

  if not "%input%" == "" goto loop

goto :eof

Last edited by zh159 on 2008-1-7 at 01:37 AM ]

echo off
set /p data_sum=data_sum number :
awk -v fn=%data_sum% "{for(i=1;i<=length(fn);i++){sum+=substr(fn,i,1)};if(sum<=NF){for

(i=1;i<=length(fn);i++){total+=$(fsum+=substr(fn,i,1))}} else {print \"warning:超过字段数，

注意！\"}};END{print total}" 1.txt
pause

@echo off
set/p input=input:
set "Test=2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100"
:loop
set/a n=%input:~0,1%
set "input=%input:~1%"
for /f "tokens=%n%*" %%a in ("%Test%") do set/a sss+=%%a&&if not "%input%" =="" set test=%%b && goto loop
echo %sss%
pause

刚发现 最后一个取不了 改过

Last edited by terse on 2008-1-7 at 01:38 AM ]

Originally posted by terse at 2008-1-7 00:58:
@echo off
set/p input=input:
set "Test=2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100"
:loop
set/a n=%input:~0,1%
set "input=%input:~1%"
for /f "tokens=%n%*" %%a in ("%Test%") do set/a sss+=%%a&&if not "%input%" =="" set test=%%b && goto loop
echo %sss%
pause

刚发现 最后一个取不了 改过

测试发现tokens=n单个最大只能达到31

Last edited by zh159 on 2008-1-7 at 01:54 AM ]

谢谢楼上几位！2楼和4楼的都可用。

再要求个小小的更改：
1.显示出结果后，按任意键回到"input"而不是退出
2.可否把结果用英文显示，每个数字空格分开。
如结果为302，则显示为three zero two

(汗，昨晚不小心碰了下插头重启后就不能联网，直到刚才狠心把杀软卸载了，竟神奇地可以上网了。。。）

@echo off

setlocal EnableDelayedExpansion

set/p input=input:

set "Test=2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100"

:loop

set/a n=%input:~0,1%

set "input=%input:~1%"

for /f "tokens=%n%*" %%a in ("%Test%") do set/a sss+=%%a && echo +%%a && if not "%input%" =="" set test=%%b && goto loop 

echo ------

echo =%sss%



:Eloop

set n=-1

for %%n in (zero one two three four five six seven eight nine ten) do (

  set/a n+=1

  if !n! == %sss:~0,1% (

    set sss=%sss:~1%

    set sssE=%sssE% %%n

  )

)

if not "%sss%" == "" goto Eloop



echo =%sssE:~1%

pause

不能按任意键返回input:吗？另外只显示英文结果就可以了。谢谢

Originally posted by zh159 at 2008-1-7 01:39:

测试发现tokens=n单个最大只能达到31

Last edited by zh159 on 2008-1-7 at 01:54 AM ]

现在最大应该达不到31 最大9
改一下zh159兄的

@echo off
:start
set sssE=
set sss=
set/p input=input:
set "Test=2 0 50000 50 0 20 4 1000 0 10 30 0 500 0 100 50000 2 0 1000 50 0 2 0 10 500 30 0 2 70 0 1000 100"
:loop
set/a n=%input:~0,1%
set "input=%input:~1%"
for /f "tokens=%n%*" %%a in ("%Test%") do set/a sss+=%%a&& if not "%input%" =="" set test=%%b && goto loop
if %sss% equ 10 echo ten&&goto start
:Eloop
set/a n=%sss:~0,1%+1
set sss=%sss:~1%
for /f "tokens=%n%" %%a in ("zero one two three four five six seven eight nine") do set ssse=%ssse% %%a&&if not "%sss%" == "" goto Eloop
echo %ssse:~1%
goto start

Last edited by terse on 2008-1-7 at 01:27 PM ]

多谢！达到了我想要的

Last edited by tireless on 2008-1-7 at 02:48 AM ]

for /l %%i in (1,1,45) do call set "aaa=%%aaa%%%%i "

set /p in=input:

set /a 1/(in/10000),1/(100000/in)||goto :eof

set /a in1=%in:~0,1%,in2=in1+%in:~1,1%,in3=in2+%in:~2,1%,in4=in3+%in:~3,1%,in5=in4+%in:~4,1%

for %%i in (%aaa%) do set /a num+=1,1/^(num-in1^),1/^(num-in2^),1/^(num-in3^),1/^(num-in4^),1/^(num-in5^)||call set "output=%%output%%%%i "&&set /a out+=%%i

echo %out%=%output%

pause

这个能解决长度的问题吧

什么长度问题？

我输入的5个数相加最大就是32的

for /f取值达不到45位，你五位数最大是45位呀

额。反正不必担心这5个数相加会大于32，我输入的5个数相加都是在32以内的

这样：如果5个数相加大于32就返回到input:

伤心了我就