中国DOS联盟论坛 - Powered by Discuz! Board

标题: [已结]如何简写输出指定多行文本的批处理 [打印本页]

作者: hbby 时间: 2007-9-13 17:30 标题: [已结]如何简写输出指定多行文本的批处理

我想指定输出一个文本的第1、13、14、15、16、17、18、19、20、21、22行，如下批处理可以实现，但是代码复杂，请问如何简写！谢谢！

for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "1"=="%%i" echo %%j>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "13"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "14"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "15"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "16"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "17"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "18"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "19"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "20"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "21"=="%%i" echo %%j>>2.txt
)
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (
      if "22"=="%%i" echo %%j>>2.txt
)

[ Last edited by hbby on 2007-9-15 at 09:23 PM ]

作者: ccwan 时间: 2007-9-13 17:43
sed q AUTOEXEC.BAK>2.txt
sed -n "13,22p" AUTOEXEC.BAK>>2.txt

作者: hbby 时间: 2007-9-13 17:46
老大，不想用SED有办法吗？谢谢

作者: ccwan 时间: 2007-9-13 17:55
这样呢？

for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do (

        if "%%i" equ "1" echo %%j>2.txt

        if "%%i" geq "13" if "%%i" leq "22" echo %%j>>2.txt

)

作者: hbby 时间: 2007-9-13 18:04
对了,老大,我的原文件是
@ECHO OFF
GOTO %CONFIG%
:RECOVER
PATH C:\DOSTOOLS;C:\DOSTOOLS\COMMAND
SET TEMP=C:\DOSTOOLS\TEMP
LH DOSTOOLS\COMMAND\DOSKEY
LH DOSTOOLS\COMMAND\MOUSE
LH DOSTOOLS\SMARTDRV.EXE
C:\DOSTOOLS\GHOST -CLONE,MODE=PLOAD,SRC=D:\GHOSTSYS\SYSTEM.GHO:1,DST=1:1 -SURE -RB
GOTO END

:BACKUP
PATH C:\DOSTOOLS;C:\DOSTOOLS\COMMAND
SET TEMP=C:\DOSTOOLS\TEMP
LH DOSTOOLS\COMMAND\DOSKEY
LH DOSTOOLS\COMMAND\MOUSE
LH DOSTOOLS\SMARTDRV.EXE
IF NOT EXIST D:\GHOSTSYS\NUL MD D:\GHOSTSYS
C:\DOSTOOLS\GHOST -Z9 -CLONE,MODE=PDUMP,SRC=1:1,DST=D:\GHOSTSYS\SYSTEM.GHO -SURE -FX
ATTRIB +A +S +H +R D:\GHOSTSYS
WIN /Z
REBOOT
GOTO END

:TOOLS
SET EXPAND=YES
SET DIRCMD=/O:N
SET LGLDRV=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
SET LGLDRV=%LGLDRV% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
CALL DOSTOOLS\SETRAMD.BAT %LGLDRV%
PATH %RAMD%:\DOSTOOLS;%RAMD%:\DOSTOOLS\COMMAND;%CDROM%:\
MKDIR %RAMD%:\DOSTOOLS
MKDIR %RAMD%:\DOSTOOLS\COMMAND
DOSTOOLS\COMMAND\ATTRIB -A -S -H -R \COMMAND.COM
COPY COMMAND.COM %RAMD%:\>NUL
DOSTOOLS\COMMAND\ATTRIB +A +S +H +R \COMMAND.COM
COPY DOSTOOLS\*.* %RAMD%:\DOSTOOLS>NUL
COPY DOSTOOLS\COMMAND\*.* %RAMD%:\DOSTOOLS\COMMAND>NUL
MKDIR %RAMD%:\DOSTOOLS\TEMP
SET TEMP=%RAMD%:\DOSTOOLS\TEMP
SET TMP=%RAMD%:\DOSTOOLS\TEMP
LH DOSTOOLS\COMMAND\DOSKEY
LH DOSTOOLS\COMMAND\MOUSE
LH DOSTOOLS\COMMAND\MSCDEX /D:ECSCD003 /E
LH DOSTOOLS\SMARTDRV.EXE
SET COMSPEC=%RAMD%:\COMMAND.COM
SET CDROM=
SET LGLDRV=

:END

