Board logo

标题: 如何对多个文本中的对应数据进行运算 [打印本页]
作者: xycoordinate     时间: 2007-2-26 04:18    标题: 如何对多个文本中的对应数据进行运算
1.txt
coun1=8
count2=3
count3=7

2.txt
count1=12
count2=17
count3=13

3.txt
count1=5
count2=15
count3=18

4.txt
count1=15
count2=25
count3=12

如何将4个文件中的count1，count2，count3，count4，分别相加计算出来？

得到result.txt
count1=40
count2=60
count3=50

PS：
因为实际的文件数目等于每月的天数，最好用
for /l %i in (1,1,4) do ...
作者: slore     时间: 2007-2-26 05:13
@echo off
set count1=0
set count2=0
set count3=0
for /l %%n in (1,1,4) do (
for /F "usebackq tokens=1,2 delims==" %%i in (%%n.txt) do (
set /a %%i=%%i+%%j
)
)
set count>Result.txt
作者: xycoordinate     时间: 2007-2-26 05:25
Originally posted by slore at 2007-2-25 04:13 PM:
@echo off
set count1=0
set count2=0
set count3=0
for /l %%n in (1,1,4) do (
for /F "usebackq tokens=1,2 delims==" %%i in (%%n.txt) do (
set /a %%i=%%i+%%j
)
)
set count>Result.txt



报错：
运算符不存在。
运算符不存在。
运算符不存在。
作者: slore     时间: 2007-2-26 05:27
那只能说你给的信息不全面。。。你自己下载我下面的东西你自己看吧。
附件 1: TempFolder.rar (2007-2-26 05:27, 647 bytes, 下载附件所需积分 1点 ,下载次数： 13)
作者: xycoordinate     时间: 2007-2-26 05:46
Originally posted by slore at 2007-2-25 04:27 PM:
那只能说你给的信息不全面。。。你自己下载我下面的东西你自己看吧。


谢谢！

是我搞错了！！！

扩展一下：
有n个文件，每个文件有m个count变量

@echo off
setlocal enabledelayedexpansion
set /p n=文件个数：
set /p m=变量个数：

for /l %%x in (1,1,!m!) do set Num%%x=0

for /l %%I in (1,1,!n!) do (
for /f "tokens=1,2 delims=count,=" %%i in (%%I.txt) do (
set /a Num%%i+=%%j
)
)

for /l %%x in (1,1,!m!) do @echo %%x !Num%%x! >>Num.txt


Num.txt
1 40
2 60
3 40

<img src="images/smilies/face-sad.png" align="absmiddle" border="0"><img src="images/smilies/face-sad.png" align="absmiddle" border="0"><img src="images/smilies/face-sad.png" align="absmiddle" border="0">
昨天，我想了一天就是那一句 set /a Num%%i+=%%j
我少了个/a

！！！
郁闷呀！！！

Last edited by xycoordinate on 2007-2-25 at 05:33 PM ]
作者: vkill     时间: 2007-2-26 10:42
@echo off
for /l %%? in (1,1,4) do (
set/p =count%%?=<nul
gawk -F= /^count%%?=/"{(t+=$2)}; END {print t}" *.txt
)
pause
作者: vkill     时间: 2007-2-26 10:50
Originally posted by slore at 2007-2-26 05:13:
@echo off
set count1=0
set count2=0
set count3=0
for /l %%n in (1,1,4) do (
for /F "usebackq tokens=1,2 delims==" %%i in (%%n.txt) do (
set /a %%i=%%i+%%j
)
)
set ...

set count>Result.txt 这句用的妙啊~
作者: xycoordinate     时间: 2007-2-26 22:55
set count>Result.txt 这句用的妙啊~

但是，如果有count11，count21。。。
result.txt就会是
count1=?
count11=?
count2=?
count22=?
count3=?
count4=?
.......

排列顺序好象有问题？？？！！！

Last edited by xycoordinate on 2008-1-14 at 09:35 AM ]
作者: slore     时间: 2007-2-27 06:39
Originally posted by xycoordinate at 2007-2-26 09:55:

但是，如果有counte11，count21。。。
result.txt就会是
count1=?
count11=?
count2=?
count22=?
count3=?
count4=?
.......

排列顺序好象有问题？？？！！！


如果那样我就分割，逐个输出。。。。

代码有的时候通用性强的好，有的时候还是针对自己要做的事写相对简捷有效的代码比较好。
作者: xycoordinate     时间: 2007-2-27 10:47
Originally posted by slore at 2007-2-26 05:39 PM:


如果那样我就分割，逐个输出。。。。

代码有的时候通用性强的好，有的时候还是针对自己要做的事写相对简捷有效的代码比较好。


愿听其详!!!<img src="images/smilies/face-wink.png" align="absmiddle" border="0">
作者: gne3     时间: 2007-2-27 11:06
顶啊，学习
作者: slore     时间: 2007-2-27 11:11
"tokens=1,2 delims=count,="

你自己不是用了？如果你说排序的问题那我用VB修正……
作者: lxmxn     时间: 2007-2-27 12:55
@echo off

set/p month=Please input the days of this month:

for /l %%a in (1,1,%month%) do (

	for /f "tokens=1,2 delims==" %%b in (%%a.txt) do (

		set /a %%b+=%%c

	)

)

set count

pause