标题: [已结]随机赋值问题。。。 [打印本页]
作者: pusofalse 时间: 2008-6-27 21:40 标题: [已结]随机赋值问题。。。
a=z
b=q
c=e
...
...
a的值是z
b的值是q
如此。。。都是随机赋值。。。
26个字母分别对应一个不同于本身的值，但是值不能重复，即是，
如果m的值是a，那么以后出现的变量中，它们的值不能再是a。。。
这是我的代码，运行之后总有几个是空值，如何避免这种情况？
Last edited by pusofalse on 2008-6-28 at 04:13 AM ]
b=q
c=e
...
...
a的值是z
b的值是q
如此。。。都是随机赋值。。。
26个字母分别对应一个不同于本身的值，但是值不能重复，即是，
如果m的值是a，那么以后出现的变量中，它们的值不能再是a。。。
这是我的代码，运行之后总有几个是空值，如何避免这种情况？
@echo off&setlocal enabledelayedexpansion
set str=a b c d e f g h i j k l m n o p q r s t u v w x y z
set var=%str: =%
for %%a in (%str%) do (
set ran=!random!
set/a mn=!ran!%%26
if not defined !mn! (
set !mn!=abcd
call :lp %%a
)
)
echo %xy%
for %%a in (%str%) do echo %%a !%%a!
pause>nul&exit/b
:lp
set %1=!var:~%mn%,1!
set/a xy+=1Last edited by pusofalse on 2008-6-28 at 04:13 AM ]
作者: bat-zw 时间: 2008-6-27 22:32
兄弟是不是这样的：
@echo off&setlocal enabledelayedexpansion
set code=abcdefghijklmnopqrstuvwxyz
set codes=%code%&set n=26
:begin
set str=&set "var="
set /a r1=%random%%%%n%,r2=%random%%%%n%
set str=!code:~%r1%,1!&set var=!codes:~%r2%,1!
echo %str%=%var%
set /a n-=1
set code=!code:%str%=!&set codes=!codes:%var%=!
if defined code goto begin
pause>nul
作者: moniuming 时间: 2008-6-27 22:36
是这样吗:
@echo off
setlocal enabledelayedexpansion
set str=a b c d e f g h i j k l m n o p q r s t u v w x y z
set var=%str: =%
for %%a in (%str%) do call :lp %%a
echo %xy%
for %%a in (%str%) do echo %%a !%%a!
pause>nul&exit/b
:lp
set/a "mn=%random%%%26"
if defined %mn% goto :lp
set "%mn%=abcd"
set "%1=!var:~%mn%,1!"
set/a "xy+=1"
作者: bat-zw 时间: 2008-6-27 22:36
如要按顺序就修改成如下代码：
@echo off&setlocal enabledelayedexpansion
set code=abcdefghijklmnopqrstuvwxyz
set codes=%code%&set n=26
:begin
set str=&set "var="
set /a r1=%random%%%%n%
set str=!code:~,1!&set var=!codes:~%r1%,1!
echo %str%=%var%
set /a n-=1
set code=!code:~1!&set codes=!codes:%var%=!
if defined code goto begin
pause>nul
作者: pusofalse 时间: 2008-6-27 22:43
谢谢楼上两位。。。真是太棒了！ ^_^
作者: 26933062 时间: 2008-6-27 23:55
26个字母分别对应一个不同于本身的值，但是值不能重复
2楼、3楼的难道不会出现 a=a e=e h=h 等等情况吗？
Last edited by 26933062 on 2008-6-28 at 12:07 AM ]
2楼、3楼的难道不会出现 a=a e=e h=h 等等情况吗？
@echo off&setlocal enabledelayedexpansion
set str=a b c d e f g h i j k l m n o p q r s t u v w x y z
for %%a in (%str%) do (
set var=!str:%%a=!
for %%b in (!num!) do set var=!var:%%b=!
call :loop %%a
)
pause
:loop
set /a max=0
for %%a in (!var!) do set /a max+=1,ttt=!random!%%max+1
for /f "tokens=%ttt%" %%i in ("!var!") do (
echo %1=%%i
set num=!num! %%i
)
goto :eof
Last edited by 26933062 on 2008-6-28 at 12:07 AM ]
作者: moniuming 时间: 2008-6-28 10:21
Originally posted by 26933062 at 2008-6-27 23:55:
26个字母分别对应一个不同于本身的值，但是值不能重复
2楼、3楼的难道不会出现 a=a e=e h=h 等等情况吗？
@echo off&setlocal enabledelayedexpansion
s ...
这种情况当然会出现,但楼主的意思是当a=a后,其它的25个字母的值都不能再等于a.
作者: bat-zw 时间: 2008-6-28 10:59
Originally posted by 26933062 at 2008-6-27 23:55:
26个字母分别对应一个不同于本身的值，但是值不能重复
2楼、3楼的难道不会出现 a=a e=e h=h 等等情况吗？
@echo off&setlocal enabledelayedexpansion
s ...
确实是这样，真的还没考虑全，其实也只要加个判断和返回就可以了：
@echo off&setlocal enabledelayedexpansion
set code=abcdefghijklmnopqrstuvwxyz
set codes=%code%&set n=26
:begin
set str=&set "var="
set /a r1=%random%%%%n%
set str=!code:~,1!&set var=!codes:~%r1%,1!
if "%str%" equ "%var%" goto begin
echo %str%=%var%
set /a n-=1
set code=!code:~1!&set codes=!codes:%var%=!
if defined code goto begin
pause>nul
ps:兄弟是不是想利用这样的替换来进行代码加密啊，我看是个好办法!
Last edited by zw19750516 on 2008-6-28 at 11:09 AM ]
作者: seuseuseu 时间: 2008-9-8 14:12
顶起来