标题: 【出题】输出设定范围内的字母 [打印本页]
作者: bat-zw 时间: 2009-2-28 07:48 标题: 【出题】输出设定范围内的字母
很久没在cn-dos发过贴了，真对不住大家，下面就先出道题给大家来练练手吧：
出题目的：
掌握将常量字符转划成数字变量的方法
掌握随机取值的方法
加分规则：
满分10分，视情形加分（以思路为重）
题目如下：
编写批处理代码，当使用者输入1－26（因为字母有26个）间的任意一个数后，程序在
26个字母中再随机生成一个不等于输入位序上字母的字母（a-z的位序为1－26），最后程序
将这两个字母中的所有字母在一行内列出，示例如下：
请输入1-26中的任意一个数值：3
c和p之间的字母是：defghijklmno
c和p之间的字母是：defghijklmno
作者: netbenton 时间: 2009-2-28 10:14 标题: 我来一个，抛砖引玉
@echo off
set "asc=abcdefghijklmnopqrstuvwxyz"
:lp
set /p in=请输入1-26中的任意一个数值：
echo.
if %in% gtr 26 echo.输入错误,请重新输入。&goto :lp
if %in% lss 1 echo.输入错误,请重新输入。&goto :lp
set/a in-=1
set/a ran=%random% %% 25
::随机数取少一个，大于或等于就加一，可去掉等于的可能
if %ran% geq %in% (set/a b=25-ran,ran+=1,a=in+1) else (set/a a=ran+1,b=26-in)
call echo.%%asc:~%in%,1%%和%%asc:~%ran%,1%%之间的字母是：%%asc:~%a%,-%b%%%
pause
作者: tireless 时间: 2009-3-1 01:08
@echo off
set /p b=请输入 1-26 中的任意一个数值:
:lp
set /a e=%random%%%26+1,1/(e-b) 2>nul || goto lp
if %e% lss %b% set /a b=%e%,e=%b%
set /a L=b-1,R=e-1,M=e-b-1
set Letters=abcdefghijklmnopqrstuvwxyz
call echo %%Letters:~%L%,1%% 和 %%Letters:~%R%,1%% 之间的字母是: %%Letters:~%b%,%M%%%
pause
set /p b=请输入 1-26 中的任意一个数值:
:lp
set /a e=%random%%%26+1,1/(e-b) 2>nul || goto lp
if %e% lss %b% set /a b=%e%,e=%b%
set /a L=b-1,R=e-1,M=e-b-1
set Letters=abcdefghijklmnopqrstuvwxyz
call echo %%Letters:~%L%,1%% 和 %%Letters:~%R%,1%% 之间的字母是: %%Letters:~%b%,%M%%%
pause
作者: bat-zw 时间: 2009-3-1 12:59
| Quote: | |
|
楼上的代码好精,但是不是没考虑到c d间无字母的情况?
作者: bat-zw 时间: 2009-3-1 13:03
| Quote: | |
|
存在楼上一样的问题
作者: netbenton 时间: 2009-3-1 13:49 标题: 增加一点
@echo off
set "asc=abcdefghijklmnopqrstuvwxyz"
:lp
set /p in=请输入1-26中的任意一个数值：
echo.
if %in% gtr 26 echo.输入错误,请重新输入。&goto :lp
if %in% lss 1 echo.输入错误,请重新输入。&goto :lp
set/a in-=1
set/a ran=%random% %% 25
::随机数取少一个，大于或等于就加一，可去掉等于的可能
if %ran% geq %in% (set/a a=in+1,ran+=1,b=ran-a) else (set/a a=ran+1,b=in-a)
if %b% equ 0 (set ech=没有字母) else (call set ech=的字母是：%%asc:~%a%,%b%%%)
call echo.%%asc:~%in%,1%%和%%asc:~%ran%,1%%之间%ech%
pause
作者: bat-zw 时间: 2009-3-1 16:05
给出本人的解：
@echo off
set "code=abcdefghijklmnopqrstuvwxyz"
set /p input=请输入1-26内的任意数值：
:lp
set /a _random=%random%%%26+1,a=_random-input
if "%a:-=%" lss "2" goto lp
if %_random% gtr %input% (
set /a a=input,b=27-_random,c=a-1,d=_random-1
) else (
set /a a=_random,b=27-input,c=a-1,d=input-1
)
call,set /p=%%code:~%c%,1%%和%%code:~%d%,1%%间的字母是：%%code:~%a%,-%b%%%<nul
pause>nul
[ Last edited by bat-zw on 2009-3-1 at 16:07 ]set "code=abcdefghijklmnopqrstuvwxyz"
set /p input=请输入1-26内的任意数值：
:lp
set /a _random=%random%%%26+1,a=_random-input
if "%a:-=%" lss "2" goto lp
if %_random% gtr %input% (
set /a a=input,b=27-_random,c=a-1,d=_random-1
) else (
set /a a=_random,b=27-input,c=a-1,d=input-1
)
call,set /p=%%code:~%c%,1%%和%%code:~%d%,1%%间的字母是：%%code:~%a%,-%b%%%<nul
pause>nul