标题: [原创]标题动态变化的cmd[模拟线程]
[打印本页]
作者: s11ss
时间: 2008-4-17 12:07
标题: [原创]标题动态变化的cmd[模拟线程]
@echo off %CMD With An Active Title(Simulate Thread) s11ss@www.cn-dos.net 2008-4-17%
if "%1" equ "-title" call :PrintTitle "%comspec%"
start /b "NewThread" %0 -title
tasklist|findstr "\<cmd.exe\>">"%tmp%\t4.17"
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('echo exit^|cmd') do (
set/a n+=1
if !n! leq 2 echo %%a
)
echo.
endlocal
:RunCommand
set/p COMMAND=%cd%^>
if "%COMMAND%"=="" (
goto :RunCommand
) else (
if "%COMMAND%"=="exit" (
for /f "usebackq tokens=2" %%a in ("%tmp%\t4.17") do set t=%%a
del "%tmp%\t4.17"
call taskkill /f /pid %%t%% >nul
)
)
call %COMMAND%
echo.
set "COMMAND="
goto :RunCommand
exit/b
:PrintTitle
set s'=%~1&set/a n'=0,t'=n'+1
:ptloop
call set o'=%%s':~%n'%,1%%&if "%o'%" equ "" goto :PrintTitle
call title %%s':~0,%t'%%%&set/a n'+=1,t'=n'+1&ping 127.1 -n 1 >nul&goto :ptloop
作者: wxcute
时间: 2008-4-17 12:14
沙发
任务栏的的文字好像不会实时变动,只有鼠标或键盘有动作时才变化。
Last edited by wxcute on 2008-4-17 at 12:17 PM ]
作者: bat-zw
时间: 2008-4-17 12:41
标题: 来个简单点的:
@echo off&mode con lines=5
:begin
set str=2008北京奥运,我们正在自豪地期盼你的到来!
for /l %%i in (1,1,23) do (
setlocal enabledelayedexpansion
title !str:~,%%i!
ping /n 1 127.1>nul
endlocal
)
goto begin