中国DOS联盟

从原来来路径的文件列表中随机选取几个成一个新列表
例如:\gequ\angela06-01.wma
D:\gequ\yinxingdcb.wma
D:\gequ\rgaxq.mp3
D:\gequ\316515760.mp3
D:\gequ\tl.mp3
D:\gequ\OIkRHUbe.mp3
D:\gequ\bengpao.mp3
D:\gequ\20061017151241308.mp3
D:\gequ\love.mp3
D:\gequ\qiutian.mp3
D:\gequ\28.mp3
我要从中随机选取3个到新列表

原来我想从数序中随机选取几个数字,然后给数字赋值,可是我却不能用来替换数傎
@echo off
set 1=D:\gequ\zuichudemengxiang.mp3
echo %1%>>1.txt
pause

请问如何解决?

N久前就有讨论过
http://www.cn-dos.net/forum/viewthread.php?tid=22128

这是我的一段

@echo off

for /f "delims=" %%i in ('dir/a-d/b *.mp3') do call set $%%random%%$%%i=$

for /f "tokens=1,2* delims=$=" %%i in ('set $') do echo %%j

pause

昨天晚上我翻了以前的帖子,以前的只是随机生成一个播放列表,达到随机播放的目的,而我的要求只随机选取部分到新列表,再有,我这得加上路径

根据这个改一下

@echo off

for /f "delims=" %%i in ('dir/a-d/b *.mp3') do (

  set /a n+=1

  call set list%%n%%=%%i

)

echo 1 to %n%

set /p m=

call echo %%list%m%%%

pause

Last edited by zh159 on 2007-11-7 at 11:42 AM ]

我的思路是通过数字生成随机数五个
@echo off
:start
cls
set Num=
set Tmp$=

:loop
set /a randomloop=%random%%%99+1
for %%n in (%Tmp$%) do if "%randomloop%" == "%%n" goto loop
call set Tmp$=%%Tmp$%% %randomloop%
set /a Num+=1
set random_%Num%=%randomloop%
if %Num% LSS 5 goto loop

for /l %%n in (1,1,%Num%) do call set /p= %%random_%%n%%<nul
echo.>>A.txt
pause
goto start
exit

我再定义每个带路径的文件名为1~99如何把A.txt中随机生机的5个数字替换成我事先定义的带路径的文件名呢?

例如我定义 1=D:\gequ\zuichudemengxiang.mp3
2=D:\gequ\school.mp3
3=D:\gequ\lige.wma
4=D:\gequ\angela06-01.wma
5=D:\gequ\yinxingdcb.wma
6=D:\gequ\rgaxq.mp3
7=D:\gequ\316515760.mp3
8=D:\gequ\tl.mp3
......
再通过随机生成的5 7 9 8 1 换成相应的带路径的文件名
请高手指教

@echo off

for /f "delims=" %%i in ('dir/a-d/b *.mp3') do (

  set /a n+=1

  call set list%%n%%=%%i

)



:loop

set /a randomloop=%random% %% %n%+1

for %%n in (%Tmp$%) do if "%randomloop%" == "%%n" goto loop

call set Tmp$=%%Tmp$%% %randomloop%

set /a Num+=1

call echo %%list%randomloop%%%

if %Num% LSS 5 goto loop



pause

参考楼上的我也写了个

@echo off

>x.txt (for /f "tokens=1*" %%a in ('^(for /f "tokens=1* delims=:" %%i in ^('findstr /n . list.txt'^) do @call set/a list^=%%random%%%%%%i^>nul^&call echo %%list%% %%j^)^|sort /r') do (set/ax+=1,y=3/x,z=1/y 2>nul&&echo %%b||goto end))



:end

pause

谢谢大家的帮助,7楼的测试之后好像会有重复的毛病

测试了一下 的确有点小毛病的