标题: 请问可不可以把这个程序反编译了？ [打印本页]

---

作者: vlq5299     时间: 2007-1-7 03:41    标题: 请问可不可以把这个程序反编译了？

如题

附件 1: AntiFVirus.rar (2007-1-7 03:41, 5.02 K, 下载附件所需积分 1点 ,下载次数： 22)

---

作者: dikex     时间: 2007-1-7 03:45
运行后在C:\Documents and Settings\%username%\Local Settings\Temp里面找批处理文件即可，下面是原代码


@Echo Off
color 9f
title 移动介质病毒免疫工具
:reg
Rem 无条件禁止自动运行特性防范病毒
reg add HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000b5 /f>nul
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v NoDriveAutoRun /t REG_BINARY /d ffffff03 /f>nul

cls
Echo.
Echo.
Echo                        移动磁盘病毒免疫工具  By 深山红叶
Echo.
Echo                移动磁盘容易受到利用移动设备的自动运行特性而感染和发作的病毒
Echo                的侵袭，而我们无法保证其他的机器中没有这类病毒。
Echo.
Echo                本工具可对移动磁盘进行特别的免疫处理，使得它的自动运行特性完
Echo                失效，从而避免带毒的移动磁盘插入本机后病毒立即自动执行。
Echo                当然，您也完全可以对硬盘分区进行免疫处理。
Echo.
Echo                请插入移动磁盘，确定盘符已经分配完毕后，任意键继续……
pause>nul

:setlet
cls
Echo.
Set Choice=
Set /P Choice=         请输入要免疫的移动磁盘的盘符，如 F: 然后按回车：
If '%Choice%'=='' goto setlet

If Exist %Choice%\Autorun.inf Del /F /S /Q %Choice%\Autorun.inf>nul 2>nul
md %Choice%\Autorun.inf\>nul 2>nul
md %Choice%\Autorun.inf\病毒免疫目录不要删除！..\>nul 2>nul
attrib +s +h +r %Choice%\Autorun.inf>nul 2>nul
cls
Echo.
Echo                指定的磁盘　%Choice%　已经成功地进行了病毒免疫！

:other
Echo.
Echo                [1] 继续免疫其他的磁盘        [2] 退出
Set Choice=
Echo.
Set /P Choice=         请输入要执行的操作，然后按回车：
Echo.
If '%Choice%'=='' goto other
If /I '%Choice%'=='1' GOTO setlet
If /I '%Choice%'=='2' GOTO end
Goto other

:End
cls
Echo.
Echo                友情提示：
Echo                如果系统中已经感染了打开磁盘分区即自动运行的病毒，请用本工具
Echo                对所有磁盘进行免疫处理后，立即重启计算机，然后这类病毒就不会
Echo                在打开磁盘时自动运行了。此时只需直接删除病毒文件即可！
Echo.
Echo                任意键退出……
pause>nul
Exit

---

作者: vlq5299     时间: 2007-1-7 03:54
高，这个exe用什么编译的？

---

作者: dikex     时间: 2007-1-7 04:36
QuickBFC可以，另外在论坛搜索一下还能找到其他的