标题: 读取每行数字然后求和，发生异常！ [打印本页]
作者: gingapeng 时间: 2007-11-22 20:25 标题: 读取每行数字然后求和，发生异常！
之前脚本是正常，后来每行数字增大到9位数后，合计的总数不对了。脚本如下：
rem sum
SET FILEPATH=E:\log\
SET BATEPATH=C:\bat\
@echo off&setlocal enabledelayedexpansion
set /a l=0
for /f "tokens=1,*" %%i in (%BATEPATH%stat.txt) do (
set /a l=%%i+!l!
)
echo 合计：%l% 字节 >>%BATEPATH%logsize.txt
EXIT
stat.txt的内容如下：
850291671
789066444
879171903
778291045
892318966
818960237
logsize.txt脚本运行后的结果如下：
live1=850291671
live2=789066444
live3=879171903
live4=778291045
live5=892318966
live6=818960237
合计：713132970 字节
找不到原因，请各位帮忙看看，谢过了！
另外set /a l=%%i+!l! 这句中的两个叹号是什么意思。
[ Last edited by gingapeng on 2007-11-22 at 08:29 PM ]
作者: gingapeng 时间: 2007-11-22 20:27 标题: 在线等。。。。。。。
在线等。。。。。。。
;)
作者: 不得不爱 时间: 2007-11-22 20:29
SET/P最大的输出数为:2147483647,超过后就得不到正确的结果
作者: zh159 时间: 2007-11-22 20:31
set /a能计算的最大数2147483647，最小-2147483648
作者: gingapeng 时间: 2007-11-22 20:36
那如何解决该问题呢？
作者: gingapeng 时间: 2007-11-22 21:20
这个脚本是合计web日志大小，默认是字节，因此将每行数字（日志大小）先转成K或是M，然后再合计，可解决。
作者: bjsh 时间: 2007-11-22 22:13
大数字的计算 很久前就有讨论 搜索吧
作者: 26933062 时间: 2007-11-22 22:26
以下方法可以对200位以内的整数进行加法运算。
:
@echo off&setlocal enabledelayedexpansion
set num=0&set jin=0
for /l %%a in (1 1 200) do set lin=0!lin!
for /f %%i in (a.txt) do echo %%i&call :lis %%i
echo.&echo 结果等于 %num%
pause>nul
exit
:lis
set lis=
set var=!lin!%~1
set num=!lin!!num!
for /l %%a in (1 1 200) do (
set /a jie=!var:~-%%a,1!+!num:~-%%a,1!+jin
set jie=0!jie!
set jin=!jie:~-2,1!
set lis=!jie:~-1!!lis!
)
set num=!lis!
for /f "tokens=* delims=0" %%a in ("%num%") do set num=%%a
goto :eof
set num=0&set jin=0
for /l %%a in (1 1 200) do set lin=0!lin!
for /f %%i in (a.txt) do echo %%i&call :lis %%i
echo.&echo 结果等于 %num%
pause>nul
exit
:lis
set lis=
set var=!lin!%~1
set num=!lin!!num!
for /l %%a in (1 1 200) do (
set /a jie=!var:~-%%a,1!+!num:~-%%a,1!+jin
set jie=0!jie!
set jin=!jie:~-2,1!
set lis=!jie:~-1!!lis!
)
set num=!lis!
for /f "tokens=* delims=0" %%a in ("%num%") do set num=%%a
goto :eof
作者: gingapeng 时间: 2007-11-23 14:10
试过了，正常运行。感谢八楼的。