中国DOS联盟

Originally posted by HAT at 2008-9-20 05:30 AM:
那就用2楼的思路吧

@echo off

setlocal enabledelayedexpansion

set /p "str=请输入:"

set sum=0

:loop

set "char=%str:~0,1%"

for /f "skip=1 delims=:" ... 



这个没有用，不管输入什么批处理都会退出

Last edited by tireless on 2008-9-20 at 01:33 PM ]

归根结底就是findstr的正则太肉

再试试这个如何?
改一下,支持特殊字符:

@echo off

setlocal enabledelayedexpansion

:bgn

type nul>t_.txt

set "n="&set "count="

set /p str=请输入:

:agn

>>t_.txt echo.!str:~,1!

if not "!str:~1!"=="" (set "str=!str:~1!"&goto :agn)

>>t_.txt echo god

for /f "delims=:" %%a in ('findstr /o .* t_.txt') do (

   set /a "n+=1","m=n-1"

   set "_!n!=%%a"

   if !n! geq 2 (

      call set /a "var=%%_!n!%%-%%_!m!%%"

      if !var! equ 4 (set /a count+=19) else (set /a count+=10)

   )

)

echo %count%

goto :bgn

Last edited by moniuming on 2008-9-21 at 10:27 AM ]

计算不正确。

床前明月光，疑是地上霜。举头望明月，低头思故乡。 的计算结果是 240。正确的应该是 456。

@echo off

setlocal enabledelayedexpansion

:bgn

del t_.txt 1>nul 2>nul

set "n="&set "count="

set /p str=请输入:

:agn

set st=!str:~,1!

>>t_.txt echo.!st!

if not "!str:~1!"=="" (set "str=!str:~1!"&goto :agn)

>>t_.txt echo god

for /f "delims=:" %%a in ('findstr /o .* t_.txt') do (

   set /a "n+=1","m=n-1"

   set "_!n!=%%a"

   if !n! geq 2 (

      call set /a "var=%%_!n!%%-%%_!m!%%"

      if !var! equ 4 (set /a count+=19) else (set /a count+=10)

   )

)

echo %count%

goto :bgn

Last edited by moniuming on 2008-9-21 at 11:41 AM ]

15楼代码的运行结果：

C:\Test>test.bat
请输入:床前明月光，疑是地上霜。举头望明月，低头思故乡。
456

能把你的测试用例和测试结果贴出来看看吗？

额，15 楼的代码有用。计算太慢了，昨晚我以为批处理没有反应，没等结果出来就关掉了...

经多次测试，20楼的通过各种测试，而且效率还可以，试试？

Last edited by moniuming on 2008-9-21 at 11:55 AM ]

最后一次整合...

20 楼的代码完全不会出错。我想在原基础上再加上一些命令处理，可是我写的代码有点问题，所以再麻烦下各位，顺便整合在一起。

想在原基础上再进行这些处理：
1、还要显示输入的是什么
2、输入后，首先进行这些判断：
如果：
直接回车，则执行命令
输入的是 /h，则执行命令然后退出
输入的是 /s，则执行命令然后退出
输入的是 /r，则执行命令然后退出
再判断下面的：
是否以 /h 开头，如果是，则截取 /h 后面的字符，然后执行命令
是否以 /s 开头，如果是，则截取 /s 后面的字符，然后执行命令

以下是我修改后的代码：
■: 原 20 楼的代码 ■: 我加上的

@echo off
setlocal enabledelayedexpansion
:bgn
del t_.txt 1>nul 2>nul
set "n="&set "count="
set /p str=请输入:
if not defined str goto 11
If %str%==/h 执行命令 & exit
If %str%==/s 执行命令 & exit
If %str%==/r 执行命令 & exit
if /i "%str:~,2%"=="/h" (
set str=%str:~2%
执行命令
goto settext
)
if /i "%str:~,2%"=="/s" (
set str=%str:~2%
执行命令
)
:settext
set Text=%str%
:agn
set st=!str:~,1!
>>t_.txt echo.!st!
if not "!str:~1!"=="" (set "str=!str:~1!"&goto :agn)
>>t_.txt echo god
for /f "delims=:" %%a in ('findstr /o .* t_.txt') do (
set /a "n+=1","m=n-1"
set "_!n!=%%a"
if !n! geq 2 (
call set /a "var=%%_!n!%%-%%_!m!%%"
if !var! equ 4 (set /a count+=19) else (set /a count+=10)
)
)
echo %count%
echo %text%
goto :bgn
:11
...

测试结果是，有空格就会出错。
（错误不出在别处，就在我添加的那段里运行中断了）

Last edited by tireless on 2008-9-21 at 01:53 AM ]

If %str%==/h 执行命令 & exit
...
if /i "%str:~,2%"=="/h"

怎么后面知道加引号，前面为何不加

怎么后面知道加引号，前面为何不加

加上引号后，输入空格没有问题了。却还有另外的问题：

请输入:(*^__^*) 嘻嘻……
此时不应有 嘻嘻……。

请输入:(**) 嘻嘻
此时不应有 嘻嘻。

请输入:O(∩_∩)O哈哈
此时不应有 O哈哈。

请输入:O(∩_∩)O
此时不应有 O。

是什么原因？

用以下代码做测试：

@echo off

:s

set /p str=请输入:



if not defined str echo 未定义&goto :s

If "%str%"=="/h" echo 执行/h命令&goto :s

If "%str%"=="/s" echo 执行/s命令&goto :s

If "%str%"=="/r" echo 执行/r命令&goto :s

if /i "%str:~,3%"=="/h " (

  set str=%str:~3%

  echo 执行/h命令

  goto showtext

)

if /i "%str:~,3%"=="/s " (

  set str=%str:~3%

  echo 执行/s命令

)



:showtext

echo %str%

goto s

Last edited by tireless on 2008-9-21 at 02:52 PM ]

试试?

@echo off

Setlocal Enabledelayedexpansion

:s

set "str="

set /p str=请输入:

if not defined str echo 未定义&goto :s

If /i "!str!"=="/h" echo 执行/h命令&goto :s

If /i "!str!"=="/s" echo 执行/s命令&goto :s

If /i "!str!"=="/r" echo 执行/r命令&goto :s

if /i "!str:~,3!"=="/h " (

  set "str=!str:~3!"

  echo 执行/h命令

  goto showtext

)

if /i "!str:~,3!"=="/s " (

  set "str=!str:~3!"

  echo 执行/s命令

)

:showtext

echo !str!

goto s

Last edited by moniuming on 2008-9-22 at 12:03 PM ]

没问题了。

谢谢大家耐心的帮助。