中国DOS联盟

虹鳟鱼:



最低价:       青岛城阳                   34.00  

最高价:       闽福鼎农贸                 80.00



活鳜鱼:

      

最低价:       北京新发地                 24.00  

最高价:       北京八里桥                 26.00 

虹鳟鱼:



最低价:       闽福鼎农贸                 80.00  

最高价:       闽福鼎农贸                 80.00



活鳜鱼:

      

最低价:       北京新发地                 26.00  

最高价:       北京八里桥                 26.00 

@echo off

setlocal enabledelayedexpansion



for /f "tokens=1,2,3" %%i in (a.txt) do (

     if not defined %%j (

        set a=

        set %%j=A

        set/a b+=1

        set str!b!=%%j)

     set/a a+=1

     set MP_%%j!a!=%%i=%%k

)

for /l %%i in (1 1 %b%) do (

    set Hprice=

    for /f "tokens=2,3 delims==" %%a in ('set MP_!str%%i!') do (

         set tmp=%%b

         set tmp=!tmp:.=!

         if not defined Hprice (

             set/a Hprice=!tmp! & set/a Lprice=!tmp!

             set Hmarcket=%%a & set Lmarcket=%%a

             ) else (

             if !tmp! GEQ !Hprice! set/a Hprice=!tmp! & set Hmarcket=%%a

             if !tmp! LEQ !Lprice! set/a Lprice=!tmp! & set Lmarcket=%%a)

      )

      echo !str%%i!：

      echo.

      echo 最高价：   !Hmarcket!      !Hprice:~0,-2!.!Hprice:~-2!

      echo 最低价：   !Lmarcket!      !Lprice:~0,-2!.!Lprice:~-2!

      echo.

)

pause>nul

@echo off

:: 当最高价和最低价相同时，产地将指向同一个地方，而不管同样的价格有几个产地

:: 并且这个产地在表中位于这类产品的最后

set max=1

set min=50000

setlocal enabledelayedexpansion

for /f "tokens=1-3" %%i in (a.txt) do (

    set class1=!class2!

    set class2=%%j&set price=%%k

    set price=!price:.=!

    if defined class1 if not "!class1!"=="!class2!" (

        call :echo_

        set max=1

        set min=50000

    )

    if !price! geq !max! set max=!price!&set addr_max=%%i

    if !price! leq !min! set min=!price!&set addr_min=%%i

)

call ::echo_

pause

goto :eof



:echo_

echo !class1!:

echo.

echo   最低价:  !addr_min!    !min:~0,-2!.!min:~-2!

echo   最高价:  !addr_max!    !max:~0,-2!.!max:~-2!

echo.

goto :eof

Originally posted by youxi01 at 2007-1-9 19:00:
斑竹就是斑竹，看了你的代码真是惭愧啊。我开始的时候还去定义鱼的种类，真是多此一举啊！
还有一个问题就是，我修改之后怎么我的帖子怎么成了2F了，原来是3F的哦！

Originally posted by namejm at 2007-1-10 08:04 AM:

　　我的代码存在一点瑕疵，具体看我代码里的说明。另外，你的代码有点问题，不知道你仔细查看了运行后的结果了没有。:P

　　呵呵，因为我 ...

@echo off



set num=0

md tmp 2>nul

setlocal enabledelayedexpansion



:: 按水产品类别建立临时文件

for /f "tokens=1-3" %%i in (a.txt) do (

    set class1=!class2!

    set class2=%%j

    set price=%%k

    if not defined class1 set /a num+=1&cd.>tmp\!num!.txt

    if defined class1 if not "!class1!"=="!class2!" (

        set /a num+=1&cd.>tmp\!num!.txt

        echo !price:.=!☆ %%i  %%j    %%k>>tmp\!num!.txt

    ) else echo !price:.=!☆ %%i  %%j    %%k>>tmp\!num!.txt

)



set num=1



:loop

echo.



:: 获取最低价记录

set switch_sort=

set switch_class=

set switch_H_or_L=0

set price1=&set price2=

set H_or_L=最低价：

set str=

for /l %%i in (1,1,3) do (

    set str=!str!

    if !switch_H_or_L! equ 0 call :sort_ !str!

)



:: 获取最高价记录

set switch_sort=/r

set switch_H_or_L=0

set price1=&set price2=

set H_or_L=最高价：

set str=

for /l %%i in (1,1,3) do (

    set str=!str:*]=!

    if !switch_H_or_L! equ 0 call :sort_ !str!

)

echo ______________________________



set /a num+=1

if exist tmp\%num%.txt goto loop



endlocal

rd /q /s tmp

pause

goto :eof





:sort_

:: 按由高到低/由低到高排序

for /f "tokens=1-4" %%i in ('findstr "^%1☆" tmp\%num%.txt^|sort %switch_sort%') do (

    set price1=!price2!

    set price2=%%i

    if not defined switch_class echo %%k:&echo.&set switch_class=1

    if not defined price1 (echo %H_or_L% %%j %%l&set switch_H_or_L=1) else (

        if "!price1!"=="!price2!" (

            echo %H_or_L% %%j %%l

        ) else goto :eof

    )

)

goto :eof

::zh159@bbs.cn-dos.net 2007-1-11

@echo off

setlocal EnableDelayedExpansion

for /f "tokens=1-3" %%i in (a.txt) do set $%%i %%j %%k=$

for /f "tokens=1-2" %%i in (a.txt) do if not "%%j" == "!Type!" set Type=%%j&&call :Scan %%j

pause

exit



:Scan

set Min=1000000

set Max=0

for /f "tokens=1-3* delims==$ " %%i in ('set $^|find "%1"') do (

    set num=%%k&&set num=!num:.=!

  if !num! LEQ !Min! set Min=!num!

  if !num! GEQ !Max! set Max=!num!

)

echo %1:

echo.

for /f "tokens=1-3* delims==$ " %%i in ('set $^|find "%1"') do set num=%%k&&set num=!num:.=!&&if "!num!" == "!Min!" echo   最低价:  %%i	%%k

for /f "tokens=1-3* delims==$ " %%i in ('set $^|find "%1"') do set num=%%k&&set num=!num:.=!&&if "!num!" == "!Max!" echo   最高价:  %%i	%%k

echo.------------------------------

goto :eof

::zh159@bbs.cn-dos.net 2007-1-13

@echo off

title 水产最低价^&最高价  zh159@bbs.cn-dos.net  2007-1-13

setlocal EnableDelayedExpansion

for /f "tokens=1-3*" %%i in (a.txt) do set %%j.%%i.%%k=.

for /f "tokens=1-3*" %%i in (a.txt) do if not "%%j" == "!Type!" set Type=%%j&&call :Scan %%j

pause

exit



:Scan

set Min=M

set Max=0

for /f "tokens=1-4* delims==." %%i in ('set "%1"') do (

  if %%k%%l LEQ !Min! set Min=%%k%%l

  if %%k%%l GEQ !Max! set Max=%%k%%l

)

echo %1:

echo.

for /f "tokens=1-4* delims==." %%i in ('set "%1"') do if "%%k%%l" == "%Min%" echo   最低价:  %%j	%%k.%%l

for /f "tokens=1-4* delims==." %%i in ('set "%1"') do if "%%k%%l" == "%Max%" echo   最高价:  %%j	%%k.%%l

echo.------------------------------

goto :eof