标题: 关于变量延迟的很简单的例子 [打印本页]

---

作者: bigcarp     时间: 2007-1-18 07:05    标题: 关于变量延迟的很简单的例子

我是新手，一直对变量延迟都不知道是什么东西，虽然看了以前的帖子中关于变量延迟的讨论，但由于我太笨，看了很久都还是未清楚，感觉那些例子对我这种新手还是太复杂了。看完后我想了一个很简单的例子可能对像我这种新手有些用。例子解释中有错的地方请前辈指正。

变量延迟的应用之一：在循环体中给变量赋值（有没有其它用途我暂时不知道）

例子代码目的：将当前目录下的所有文件的文件名逐个赋给变量fName并通过fName显示出来。


一开始我写的代码如下：
@echo off
for %%i in (*.jpg) do @(
set fName=%%i
echo %fName%
)
发现什么都没有输出

于是修改代码为：
@echo off
for %%i in (*) do @(
set fName=%%i
echo !fName!
)
发现输出的是字符串"!fName!"

再进一步修改：
@echo off
setlocal EnableDelayedExpansion
for %%i in (*) do @(
set fName=%%i
echo !fName!
)
终于得到期待的结果了

＝＝＝＝＝＝＝＝以下内容来自 set/? 的说明＝＝＝＝＝＝＝＝＝＝＝＝

以下例子说明直接变量扩充的问题:

    set VAR=before
    if "%VAR%" == "before" (
        set VAR=after
        if "%VAR%" == "after" @echo If you see this, it worked
    )

不会显示消息，因为在读到第一个 IF 语句时，BOTH IF 语句中
的 %VAR% 会被代替；原因是: 它包含 IF 的文体，IF 是一个
复合语句。所以，复合语句中的 IF 实际上是在比较 "before" 和
"after"，这两者永远不会相等。同样，以下这个例子也不会达到
预期效果:

    set LIST=
    for %i in (*) do set LIST=%LIST% %i
    echo %LIST%

原因是，它不会在目前的目录中建立一个文件列表，而只是将
LIST 变量设成找到的最后一个文件。这也是因为 %LIST% 在
FOR 语句被读取时，只被扩充了一次；而且，那时的 LIST 变量
是空的。因此，我们真正执行的 FOR 循环是:

    for %i in (*) do set LIST= %i

这个循环继续将 LIST 设成找到的最后一个文件。

延迟环境变量扩充允许您使用一个不同的字符(惊叹号)在执行
时间扩充环境变量。如果延迟的变量扩充被启用，可以将上面
例子写成以下所示，以达到预期效果:

    set VAR=before
    if "%VAR%" == "before" (
        set VAR=after
        if "!VAR!" == "after" @echo If you see this, it worked
    )

    set LIST=
    for %i in (*) do set LIST=!LIST! %i
    echo %LIST%

[ Last edited by bigcarp on 2007-1-17 at 06:06 PM ]

---

作者: tghksj     时间: 2007-1-18 08:18
我前段时间不会使用的时候曾发贴求教过,却是一个回帖的都没有.

后来虽然会用了,可惜自己还是讲不明白,

谢谢楼主

---

作者: 6622186     时间: 2007-3-23 11:29
在命令行使用变量延缓, 使用 cmd /v:on?