@echo off
setlocal enabledelayedexpansion
type nul>b.txt
set test=最近看到网上有人喜欢用竖向排版方式发帖，感觉很有意思，就写了一个批处理排版，与大家分享。有时间的话，我希望自己能够继续完善这个批处理。
set rows=10
set clos=10
set /a tmpclos=%clos%*2-1
set header=╔
set footer=╚
for /l %%a in (1,1,%tmpclos%) do (
  set /a flag=%%a%%2
  if !flag! == 1 (
    set header=!header!═
    set footer=!footer!═
  ) else (
    set header=!header!╤
    set footer=!footer!╧
  )
)
set header=!header!╗
set footer=!footer!╝
echo !header!>>b.txt
for /l %%a in (1,1,%rows%) do (
  set curclo=0
  set row=║
  for /l %%b in (1,1,%clos%) do (
    set /a curclo+=1
    set /a cut=%clos%-%%b
    set /a cut=!cut!*%rows%+%%a-1
    call set char=%%test:~!cut!,1%%
    if "!char!" equ "" (
      set row=!row!　
    ) else (
      set row=!row!!char!
    )
    if !curclo! lss %clos% (
      set row=!row!│
    )
  )
  echo !row!║>>b.txt
)
echo !footer!>>b.txt

@echo off&setlocal enabledelayedexpansion
set str=最近看到网上有人喜欢用竖向排版方式发帖，感觉很有意思，就写了一个批处理排版，与大家分享。有时间的话，我希望自己能够继续完善这个批处理。　
for /l %%i in (1 1 10) do (
   for /l %%a in (3 2 21) do set "h%%i.%%a=│"
   set h%%i.21=║&set "h%%i.1=║"
)
for /l %%a in (20 -2 2) do (
   for /l %%i in (1 1 10) do (
      if defined str (
         set h%%i.%%a=!str:~0,1!
         set str=!str:~1!
       ) else set "h%%i.%%a=　"
))
echo ╔═╤═╤═╤═╤═╤═╤═╤═╤═╤═╗ 
for /l %%i in (1 1 10) do (
   for /l %%a in (1 1 21) do set /p=!h%%i.%%a!<nul
   echo.  
)
echo ╚═╧═╧═╧═╧═╧═╧═╧═╧═╧═╝
pause>nul