标题: 求助:显示子目录下的前5个文件名再计算文件总数! [打印本页]
作者: ganjie 时间: 2009-2-11 08:57 标题: 求助:显示子目录下的前5个文件名再计算文件总数!
以下代码可以批量显示子目录下的前5个文件名！如现在当前目录下有两个子文件夹：psp、nds
@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do call:lp "%%a"
pause&goto :eof
:lp
for /f "delims=" %%j in ('dir /a-d /b "%~1\*.jpg" 2^<nul') do (
set/a n+=1
echo %%j
if !n! equ 5 set n=&goto :eof
)
但小弟现在想在显示完前5个文件名后再显示其文件总数，偶已经试过用同时使用两个call ，但均失败，求大虾们帮写个批处理代码，谢谢！
nds\001.jpg
nds\002.jpg
nds\003.jpg
nds\004.jpg
nds\005.jpg
nds文件个数为13
psp\A.jpg
psp\B.jpg
psp\C.jpg
psp\D.jpg
psp\E.jpg
psp文件个数为21
作者: netbenton 时间: 2009-2-11 12:52
@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do call:lp "%%a"
pause&goto :eof
:lp
for /f "delims=" %%j in ('dir /a-d /b "%~1\*.jpg" 2^<nul') do (
set/a n+=1
if !n! leq 5 echo %%j
)
echo !n!
作者: tireless 时间: 2009-2-11 13:20
@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do (
set "n="
for %%i in ("%%a\*.jpg") do (
set /a n+=1
if !n! leq 5 echo %%i
)
if defined n (echo "%%a" 文件个数为 !n!。& echo.)
)
pause
[ Last edited by tireless on 2009-2-11 at 13:39 ]setlocal enabledelayedexpansion
for /d %%a in (*) do (
set "n="
for %%i in ("%%a\*.jpg") do (
set /a n+=1
if !n! leq 5 echo %%i
)
if defined n (echo "%%a" 文件个数为 !n!。& echo.)
)
pause
作者: ganjie 时间: 2009-2-11 14:22
可不可以用两个call的形式，一个call显示前5个的，如上面的偶那个代码，一个call用来计算总数的？昨天我就是用了两个call的形式，可是却打印出了其它的内容，根本不是我想要的，是不是call不能这样用？
作者: alex9527 时间: 2009-2-11 16:30
应该是变量%%a不能传递到call的函数里。用set "forderName=%%a"就可以传参了。
@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do (
set "forderName=%%a"
set "n="
call :show5Files
call :showNum
)
goto :eof
:show5Files
for %%i in ("%forderName%\*.*") do (
set /a n+=1
if !n! leq 5 echo %%i
)
goto :eof
:showNum
if defined n (echo "%forderName%" Number: !n!. & echo.)
goto :eof
setlocal enabledelayedexpansion
for /d %%a in (*) do (
set "forderName=%%a"
set "n="
call :show5Files
call :showNum
)
goto :eof
:show5Files
for %%i in ("%forderName%\*.*") do (
set /a n+=1
if !n! leq 5 echo %%i
)
goto :eof
:showNum
if defined n (echo "%forderName%" Number: !n!. & echo.)
goto :eof