中国DOS联盟论坛 - Powered by Discuz! Board

标题: [在线求助]变量未定义的问题 [打印本页]

作者: HUNRYBECKY 时间: 2006-12-18 22:49 标题: [在线求助]变量未定义的问题

我想在CheckV.TXT中查找ACCESS字符串,如果找到就赋值给变量ACCESS,如果找不到则把值NO赋给变量,但是运用后这时则使用ECHO %ACCESS% 不能显示出改变量,说明变量NO没有赋给ACCESS,不知道是那里的错误,请求高手指点下.
我的代码如下:

@ECHO OFF
FOR /F %%I IN ('FINDSTR /I "ACCESS" "%TEMP%"\CheckV.TXT') DO (
SET ACCESS=%%I
IF /I NOT DEFINED I (SET ACCESS=NO)
)
ECHO %ACCESS%
PAUSE

其中CheckV.TXT的内容如下,这个文件的内容我是从一个网页文件中提取的(ACCESS运行的条件:主程序ACCESS,DAO ADO和JET及其版本):
Jet4.0
DAO3.60
ADO2.80
ACCESS2003

[ Last edited by HUNRYBECKY on 2006-12-19 at 02:08 AM ]

作者: ccwan 时间: 2006-12-18 23:18

@ECHO OFF

   FOR /F %%I IN ('FINDSTR /I "ACCESS" %TEMP%\CheckV.TXT') DO (

   SET ACCESS=%%I

   IF /I NOT DEFINED ACCESS (SET ACCESS=NO)

   )

   ECHO %ACCESS%

PAUSE

是否要定义的为ACCESS？

作者: ccwan 时间: 2006-12-18 23:27
好像有问题，存在ACCESS时没事，若找不到ACCESS就不行了。

作者: HUNRYBECKY 时间: 2006-12-18 23:28
是呀，所以怎么解决这个问题呢.我怎么试验也不行.

作者: HUNRYBECKY 时间: 2006-12-18 23:30

Quote:

Originally posted by ccwan at 2006-12-18 23:27:
好像有问题，存在ACCESS时没事，若找不到ACCESS就不行了。

如果找到ACCESS行我就赋找到的值给ACCESS变量,否则赋变量NO给ACCESS变量.

作者: redtek 时间: 2006-12-18 23:44
当那个 Findstr 找不到 ACCESS 字符串时，那个ｆｏｒ是取不出来结果的（空），
既然ｆｏｒ取到的是０行内容，那么ｆｏｒ中的语句不会被执行。

所以，ｆｏｒ一想：“怎么一行内容都没有读到啊？喔……干脆我甭执行了，退出吧……”。
于是ｆｏｒ以外（后面）的 Echo 就显示了一个未定义的变量：）

［怎么知道ｆｏｒ里面的语句没有执行？］

可以在那个For里面单独加一句：　Echo 没执行
然后运行代码，如果Findstr找不到　“ACCESS”　字符串，上面这句是显示不出来的，就说明它没有执行。

（ｆｏｒ /ｆ取不取内容再执行ｆｏｒ里面的语句显然没有实际用处）

[ Last edited by redtek on 2006-12-18 at 10:45 AM ]

作者: ccwan 时间: 2006-12-18 23:47
这样没问题了

@ECHO OFF

FOR /F "DELIMS=" %%I IN ('FINDSTR /I "ACCESS" %TEMP%\CheckV.TXT') DO (

IF NOT "%%I"=="" SET ACCESS=%%I&GOTO LOOK )

ECHO NO&PAUSE

GOTO :EOF

:LOOK

ECHO %ACCESS%

PAUSE

作者: NaturalJ0 时间: 2006-12-18 23:52
find /i "access" && set access=access || set access=no
不知道能不能满足楼主的要求。

PS：“但是运用后这时则使用ECHO %ACCESS% 不能显示出改变量” 这是什么语法？

作者: HUNRYBECKY 时间: 2006-12-19 00:00

Quote:

Originally posted by redtek at 2006-12-18 23:44:
当那个 Findstr 找不到 ACCESS 字符串时，那个ｆｏｒ是取不出来结果的（空），
既然ｆｏｒ取到的是０行内容，那么ｆｏｒ中的语句不会被执行。

扠...

分析的非常有道理.现在明白了，原来我钻进死牛角了，怎么也找不到这个

作者: HUNRYBECKY 时间: 2006-12-19 00:07

Quote:

Originally posted by NaturalJ0 at 2006-12-18 23:52:
find /i "access" && set access=access || set access=no
不知道能不能满足楼主的要求。

PS：“但是运用后这时则使用ECHO %ACCESS% 不能显示出改变量†...

