中国DOS联盟论坛 - Powered by Discuz! Board

标题: [求助]可不可以用文件的最后访问时间为标准删除文件？ [打印本页]

作者: xiaopiaoaiting 时间: 2008-2-13 20:04 标题: [求助]可不可以用文件的最后访问时间为标准删除文件？

我做有一些歌库，客户用了一段时间后需要加一些新歌，但里面的空间毕竟有限。而一套歌库里面其实真正常唱的只有几千首歌。其他的一两年都没有人点一次。这样就占用蛮多的空间。
现在我想这样子：以最后访问时间为标准，删除某个时间前访问的文件。

不知道能不能够做出这样的批处理？那些文件后缀是vob mpg dat。

希望高手们能够帮助解决这个问题。感谢大虾们，祝大家新年发财。

─────────────────　版务记录　─────────────────
执行：HAT
操作：在帖子标题中增加搜索关键字
说明：原标题"可不可以用访问为条件删除文件？"不利于论坛搜索
─────────────────　版务记录　─────────────────

Last edited by HAT on 2008-9-27 at 10:44 ]

作者: digger 时间: 2008-2-13 21:06

没问题，dir /ta + for 解决掉。

作者: xiaopiaoaiting 时间: 2008-2-14 19:43

Originally posted by digger at 2008-2-13 09:06 PM:
没问题，dir /ta + for 解决掉。

晕，我好菜的啦!具体点可不可以？

作者: xiaopiaoaiting 时间: 2008-2-16 03:54

唉~!看来没人肯帮做个完美的解答了。真遗憾。

作者: moniuming 时间: 2008-2-16 15:03

@echo off
echo 日期格式为: 2008-01-01
set /p aa=请输入要删除的文件的访问日期(这个日期之前的文件也会被删除):
for %%a in (vob mpg dat) do (
for /f "skip=5 tokens=1,2,3*" %%b in ('dir /od /ta /a-d *.%%a^|findstr /v "字节"') do (
set bb=%%b
set cc=%%e
call :aaa
)
)
pause
goto :eof
:aaa
if %bb% leq %aa% echo %cc%

如果日期格式不同,请适当更改
删除文件需谨慎,如果确定删除,请将最后一行的echo换成del /f /q

作者: fastslz 时间: 2008-2-16 15:11

Originally posted by xiaopiaoaiting at 2008-2-16 03:54:
唉~!看来没人肯帮做个完美的解答了。真遗憾。

你完全可以搜索到的,代码给你了不知道怎么用怎么改也没办法了
代码删除30天未访问过的.dat .vob .mpg

@echo off

regedit /e "%temp%\bak.reg" "HKEY_CURRENT_USER\Control Panel\International"

>aDate.reg echo REGEDIT4

>>aDate.reg echo.

>>aDate.reg echo 

>>aDate.reg echo "sShortDate"="yyyy-MM-dd"

>>aDate.reg echo "sDate"="-"



>tmp.vbs echo Wscript.echo FormatDateTime (DateAdd("d",-30,Date),2)

for /f "delims=" %%i in ('cscript.exe //nologo tmp.vbs') do set aDate=%%i

del tmp.vbs

for /f "tokens=1,4" %%i in ('dir /s/a-d/ta "歌库\*"^|findstr /i ".dat .vob .mpg"') do if %%i lss %aDate% del /s/q/f "歌库\%%j" 2>nul

regedit /s aDate.reg

del aDate.reg

pause

作者: moniuming 时间: 2008-2-16 16:16

最后一行改成if %bb% leq %aa% echo %bb% %cc%会连访问时间一起显示

作者: moniuming 时间: 2008-2-16 16:40

还是6楼厉害,我的代码真的是......唉,还是改改吧(根据6楼的代码)

@echo off
echo 日期格式为: 2008-01-01
set /p aa=请输入要删除的文件的访问日期(这个日期之前的文件也会被删除):
for %%a in (dat mpg vob) do (
for /f "tokens=1,4" %%b in ('dir /od /ta /a-d ^|findstr /i ".%%a"') do (
set bb=%%b
set cc=%%c
call :aaa
)
)
pause
goto :eof
:aaa
if %bb% leq %aa% echo del /f /q %bb% %cc%

作者: fastslz 时间: 2008-2-16 18:32

测试后发现处理不了带空格文件名的文件

@echo off
regedit /e "%temp%\bak.reg" "HKEY_CURRENT_USER\Control Panel\International"
>aDate.reg echo REGEDIT4
>>aDate.reg echo.
>>aDate.reg echo
>>aDate.reg echo "sShortDate"="yyyy-MM-dd"
>>aDate.reg echo "sDate"="-"
regedit /s aDate.reg&del aDate.reg

>tmp.vbs echo Wscript.echo FormatDateTime (DateAdd("d",-30,Date),2)
for /f "delims=" %%i in ('cscript.exe //nologo tmp.vbs') do set aDate=%%i
del tmp.vbs
for /f "tokens=1,3*" %%i in ('dir /s/a-d/ta "歌库\*"^|findstr /i ".dat .vob .mpg"') do if %%i lss %aDate% del /s/q/f "歌库\%%k" 2>nul
regedit /s "%temp%\bak.reg"&del "%temp%\bak.reg"
pause

红色指定日期,蓝色要处理的目录(自行修改)

Last edited by fastslz on 2008-2-17 at 01:29 PM ]

作者: xiaopiaoaiting 时间: 2008-2-17 20:59

哈哈~!!!得了。多谢~! 我用了6楼的方法，完全适用。哈哈~!!

非常感谢，在这里也学了不少的东西。