中国DOS联盟论坛 - Powered by Discuz! Board

标题: ［请教］把单行的文字用某种分隔符拆成多行 [打印本页]

作者: Billunique 时间: 2007-11-16 18:32 标题: ［请教］把单行的文字用某种分隔符拆成多行

在论坛里，有大家的帮助，真是一件很幸福的事。我又来请教了。一个1.txt文件，大致像这个样子：

小明、小红、小军、小强、小李、小郑、小张、大拿.......

这些名字在同一行，中间以中文顿号隔开。现在的需求是，如何以顿号为分隔符，将他们分行，一个名字占一行。即类似于2.txt：

小明
小红
小军
.....

处理文稿时，很多时候会遇到这样的场景，但一直不知如何解决，特向各位求教，谢谢！另外，如果已经有一个2.txt，想转成1.txt的样子，又该如何处理？ [ Last edited by Billunique on 2007-11-21 at 10:05 AM ]

作者: knoppix7 时间: 2007-11-16 19:12

鄙人不才: 先把文件里所有的、替换成, 然后保存然后用 @echo off for /f "eol=; tokens=1* delims=龓" %%i IN (1.txt) DO ( for %%a IN (%%i) DO echo %%a>>2.txt ) pause 完成转换...

作者: terse 时间: 2007-11-16 19:41

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (test1.txt) do (
set src=%%i
set src=!src:、= !
for %%a in (!src!) do ECHO %%a
)
pause

@echo off
for /f %%a in (test2.txt) do set/p =%%a、<nul
pause

[ Last edited by terse on 2007-11-16 at 07:42 PM ]

作者: lxmxn 时间: 2007-11-16 19:45

1 、1.txt ==》2.txt

@echo off&Setlocal
for /f "delims=" %%a in (1.txt) do call :loop "%%a"
pause
exit/b0

:loop
for /f "tokens=1* delims=、" %%a in ("%~1") do (
	>>2.txt echo %%a
	call :loop "%%b"
)

2、2.txt==》1.txt

@echo off&setlocal
for /f "delims=" %%a in (2.txt) do set/p=%%a、<nul>>1.txt

作者: zh159 时间: 2007-11-17 00:12

我也来一个 1.txt ==》2.txt

@echo off
:loop
set /a n+=1
for /f "tokens=%n%* delims=、" %%a in (1.txt) do echo %%a&&if not "%%a" == "" goto loop
pause
exit

[ Last edited by zh159 on 2007-11-17 at 12:14 AM ]

作者: lxmxn 时间: 2007-11-17 00:21

TO zh159: 方法比较巧妙啊，不过好像只能处理文本中的第一行，改进一下？

作者: zh159 时间: 2007-11-17 00:32

多行的：

@echo off
for /f "delims=" %%a in (1.txt) do set n=0&&call :loop "%%a"
pause
exit

:loop
set /a n+=1
for /f "tokens=%n% delims=、" %%a in (%1) do echo %%a&&if not "%%a" == "" goto loop
goto :eof

作者: Billunique 时间: 2007-11-20 21:36

哈哈，多谢各位兄台！这两天忙没有上来看，上来一看真兴奋，问题已经被解决得这么好！ 3楼的帅气，4楼的深厚，5楼的巧妙，我可真是想不出来啊！当时一个朋友给我说了个PHP的解法，贴出来一下，不会挨骂吧，呵呵

<?php
$str=file_get_contents('1.txt');
$ar=explode("、", $str);
$fp=fopen('2.txt', 'ab');
foreach($ar as $key => $word)
	fwrite($fp, $word."\r\n");
fclose($fp);
?>

作者: zh159 时间: 2007-11-21 00:25

VBS的

Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile("1.txt",1)
  str = Replace(f.ReadAll,"、",vbCrLf)
  f.Close

Set f = fso.CreateTextFile("2.txt",2,Turn)
  f.WriteLine str
  f.Close

作者: bjsh 时间: 2007-11-21 13:36

sed 1. sed 's/、/\n/g' 1.txt 2. sed ':a;$q;H;N;s/\n/、/;ba' 2.txt awk 1. awk -F'、' '{for (i=1;i<=NF;i++) {print $i}}' 1.txt 2. awk '{printf $0"、"}' 2.txt

作者: jmz573515 时间: 2007-11-22 13:50

@echo off
for /f "delims=" %%i in (1.txt) do (
set str=%%i
)
set str=%str:、=^&echo.%
echo %str%
pause

作者: zysheng110 时间: 2007-11-23 00:32

我还不会！！真是个个帅的掉渣！！什么时候我也来一个！

作者: zh159 时间: 2007-11-23 01:19

Originally posted by jmz573515 at 2007-11-22 13:50:
@echo off
for /f "delims=" %%i in (1.txt) do (
set str=%%i
)
set str=%str:、=^&echo.%
echo %str%
pause

这个输出有问题，只能输出最后一行最后一个改一下：

@echo off
for /f "delims=" %%i in (1.txt) do (
set str=%%i
call :loop
)
pause
exit

:loop
set str=%str:、=^&^>^>2.txt echo.%
>>2.txt echo.%str%
goto :eof

其实和VBS的把“、”替换成回车换行符差不多