:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::运行环境2000、xp或更高 ::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@Echo Off
Title CAB文件夹最大压缩工具
Set Prestr=MAKECAB /v3 /D CompressionType=LZX /D CompressionMemory=21 /D MaxDiskSize=CDROM /D Cabinet=On /D Compress=On
:begin
Set fullname=%~1
Set dirpath=%~dp1
Set srcname=%~n1
if exist "%fullname%\" goto is_dir
:is_file
Set Cmdstr=%Prestr% "%fullname%" "%dirpath%%srcname%.CAB"
%Cmdstr%
Set Cmdstr=
shift
Set tmpstr=%1
if not %tmpstr%=="" goto begin
goto end
:is_dir
Set Cmdstr=%Prestr% /D FolderSizeThreshold=5000000 /D DiskDirectoryTemplate="%dirpath%." /D CabinetNameTemplate="%srcname%.CAB"
Set Tempfile=%TEMP%\mkcabtmp.tmp
If Exist "%Tempfile%" Del "%Tempfile%" >NUL
SETLOCAL ENABLEDELAYEDEXPANSION
For /f "delims=" %%i In ('dir "%fullname%" /s /b /a-d') Do (
Set subname=%%i
Set "subname=!subname:%fullname%\=!"
Echo "%%i" "!subname!">>%Tempfile%
)
ENDLOCAL
%Cmdstr% /F %Tempfile%
Del /F /S /Q "%Tempfile%" SETUP.INF SETUP.RPT >NUL
Set Tempfile=
Set Cmdstr=
shift
Set tmpstr=%1
if not %tmpstr%=="" goto begin
:end
Set tmpstr=
Set srcname=
Set dirpath=
Set fullname=
Set Prestr=

[[i] Last edited by netwinxp on 2007-7-27 at 11:41 AM [/i]]

压缩率比WINRAR最大压缩略高，每个对象比压缩成同名的CAB文件(原文件仍保留)，大家用过有何BUG请反馈，谢谢先。

如果楼主用过微软原版光盘上的压缩工具，就该知道那才是压缩率高的。

这个本身就是调用微软的CAB制作工具(只不过makecab操作文件夹繁琐)，并采用最大化压缩，没有理由会比它低。我们以office2000sch原装光盘里面的ofifice1.cab来做测试，原压缩包110M(115,385,377)内含252个文件，解压后210M(220,265,737)共252个文件，重新用上面的压缩后105M(110,611,933)内含252个文件，经解压进行文件对比，完全重合，用新压缩包替换老压缩包安装过程完全没问题。新包比原包少了5M，也就是说微软的原装包并不全是最大压缩。

Last edited by netwinxp on 2007-7-27 at 04:09 PM ]

LZ的程序确实能批量打包，不过打包后的路径和文件名加在一起了
如：
D:外置程序PE_OUTERPART新建文件夹DRIVERS_NET3COM3c940_3c2000EL2000x.inf

其中的斜杠完全丢失

期待下个版本

我靠，好东西

简单的测试了下：压缩大小是比WinRAR小，比7z的大

原文件111KB
WinRAR 19.1KB （采用了最大压缩）
你的作品 14.6KB\14KB...
7z 13.1KB\12.1KB （采用最大压缩）

Last edited by tireless on 2007-9-18 at 05:46 AM ]

这个不错，在无忧看过了

楼主再写个解压的批处理啊

好加密的,就更好了.

但此工具,只好,被在同一磁盘下引用??????

Last edited by cad55 on 2007-12-15 at 10:58 AM ]