中国DOS联盟

如何查找一天内17：00－17：25创建的所有文件？
@echo off
set /p d=请输入完整的路径：
set /p strTime=请输入文件的创建时间:
for /f "tokens=3,*" %%i in ('dir /a-d/od/t:C "%d%"^|find ^"%strtime%^"') do (echo %%j>>d:\22.txt)
pause
这样的我会，查找一定时间范围内，我不会，有哪位能帮我改一下？

　　试试这个，每个输入都要标准，日期范例：2006-11-25，时间范例（二十四小时制的）：09:20、23:50

@echo off

set/p d_=请输入要查找的路径(默认当前文件夹):

set/p date_=请输入查询的文件的创建日期:

if not defined date_ goto error

set/p time1=输入起始时间：

if not defined time1 goto error

set/p time2=请输入结束时间:

if not defined time2 goto error

cls

echo 查找结果:&&echo;

for /f "skip=5 tokens=1,2,4*" %%a in ('dir /a-d/od/tc "%d_%" ^| find "%date_%"') do (

	if %%b geq %time1% if not %%b geq %time2% (

		echo %%c

	)

)

pause

goto :eof

:error

echo 输入错误

pause

[ Last edited by lxmxn on 2006-11-27 at 10:21 AM ]

我试了一下,查不到结果的,代码还应再改一下呀.

　　Re tianzizhi :

　　不会吧，我试了可以呀，除非你输入的日期或者时间的格式不对，或者在你指定的时间或者日期内没有任何文件。

[ Last edited by lxmxn on 2006-11-26 at 09:15 AM ]

谢谢各位了！

我的文件创建时间是：16：16：48，我把开始时间设为16：15，结束时间设为16：17。结果没有找到。但如果把开始时间设为16：14就能找到，是为什么？
我重新建立一个文件，结果时间怎么设，都能找到。然后，我又按照上面的时间设了一遍，结果找到了。
我认为dos有时也是不稳定的，就像操作系统一样，其实dos也是一种操作系统吧。不知道，这样的理解对不对
另外，我想在全盘比如，c或d盘，进行时间段的查找文件，应该怎么添加代码？

[ Last edited by anqing on 2006-11-26 at 10:20 AM ]

另外，如果我想在c盘内进行查找，这个p也是找不到

我想在全盘比如，c或d盘，进行时间段的查找文件，应该怎么添加代码？

等了一天了，怎么没有人回答？

wmic datafile where "InstallDate>'20061126200000.000000+480'  and drive='d:' and InstallDate<'20061126230000.000000+480'" get caption

上面是查找2006年11月26号20点到23点间D盘下创建的文件的例子，你可以自己指定盘符，目录等等其他过滤条件。
p.s:如果全盘搜索的话可能会运行太长时间而导致“没有响应”(文件数目较大时)。

谢谢版主，我想在上面的批处理中实现指定时间段，对整个盘符进行搜索

@echo off
set/p d_=请要查找的路径输入路径(默认当前文件夹):
set/p date_=请输入查询的文件的创建日期:
if not defined date_ goto error
set/p time1=输入起始时间：
if not defined time1 goto error
set/p time2=请输入结束时间:
if not defined time2 goto error
cls
echo 查找结果:&&echo;
for /f "skip=5 tokens=1,2,4*" %%a in ('dir /a-d/s/od/tc "%d_%" ^| find "%date_%"') do (
if %%b geq %time1% if not %%b geq %time2% (
echo %%c
)
)
pause
goto :eof
:error
echo 输入错误
pause
谁帮我改改，以达到能搜索整个盘符，和指定路径中创建的文件。

lxmxn..如果符合条件的文件中含有空格 echo %%c 只能显示一部分..应该用echo %%c %%d 吧.

@echo off
set /p d_=请输入要查找的路径(默认当前文件夹):
if not defined d_ (set d_=%cd%)
echo 已经设置查询路径为%d_%
set /p date_=请输入查询的文件的创建日期:
if not defined date_ (for /f %%a in ("%date%") do (set date_=%%a))
echo 已经设置查询创建日期为%date_%的文件。
set /p time1=输入起始时间：
if not defined time1 (set time1=00:00)
set /p time2=输入结束时间:
if not defined time2 (set time2=24:00)
cls

echo 查找结果: && echo.
for /f "tokens=1,2,3,4*" %%a in ('dir /a-d/s/od/tc "%d_%" ^| find "%date_%"') do (
if %%b geq %time1% (
if %%b leq %time2% (
echo %%d %%e
)
)
)

echo.
pause >nul

[ Last edited by zhoung0 on 2007-1-11 at 04:32 AM ]

anqing你好！
我的需求和你差不多，我是要把每天晚上九点和前一天晚上九点生成的文件找出来。
我是一个新新手，不知道该怎么编这个批处理程序，请您帮忙看一下

@echo off
setlocal enabledelayedexpansion
set /p time1=输入起始时间(格式HH:MM:SS):
set /p time2=输入结束时间(格式HH:MM:SS):

set StartTime=%date:~0,4%%date:~5,2%%date:~8,2%%time1:~0,2%%time1:~3,2%%time1:~6,2%
set EndtTime=%date:~0,4%%date:~5,2%%date:~8,2%%time2:~0,2%%time2:~3,2%%time2:~6,2%

wmic datafile where "InstallDate>'%StartTime%.000000+480' and drive='d:' and InstallDate<'%EndtTime%.000000+480'" get caption>Result.txt

这个貌似只查.dat文件啊怎么改全部?