中国DOS联盟

@set dbg=

@echo %dbg% off&setlocal enabledelayedexpansion

:: code by qasa copyright@qknet 2:16 2007-1-19

title 全自动设置机号、IP工具  作者:qasa

set no_=0

mode con cols=40 lines=10&color fc

for /f "tokens=12 delims= " %%i in ('ipconfig /all^|find /i "Physical Address"') do (

   set mac=%%i

   set mac=!mac:~0,-1!

   )

for /f "tokens=1-3 delims==|" %%j in (MAC.INI) do (

   set mac_=%%j

   set ip_=%%k

   set sm_=%%l

   if !mac! equ !mac_! (

      call :set_ !mac_! !ip_! !sm_!  

      set /a no_+=1

      )   

   )

 if "!no_!"=="0" (

   echo.&echo MAC.ini中没有此机的MAC地址，将发送到工作机上......

       echo %date% %time%新发现的MAC地址：>>NewMAC.ini&echo !mac! >>NewMAC.ini

   echo.&echo 已经发送到工作机! ! !

   )

start shutdown -r -t 40

echo.

set/p zz_=         按Q键退出关机状态:

if /i !zz_! equ q (start shutdown -a)

ping/n 5 127.1>nul

exit /b



:set_

echo %1 %2 %3

set yy_=%3

echo.&echo 正在为%yy_:~1,3%号设置IP、机号...... 请稍候

for /f "tokens=1-4 delims==|" %%e in (DNS.ini) do (

    set dns1_=%%e

    set dns2_=%%f

    set workgate_=%%g

    set zwym_=%%h

    )

for /l %%w in (1,1,2) do (

  netsh interface IP Set Address "本地连接" Static %2 %zwym_% %workgate_% 1 >nul

  )

netsh interface IP Set Dns "本地连接" static %dns1_% >nul

netsh interface ip add dns "本地连接"  %dns2_% >nul

REG ADD HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ActiveComputerName /v "ComputerName" /t REG_SZ /d %3 /f >nul 2>NUL

REG ADD HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v "ComputerName" /t REG_SZ /d %3 /f >nul 2>NUL

REG ADD HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "Hostname"    /t REG_SZ /d %3 /f >nul 2>NUL

REG ADD HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d %3 /f >nul 2>NUL

echo.&echo                设置完毕

goto :eof

00-0A-EB-21-A7-EC=192.168.0.5|-005

00-E0-4C-8F-11-4A=192.168.0.6|-006

00-0A-EB-A0-1D-9A=192.168.0.7|-007

00-40-05-14-E7-C9=192.168.0.8|-008

00-0A-EB-A0-1C-7A=192.168.0.9|-009

00-0D-87-F2-03-50=192.168.0.10|-010

00-0D-87-F2-A3-5C=192.168.0.11|-011

202.96.128.86=202.96.128.186|192.168.0.1|255.255.255.0

Originally posted by qasa at 2007-1-19 04:51 AM:
在测试的时候有个奇怪的地方就是
for /l %%w in (1,1,2) do (
netsh interface IP Set Address "本地连接" Static %2 %zwym_% %workgate_% 1 >nul
)
如果我不循环 ...

Originally posted by everest79 at 2007-1-20 13:43:
还有楼主为什么不将dns.ini与mac.ini跟批处理放在一起呢，三个文件乱了点

::D=202.96.128.86=202.96.128.186|192.168.0.1|255.255.255.0
::M=00-0A-EB-21-A7-EC=192.168.0.5|-005 ...