find在文件查找后回返回文件的路径和找到的字符串,所以使用FIND无法实现的，但是可以使用FINDSTR解决这个问题;
access=access这个也是不行的.实际上我是查找包含ACCESS行的变量,如找到ACCESS97则ACCESS=ACCESS97,找到ACCESS2007则ACCESS=ACCESS2003,我的目的很明确就是为了检测ACCESS的版本问题;
ECHO %ACCESS% 如果没有改ACCESS变量则显示不错,而显示回显关闭什么的.

作者: HUNRYBECKY 时间: 2006-12-19 00:22

Quote:

Originally posted by ccwan at 2006-12-18 23:47:
这样没问题了
[code]@ECHO OFF
FOR /F "DELIMS=" %%I IN ('FINDSTR /I "ACCESS" %TEMP%\CheckV.TXT') DO (
IF NOT "%%I"=="" SET ACCESS=%%I&GOTO LOOK )
...

我的问题不是当没有的时候就不显示而是必须把值赋给ACCESS,即ACCESS=NO

作者: ccwan 时间: 2006-12-19 00:25

@ECHO OFF

FOR /F %%I IN ('FINDSTR /I "ACCESS" %TEMP%\CheckV.TXT') DO (

IF NOT "%%I"=="" SET ACCESS=%%I&GOTO LOOK )

SET ACCESS=NO

ECHO %ACCESS%&PAUSE

GOTO :EOF

:LOOK

ECHO %ACCESS%

PAUSE

作者: HUNRYBECKY 时间: 2006-12-19 00:27
问题已经解决,根据REDTEK兄弟的提示,修改为以下代码就OK了:
@ECHO OFF
FOR /F "DELIMS=" %%I IN ('FINDSTR /I "ACCESS" %TEMP%\CheckV.TXT') DO (
IF NOT "%%I"=="" SET ACCESS=%%I)
IF NOT DEFINED ACCESS SET ACCESS=NO
ECHO %ACCESS%
PAUSE

这里不能使用IF NOT DEFINED I SET ACCESS=NO 因为正如REDTEK兄弟所说的,变量I实际上是在FOR语句中,而DEFINED则是在FOR之外,所以开始用I不行,改为FOR就可以了

另外大家想想能否直接使用FINDSTR实现,关键点在于如何把FINDSTR返回的值赋给一个变量ACCESS.

作者: HUNRYBECKY 时间: 2006-12-19 00:29

Quote:

Originally posted by ccwan at 2006-12-19 00:25:
[code]@ECHO OFF
FOR /F %%I IN ('FINDSTR /I "ACCESS" %TEMP%\CheckV.TXT') DO (
IF NOT "%%I"=="" SET ACCESS=%%I&GOTO LOOK )
SET ACCESS=NO
ECHO %ACCESS%&PAUSE
...

谢谢兄弟,代码测试OK

作者: redtek 时间: 2006-12-19 01:56
另一种方法：

@echo off && set "access=NO"

for /f %%i in ('findstr /i "ACCESS" "%temp%\CheckV.txt"') do set access=%%i

echo %access%

pause

先赋值给 access=NO
然后再执行ｆｏｒ读出那个你要的数据。假如就算 Findstr 没找到 "ACCESS" 也没关系，顶多ｆｏｒ中 access 变量没被赋值。

但是，ｆｏｒ之前已经被赋初值ＮＯ了，所以后面 FOR 不成功就是ＮＯ，如果成功找到了那么ACCESS=NO的原值会被FOR中的值取代～：）

（多谢版主提醒，我也忘记加引号了，刚刚补上～：）

[ Last edited by redtek on 2006-12-18 at 01:09 PM ]

作者: namejm 时间: 2006-12-19 02:00
　　就你顶楼的代码提两点建议：
　　1、加上变量延迟语句；
　　2、%tmp% 路径若带空格，则应带引号。

　　若要把 findstr 的返回值赋予一个变量，请把你的 CheckV.TXT 内容张贴出来。

作者: HUNRYBECKY 时间: 2006-12-19 02:04

Quote:

Originally posted by redtek at 2006-12-19 01:56:
另一种方法：

@echo off && set "access=NO"

for /f %%i in ('findstr /i "ACCESS" %temp%\CheckV.txt') do set access=%%i

echo %access%

pause

...

的确高明.先赋值的方法值得提倡.

作者: HUNRYBECKY 时间: 2006-12-19 02:05

Quote:

Originally posted by namejm at 2006-12-19 02:00:
　　就你顶楼的代码提两点建议：
　　1、加上变量延迟语句；
　　2、%tmp% 路径若带空格，则应带引号。

　　若要把 findstr 的返回值赋予一个变頮..

谢谢斑竹的规范.好马上改.

作者: ccwan 时间: 2006-12-19 02:08
redtek兄比我高很多啊！

作者: redtek 时间: 2006-12-19 02:17
ccwan兄太谦虚了～：）
我只不过是没跟着HUNRYBECKY兄１楼代码的思路走，没受“原思想”干扰，才用了另一种方法：）