中国DOS联盟

今天遇到个问题，用了很多方法都没解决。（VBS,C/C++...）。 情况是这样的。 有一个网页是txt的，（源码） 我想提取里面的几个连接，然后根据具体的连接内容返回不同的值。。 如： images\char\44.jpg 就返回A, images\char\45.jpg 则返回B。。。。

我先用 type wangye.txt | find "images\char\" >1.txt
得到的文件内容是：
<td bgcolor="#000000" align="left"> <img src="images/char/oo.gif" border=0 width="25" height="25">
<td bgcolor="#000000" align="left"> <img src="images/char/S.gif" border=0 width="25" height="25">
<td bgcolor="#000000" align="left"> <img src="images/char/cc.gif" border=0 width="25" height="25">
<td bgcolor="#000000" align="left"> <img src="images/char/V.gif" border=0 width="25" height="25">

其中都含有特征“images\char\” 这个代码， 我想根据images/char/后面的信息来判断。。也就是oo.gif , S.gif , cc.gif , V.gif 来返回不同的值，保持顺序不变，然后输出到一个文件中。。 请高手帮帮我～～。 谢谢

　　给一段提取 gif 名的批处理代码，至于究竟要返回什么值，请根据你自身的要求来做：

@echo off

for /f "tokens=3 delims=/." %%i in (1.txt) do echo %%i

pause

欣赏！简捷至极～：）

setlocal enabledelayedexpansion
for /f "tokens=9 delims=^<^>^=^/" %%i in (1.txt) do (
set gif=%%i
set gif=!gif:"=!
set gif=!gif: border=!
echo !gif!
)
pause

先谢谢各位的帮助了～～ （感动ing...）
我刚才根据上位各位的代码，自己修改了一下：
setlocal enabledelayedexpansion
for /f "tokens=9 delims=^<^>^=^/" %%i in (123.txt) do (
set n=%%i
set n=!n:"=!
set n=!n: border=!
set n=!n:oo.gif=o!
set n=!n:S.gif=S!
set n=!n:cc.gif=c!
set n=!n:V.gif=V!
echo !n!>>joeyjoey.txt
)
pause

替换内容成功， 但是输出的文件joeyjoey.txt的内容是这样的：
o
S
c
v
也就是说内容是竖起来的。 能不能把他们横过来那？ 就像C语言里不用“/n” 那样的

把　echo !n!>>joeyjoey.txt　这句改为下面指令，就可以输出内容到文件但不换行～：）

>>joeyjoey.txt set/p=!n!<nul

试了6楼朋友的方法，可是输出的是：
o set /p=o
S set /p=S
c set /p=c
V set /p=V
不知道为何

我试着你的代码，并用顶楼的那些html数据试验，输出如下内容：

oScV


下面代码没有问题，兄在试一下～：）

setlocal enabledelayedexpansion

for /f "tokens=9 delims=^<^>^=^/"  %%i in (123.txt) do  (

                                      set n=%%i

                                      set n=!n:"=!

                                      set n=!n: border=!

                                      set n=!n:oo.gif=o!

                                      set n=!n:S.gif=S!

                                      set n=!n:cc.gif=c!

                                      set n=!n:V.gif=V!

                                      >>joeyjoey.txt set/p=!n!<nul

)

pause

另：兄代码中关于for的语句可以参考２楼版主代码，２楼代码精炼～：）
namejm版主的　"tokens=3 delims=/."　这段指令非常简捷，也不会出错：）

C:\TEMP\t>for /f "tokens=3 delims=/." %i in (123.txt) do echo %i





下面是执行后的输出过程：

C:\TEMP\t>echo oo

oo



C:\TEMP\t>echo S

S



C:\TEMP\t>echo cc

cc



C:\TEMP\t>echo V

V

　　把提取到的 gif 文件名横向排列可以使用如下代码(兼容各种特殊字符的文件名)：

@echo off

for /f "tokens=3 delims=/." %%i in (1.txt) do call set "var=%%var%%%%i"

echo "%var%"

pause

非常感谢namejm版主和redtek兄弟的帮助， 我今后会努力学习的， 呵呵 还有你们两个真的很厉害～ 羡慕。。

精彩！redtek和namejm的代码很厉害，尤其namejm兄，非常简洁高效。