Board logo

标题: [已结]读取指定标记行后的文本内容 [打印本页]
作者: uiopuiop     时间: 2009-6-12 07:00    标题: [已结]读取指定标记行后的文本内容

读取指定标记行后的文本内容？ 有个文本如下, 要读取最后一个 [append]
标记行后的内容。[append] 标记左右有可能有些TAB和空格。
findstr /n /c:"[append]" email_list.txt 倒是可以知道标记的行号。

email_list.txt

emailx@xxx4.com
emailad@xxx4.com

  [append]  

emailx@xxx3.com
emailx@xxx3.com
emailx@xxx3.com

  [append]      

emailx@222.com
emailx@222.com
emailx@222.com

～～～～～～～～～～～～～～～～
输出的新文件因该是：
emailx@222.com
emailx@222.com
emailx@222.com

[ Last edited by uiopuiop on 2009-6-12 at 10:26 ]
作者: ccwan     时间: 2009-6-12 07:32

@echo off
for /f "tokens=1 delims=:" %%i in ('findstr /n /c:"[append]" email_list.txt') do set/a num=%%i
more +%num% <email_list.txt
pause
作者: uiopuiop     时间: 2009-6-12 08:07    标题: 楼上强的，加分

我也刚写出的我自己的代码，但没你的精简。

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('findstr /n /i /c:"[append]" email_list.txt') do (
        set Mark_Str=%%j
        set Mark_Str=!Mark_Str: =!
        set Mark_Str=!Mark_Str:        =!
        if /i !Mark_Str!==[append] set Mark_LineNum=%%i
)

ECHO !Mark_Str! ___ %Mark_LineNum%


               
for /f "tokens=1* delims=:" %%1 in ('findstr /n .* email_list.txt') do (
        if defined Mark_LineNum if %%1 GTR !Mark_LineNum! echo.%%2<nul>>appended_email.txt
)

endlocal


～～～～～～～～～～～～～～～～～～～～～～～

有关MORE 我有个问题，如果列表很长的话，MORE会不会列出一部分？

另外，如果把结果输出到文件？ more +%num% <email_list.txt 为什么不行？

[ Last edited by uiopuiop on 2009-6-12 at 08:15 ]
作者: uiopuiop     时间: 2009-6-12 08:56
做了个实验，问题解决了。
如果列表很长，使用MORE 没问题。（email_list.txt 600多行）

more +10 <email_list.txt >test.log

并且可以输出到文件。前面自己搞错了。


整合了一下：
@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('findstr /n /i /c:"[append]" email_list.txt') do (
        set Mark_Str=%%j
        set Mark_Str=!Mark_Str: =!
        set Mark_Str=!Mark_Str:        =!
        if /i !Mark_Str!==[append] set Mark_LineNum=%%i
)

if defined Mark_LineNum more +!Mark_LineNum!<email_list.txt>test.log
endlocal
[ Last edited by uiopuiop on 2009-6-12 at 09:11 ]