中国DOS联盟

Now I'm using the One-key GHOST hard disk version, and it will create a folder named ~1 in the last partition of the first hard disk. If it's in FAT32 format, you can't see it even if you show system files!
I'd like to ask all the experts how to create this folder???
Brother here thanks in advance!

Using IBM One-Click Restore R&R is very easy. Make a batch file that contains ghost.exe. After pressing F11, you can choose to backup or restore. The following is my one-click system restore batch file.

@ECHO OFF
set EXPAND=YES
SET DIRCMD=/OGN /4 /P
set CDROM=R
set CDUSB=W
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
rem set RAMD=X
cls
call setramd.bat %LglDrv%
cls
rem xmsdsk 4096 %ramd%: /y /t >NUL
set temp=%RAMD%:\temp
set tmp=%RAMD%:\temp
PATH=%RAMD%:\;%CDROM%:\;%CDUSB%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL

:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert MS-DOS 7.10 Startup Disk 2
echo.
pause
GOTO ERROR

:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
@echo off
LH %RAMD%:\TW.EXE /np >NUL

if "%config%"=="RR" goto RR
if "%config%"=="DOS" goto DOS

:RR
c:
cls
echo.
echo.
echo. Welcome to the One-Click Restore System (Made by Kaven Lee)
echo. ================================================
echo.
echo.
echo.
echo 1、 Restore your operating system and all applications
echo 2、 Restore your files
echo 3、 Backup your operating system and all applications
echo 4、 Backup your files
echo 5、 Enter DOS system
echo 6、 Restart the system
echo.
echo.
echo.
echo.
CHOICE /C:123456 /t:6,15 Please choose the operation you want to perform
If errorlevel=6 goto REBOOT
If errorlevel=5 goto DOS1
if errorlevel=4 goto BACKUPFI
If errorlevel=3 goto BACKUP
If errorlevel=2 goto RECFILES
If errorlevel=1 goto RECOVERY

:RECOVERY
@ECHO OFF
cls
echo.
echo.
echo The computer will restore your system to the state of the last normal use, please wait...
echo ==========================================================
@echo off
wait 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pload,src=c:\windows\win.gho:1,dst=1:1 -sure
ghost -clone,mode=pload,src=c:\windows\prog.gho:1,dst=1:3 -sure -rb
goto END

:RECFILES
@ECHO OFF
cls
echo.
echo.
echo The computer will restore your files to the state of the last backup, please wait...
echo ==========================================================
@echo off
wait 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pload,src=c:\windows\files.gho:1,dst=1:4 -sure -rb
goto END


:BACKUP
@echo off
cls
echo.
echo.
echo The computer is preparing to backup the system you are using, please wait...
echo ================================================
WAIT 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pdump,src=1:1,dst=c:\windows\win.gho -z9 -auto -sure
ghost -clone,mode=pdump,src=1:3,dst=c:\windows\prog.gho -z9 -auto -sure
ghost -clone,mode=pdump,src=1:4,dst=c:\windows\files.gho -z9 -auto -sure -rb
goto END

:BACKUPFI
@echo off
cls
echo.
echo.
echo The computer is preparing to backup your files, please wait...
echo ==========================================
wait 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pdump,src=1:4,dst=c:\windows\files.gho -z9 -auto -sure -rb
goto END

:DOS
c:
cls
echo.
echo.
echo. Welcome to the DOS operating system, please choose:
echo. =============================
echo.
echo.
echo.
echo. 1、 Enter DOS
echo. 2、 Restart the system
echo. 3、 Shut down the system
echo.
echo.
echo.

CHOICE /C:123 /t:3,15 Please choose:
If errorlevel=3 goto SHUTDOWN
If errorlevel=2 goto REBOOT
If errorlevel=1 goto DOS1

:DOS1
LH %ramd%:\Shsucdx.exe /D:?IDE-CD %CDROM% /D:?FWR-CD %CDROM% /D:?USB-CD %CDUSB%
copy ZENO.EXE %RAMD%:\ > NUL
copy MENU\*.* %RAMD%:\ > NUL
copy DOSKEY.COM %RAMD%:\ > NUL
copy MOUSE.EXE %RAMD%:\ > NUL
LH %RAMD%:\ZENO.EXE /Q > NUL
LH %RAMD%:\DOSKEY.COM > NUL
LH %RAMD%:\KILLER.EXE > NUL
LH %RAMD%:\ESCAPE.EXE > NUL
LH %RAMD%:\MOUSE.EXE /W > NUL
LH %RAMD%:\Key.com WB PY LX > NUL
call %RAMD%:\M.bat
c:\fshare
goto END

:REBOOT
@echo off
cls
echo.
echo.
echo The system will now restart, please wait...
echo ================================
@echo off
wait 5
shutdown r
goto END

:SHUTDOWN
@echo off
cls
echo.
echo.
echo The system will now shut down, please wait...
echo ============================
@echo off
wait 5
shutdown s
goto END

:END
C:

The expert at the 2nd floor, I did as you said, but why isn't it working?

Oh, I forgot to tell everyone that this is just a batch processing program. The following work still needs to be done:
(1) In addition to the C: drive being the primary partition, another primary partition needs to be divided after the C: drive, that is, the D: drive (note that it must be a primary partition, not a logical partition). And set the Label to: IBM_SERVICE.
(2) Use PQ to hide the C: drive and activate the D: drive as the active drive.
(3) Restart the computer with a floppy disk, USB flash drive, or CD, and transfer the system to the C: drive (actually the D: drive, because the C: drive has been hidden just now)
(4) Run the IBM one-click recovery software
Then save the batch processing in the 2nd floor as autoexec.bat.

I can't upload the IBM R&R. Please search online and download it directly.

http://www.cn-dos.net/forum/viewthread.php?tid=29478&fpage=1&highlight=one%20ghost&page=1