Board logo

标题: 请高手看看批处理错在哪里 [打印本页]
作者: willsion     时间: 2007-3-16 22:24    标题: 请高手看看批处理错在哪里

@echo off
setlocal ENABLEDELAYEDEXPANSION

set asus=_ASUS_
set lenovo=_LENOVO_
set sony=_SONY_

set OEM=asus

for %%i in (asus lenovo sony) do (
    set OEM=%%i
    echo The OEM value is !%OEM%!
    rem 以下对 !%OEM%! 进行处理
    )

pause

exit

这个批处理本意是通过引用OEM变量得到asus、lenovo和sony的值，然后进行处理。

但for循环内OEM的值没有发生改变，还是原来的初始值"asus"，
输出结果是三行的 The OEM value is _ASUS_

不是预期的The OEM value is _ASUS_
               The OEM value is _LENOVO_
               The OEM value is _SONY_

请各位高手指点一下。

谢谢。

[ Last edited by willsion on 2007-3-16 at 10:25 PM ]
作者: electronixtar     时间: 2007-3-16 22:47
都中级用户了，还取这么个帖子标题。
作者: willsion     时间: 2007-3-16 23:08


  Quote:
Originally posted by electronixtar at 2007-3-16 10:47 PM:
都中级用户了，还取这么个帖子标题。

不好意思，请指明如何修改题目？
作者: NaturalJ0     时间: 2007-3-17 00:40
call echo The OEM value is %%!OEM!%%
作者: willsion     时间: 2007-3-17 01:10


  Quote:
Originally posted by NaturalJ0 at 2007-3-17 12:40 AM:
call echo The OEM value is %%!OEM!%%

用call无效，去掉call后，输出结果为：
The OEM value is %_ASUS_%
The OEM value is %_LENOVO_%
The OEM value is %_SONY_%

假如把%%!OEM!%% 改为%!OEM!%，又变为空白值了。即输出为
The OEM value is
The OEM value is
The OEM value is
作者: NaturalJ0     时间: 2007-3-17 02:48
实际运行结果如下：
C:\Documents and Settings\J\桌面>type a.bat&echo =======================&a
@echo off
setlocal ENABLEDELAYEDEXPANSION

set asus=_ASUS_
set lenovo=_LENOVO_
set sony=_SONY_

set OEM=asus

for %%i in (asus lenovo sony) do (
    set OEM=%%i
    call echo The OEM value is %%!OEM!%%
    rem 以下对 !%OEM%! 进行处理
    )

pause

exit
=======================
The OEM value is _ASUS_
The OEM value is _LENOVO_
The OEM value is _SONY_
请按任意键继续. . .
作者: willsion     时间: 2007-3-17 03:31


  Quote:
Originally posted by NaturalJ0 at 2007-3-17 02:48 AM:
实际运行结果如下：
[code]

C:\Documents and Settings\J\桌面>type a.bat&echo =======================&a
@echo off
setlocal ENABLEDELAYEDEXPANSION

set asus=_ASUS_
set le ...

原来是我将原程序修改了，所以得不到正确结果。

现在又有问题了，要用call echo才能显示%%!OEM!%%的值，那如何才能将%%!OEM!%%的值赋值到其他变量，以便进行操作呢？

谢谢。
作者: NaturalJ0     时间: 2007-3-17 06:07
call set ...
作者: willsion     时间: 2007-3-17 06:18


  Quote:
Originally posted by NaturalJ0 at 2007-3-17 06:07 AM:
call set ...

用call set pp＝%%!OEM!%%
   echo The pp is !pp!

果然成功了。
非常感谢热心的NaturalJ0朋友！
作者: NaturalJ0     时间: 2007-3-17 06:24
客气了，这个用法，我也是跟这里的前辈们学的。
作者: scriptor     时间: 2007-3-17 21:55


  Quote:
Originally posted by willsion at 2007-3-16 09:24:
@echo off
setlocal ENABLEDELAYEDEXPANSION

set asus=_ASUS_
set lenovo=_LENOVO_
set sony=_SONY_

set OEM=asus

for %%i in (asus lenovo sony) do (
    set OEM=%%i
    echo The OEM value is ...

很显然，在变量列表中，是asus,lenovo,sony，而不是_ASUS_,_LENOVO_,_SONY_，
所以改一下变量列表就可以了。
for %%i in (!asus! !lenovo! !sony!) do (
  echo The OEM value is %%i
)
同时去掉那些画蛇添足的语句。并且那些语句会造成set资源浪费。
呵呵
作者: scriptor     时间: 2007-3-17 21:58
这位是犯了变量调用不清和重复调用的错误。

建议编程的时候不要对相似变量重复定义和调用。

用一个旧足以解决了。
作者: zh159     时间: 2007-3-17 23:57
按LZ用法，连变量延迟都可以不用：
@echo off
set asus=_ASUS_
set lenovo=_LENOVO_
set sony=_SONY_

for %%i in (%asus% %lenovo% %sony%) do (
    echo The OEM value is %%i
    )
pause
exit
作者: godicozy     时间: 2007-3-18 04:53
这就是高手啊，擦据。。