标题: [求助]如何提取特定字符后的固定长度字符 [打印本页]
作者: gskuser 时间: 2007-11-13 17:42 标题: [求助]如何提取特定字符后的固定长度字符
文本文件1.txt如下内容如下，各编号之间是用空格分开：
SH:212655 213425 @213455 @213459 213521 ........
BJ:101228 @101325 101329 @101352 @101365 ........
GZ:@200231 200255 @200268 @200286 200301 ........
XA: ........
HM: .........
: ..........
: ..........
: ..........
要的就是将含有@的6位固定长度编号存入变量中进行处理，如上面的@213455，@213459，@200286等等，而含有@的编号位置没有规律的，
想用For的批处理，如for /f "tokens=2 delims=@"。。。但实现不了，在论坛找了一天也找不到解决办法，
因为代码上头要审查，不能用SED或其它等第三方工具，只能用XP下DOS自带的命令啊，各位先进有没有办法啊？
作者: knoppix7 时间: 2007-11-13 18:09
用FOR按空格分割.
对分割出的每一个元素的第一个字符进行判断.
作者: genteman 时间: 2007-11-13 18:52
楼上说的是对的，补充一点
delims=:@
作者: gskuser 时间: 2007-11-14 11:51
试过不行啊，不能遍厉整个文本文件，只取得一行的第一个含有@的编号，后面的就找不到，能给个详细的For语句实现吗
作者: lxmxn 时间: 2007-11-14 13:04
try this code:
@echo off & SetLocal EnableDelayedExpansion
for /f "delims=: tokens=2" %%a in (1.txt) do (
for %%b in (%%a) do (
set string=%%b
if "!string:~0,1!"=="@" (
rem you can do something in this block
echo\!string!
)
)
)
pause
for /f "delims=: tokens=2" %%a in (1.txt) do (
for %%b in (%%a) do (
set string=%%b
if "!string:~0,1!"=="@" (
rem you can do something in this block
echo\!string!
)
)
)
pause
作者: 26933062 时间: 2007-11-14 15:38
::
@echo off
for /f "delims=" %%a in (a.txt) do (
set var=%%a
setlocal EnableDelayedExpansion
set shu=-1
call :lis
endlocal
)
pause
exit
:lis
set /a shu+=1
set num=!var:*@=!
if "!num!"=="!var:@=!" (goto :eof) else (
echo !num:~0,6!
set var=!num!
)
goto lis
for /f "delims=" %%a in (a.txt) do (
set var=%%a
setlocal EnableDelayedExpansion
set shu=-1
call :lis
endlocal
)
pause
exit
:lis
set /a shu+=1
set num=!var:*@=!
if "!num!"=="!var:@=!" (goto :eof) else (
echo !num:~0,6!
set var=!num!
)
goto lis
作者: 26933062 时间: 2007-11-14 15:40
没注意 lxmxn 版主已经发了，比我的简洁多了。
作者: gskuser 时间: 2007-11-16 14:52
版主的For代码测试了二天都验正结果正确，版主真是牛人啊 太感谢了
作者: zqdarkday 时间: 2007-11-17 13:01
to lxmxn 斑竹
有个问题想问下，你所写的这个代码我有个地方想不通
就是for for %%b in (%%a) do
的时候for不是提取的是一整行吗
最后为什么能把一行中的几段分别提出来呢？是if语句起的作用吗？到底是什么原因
请告诉小弟一下！
谢谢了
作者: lxmxn 时间: 2007-11-17 13:07
RE zqdarkday:
| Quote: | |
|
关键是注意%%a的内容是什么格式，第一次循环时，%%a的内容就是：
212655 213425 @213455 @213459 213521
这里得到的是以空格分隔的单独的元素项，那么for不加参数时刚好可以循环迭代in后面括号中的每个元素了，再加上判断，就可以得到最终的结果了。
命令行下面试试 for %a in (c d e f g) do @echo \ %a \ ，看得到什么结果。
作者: ansipeter 时间: 2007-11-17 14:03
玩儿......................................
@echo off&setlocal
for /f "tokens=1* delims=:" %%a in (kk.txt) do call:9527 %%b
goto:eof
:9527
for %%c in (%*) do echo/%%c|findstr "^@"
[ Last edited by ansipeter on 2007-11-17 at 02:05 PM ]for /f "tokens=1* delims=:" %%a in (kk.txt) do call:9527 %%b
goto:eof
:9527
for %%c in (%*) do echo/%%c|findstr "^@"
作者: zqdarkday 时间: 2007-11-17 15:10
re lxmxn 斑竹
饿，原来最基本的都忘了，谢谢了
不过我还是有个问题，还是关于for机制的
例如把1.txt的空格都改为逗号
SH:212655,213425,@213455,@213459,213521 ........
BJ:101228,@101325,101329,@101352,@101365 ........
GZ:@200231,200255,@200268,@200286,200301 ........
XA: ........
HM: .........
这样
我写了一个类似的
@echo off & SetLocal EnableDelayedExpansion
for /f "delims=: tokens=2" %%a in (1.txt) do (
for /f "delims=," %%b in ('echo %%a') do (
echo %%b
set string=%%b
if "!string:~0,1!"=="@" (
echo\!string!
)
)
)
pause
其中%%b只能显示第一个
这样是怎样的原理啊，谢谢哦
作者: lxmxn 时间: 2007-11-17 17:38
for /f 的时候默认是取第一个元素的，所以只能显示一个。。
作者: lxmxn 时间: 2007-11-17 20:56
TO zqdarkday:
你修改了这个格式其实用我5楼的代码同样适用。。。
作者: zqdarkday 时间: 2007-11-17 21:18
re zqdarkday
能不能把具体代码发上来让我看下吗？
谢谢哦
作者: lxmxn 时间: 2007-11-17 21:36
在5楼...
作者: zqdarkday 时间: 2007-11-17 23:11
to lxmxn
我先是把空格改为"."当时结果如下
@200231.200255.@200268.@200286.200301
后来我就随便把空格改为"," 我想都一样就没测试
我不在意结果，也不求解决什么问题，我现在关心for这样分析原理
为什么对这样呢？难道for还把逗号变为默认分割符了吗？
还有在你的代码的基础上怎样做出来呢？？？
麻烦了！
作者: lxmxn 时间: 2007-11-17 23:23
嗯，正是利用了逗号（,）也是默认的分隔符的原理，你可以试试还有其它哪些分隔符。
如果替换成句号（.）的话，就需要另外的思路了。
作者: zqdarkday 时间: 2007-11-17 23:45
惭愧，最近学vbs多了，for忘多了
谢谢解答啊
另外的方法就留给我拉
再说声谢谢哦