用您的批处理结果为
@ECHO OFF
GOTO %CONFIG%
PATH C:\DOSTOOLS;C:\DOSTOOLS\COMMAND
SET TEMP=C:\DOSTOOLS\TEMP
LH DOSTOOLS\COMMAND\DOSKEY
LH DOSTOOLS\COMMAND\MOUSE
LH DOSTOOLS\SMARTDRV.EXE
IF NOT EXIST D:\GHOSTSYS\NUL MD D:\GHOSTSYS
C:\DOSTOOLS\GHOST -Z9 -CLONE,MODE=PDUMP,SRC=1:1,DST=D:\GHOSTSYS\SYSTEM.GHO -SURE -FX
ATTRIB +A +S +H +R D:\GHOSTSYS
WIN /Z
REBOOT

多出了一行GOTO %CONFIG%
能再看看吗?谢谢

[ Last edited by hbby on 2007-9-13 at 07:14 PM ]

作者: ThinKing 时间: 2007-9-13 20:13
命令行执行：

for /f "delims=: tokens=1*" %a in ('findstr /n .* a.txt^|findstr "^1: ^13 ^14 ^15 ^16 ^17 ^18 ^19 ^20 ^21 ^22" ') do @echo\%b>>2.txt

作者: wxl7759 时间: 2007-9-13 21:44
我是来学习的

作者: acai 时间: 2007-9-13 22:24
学习学习，真是牛人

作者: ccwan 时间: 2007-9-14 09:59

set/p kk=<AUTOEXEC.BAK&call echo %%kk%%>2.txt

for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do if %%i geq 13 if %%i leq 22 echo %%j>>2.txt

作者: hbby 时间: 2007-9-14 10:36
老大就是厉害！已经解决！谢谢！
但是还存在问题
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do if %%i geq 13 if %%i leq 32 echo %%j>>2.txt
如果到从13行到32行，在其中有个:tool，“：”这个特殊符号不能被导出！能再看看吗？谢谢

[ Last edited by hbby on 2007-9-14 at 10:50 AM ]

作者: ccwan 时间: 2007-9-14 10:44
to hbby
ThinKing的代码很简洁，正则表达式也是你应该掌握的技巧。我只是用另一种思路来完成罢了。

作者: ccwan 时间: 2007-9-14 11:09

Quote:

Originally posted by hbby at 2007-9-14 10:36:
老大就是厉害！已经解决！谢谢！
但是还存在问题
for /f "tokens=1* delims=:" %%i in ('findstr/n . AUTOEXEC.BAK') do if %%i geq 13 if %%i leq 32 echo %%j>>2.txt
...

以findstr /n 列出行数，就是以冒号为分隔符的，要想处理，一定要多写代码，所以建议还是用sed吧。很简单的，有空你可以学习一下。

作者: hbby 时间: 2007-9-15 15:42

Quote:

Originally posted by ccwan at 2007-9-14 11:09:

以findstr /n 列出行数，就是以冒号为分隔符的，要想处理，一定要多写代码，所以建议还是用sed吧。很简单的，有空你可以学习一下。

除了用SED就真的没有其他办法吗?各位高手再帮忙想想办法吧！谢谢大家！

作者: terse 时间: 2007-9-15 20:04
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
      set /a mn=%%i 2>nul
      set "m=%%i"
      setlocal enabledelayedexpansion
      set m=!m:*:=!
      if !mn! LSS 2 echo.!m!>test2.txt
      if !mn! GEQ 13 if !mn! LEQ 22 echo.!m!>>test2.txt
endlocal

[ Last edited by terse on 2007-9-17 at 10:41 AM ]

作者: hbby 时间: 2007-9-15 21:13

Quote:

Originally posted by terse at 2007-9-15 20:04:
r /f "delims=" %%i in ('findstr /n .* test.txt') do (
      set /a mn=%%i 2>nul
      set "m=%%i"
      setlocal enabledelayedexpansion
      set m=!m:*:=!
   ...

楼上的兄弟,没看明白,能写完整吗?谢谢!

作者: hbby 时间: 2007-9-15 21:17
应该是这样吧!?
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
      set /a mn=%%i 2>nul
      set "m=%%i"
      setlocal enabledelayedexpansion
      set m=!m:*:=!
      if !mn! LSS 2 echo.!m!>test2.txt
      if !mn! GEQ 3 if !mn! LEQ 3 echo.!m!>>test2.txt
endlocal
)
谢谢!