标题: [讨论][NT]扩展变量内容中的待扩展变量的简便方法？ [打印本页]
作者: BatMan 时间: 2008-1-5 13:55 标题: [讨论][NT]扩展变量内容中的待扩展变量的简便方法？
我在使用BAT时，需要访问My Documents目录。我发现没有任何一个系统环境变量指向该处，而我的My Documents进行了自定义而不在系统的默认位置%USERPROFILE%\My Documents上，遂从注册表读HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders下的Personal的值，赋给一个变量以使用。
这方法在我的机器上运作良好，但在其他没有自定义My Documents位置的机器上，取注册表得到的值为%USERPROFILE%\My Documents，我想再作一次扩展使其扩展成一个不带未扩展变量的值，如C:\Documents And Settings\UserName\My Documents。
我目前的解决方案如下，感觉有点罗嗦，希望能看到以更简洁的方式获得相同的效果。另外，如果有更简便的方式获得My Documents目录，也请不吝赐教，谢谢！
@ECHO OFF
FOR /F "tokens=2*" %%I IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" ^| FIND /i "Personal"') DO SET "Personal=%%J"
CALL :ExpandPathMacro "%Personal%" Personal
ECHO %Personal%
PAUSE
@ECHO ON
@GOTO :EOF
:: 扩展路径宏，参数1为待扩展字符串，参数2为返回变量名
:ExpandPathMacro
SETLOCAL ENABLEDELAYEDEXPANSION
SET "EPM=%~1"
SET "EPM=!EPM:%%=?!"
SETLOCAL ENABLEEXTENSIONS & ENDLOCAL & SET "EPM=%EPM:?=!%"
ENDLOCAL & SET "%2=%EPM%"
GOTO :EOF
[ Last edited by BatMan on 2008-1-5 at 02:15 PM ]
作者: BatMan 时间: 2008-1-5 16:50
自己多把玩了一下，发现个更简单的方法，把ExpandPathMacro函数修改为：
:ExpandPathMacro
SET "%~2=%~1"
GOTO :EOF
已经简单好多了，有没有不需要调函数，直接在同层语句实现的方法呢？
作者: qzwqzw 时间: 2008-1-5 21:13
绕太大弯子了
有两个更直接的办法
一是在 SET "Personal=%%J" 前面加个call
变成 CALL SET "Personal=%%J"
其它的扩展代码都可以省略了
二是改取Shell Folders下的键值
而非User Shell Folders下的
请注意二者的键值区别
主要是类型不同以及是否扩展
另外发现个 03 下的 reg query 的问题
不知道是不是bug
在reg query user shell folders下的键值时
所有reg_expand_sz类型的键值全部显示为reg_sz类型
如果键值中有%等扩展符号
则提示 “错误: 有更多数据可用。”
然后不显示这些带扩展符号的reg_expand_sz类型的键值
作者: BatMan 时间: 2008-1-5 21:37
| Quote: | |
|
谢谢3楼！学到了！另外我在公司的XP Sp2的机器上也看到过User Shell Folders下出现部分键值为REG_SZ，部分为REG_EXPAND_SZ类型的情况，没考究过成因和影响。
作者: qzwqzw 时间: 2008-1-5 21:44
应该是某些软件或个人后期修改的
而且没有遵照windows的约定去改