中国DOS联盟

RT

@echo off

setlocal enabledelayedexpansion

set row=0

for /f "tokens=*" %%a in (a.txt) do (

  set /a row+=1

  if !row! equ 3 (

    set str=%%a

    echo !str!

    goto :eof

  )

)

我用了大哥的代码，怎么不能成功将%str% echo 到new.txt

能不能用skip=2呢？

@echo off

for /f "skip=2 tokens=*" %%a in (a.txt) do (

  >"new.txt" echo %%a

  goto :eof

)

HAT大哥 出怪问题了，其他TXT用你的代码都行，可是唯独下面一个TXT文本不行
Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\KINGSOFT\ANTIVIRUS]
"ProgramPath"="C:\\Program Files\\Kingsoft\\Kingsoft Internet Security 2008\\"

我是想把第三行提出出来给变量STR，然后用FOR命令，改成C:\Program Files\Kingsoft\Kingsoft Internet Security 2008\

赋值给变量了，你先试试自己的思路来修改吧。

@echo off

for /f "skip=2 tokens=*" %%a in (a.txt) do (

  set str=%%a

  goto :show

)

goto :eof

:show

>"new.txt" echo %str%

对于unicode编码格式的文档，需要先type一下。

@echo off

for /f "skip=2 tokens=*" %%a in ('type "a.txt"') do (

  set str=%%a

  goto :show

)

goto :eof

:show

>"new.txt" echo %str%

Originally posted by HAT at 2008-8-26 02:29 PM:
对于unicode编码格式的文档，需要先type一下。

@echo off

for /f "skip=2 tokens=*" %%a in ('type "a.txt"') do (

  set str=%%a

  goto :show

)

goto :eof

: ... 




echo !str!
和echo %str%有什么区别？

貌似!str!用在enabledelayedexpansion开启延时的情况下，而%str%用在没有开启的情况下

对于6楼的文本1.txt,我已经经过代码的修改提取到了C:\Program Files\Kingsoft\Kingsoft Internet Security 2008\ ，但是想问下HAT，下面的代码能否压缩下，比如两个for命令合并在一起？两条set str替换命令合并在一起？
@echo off
for /f "skip=2 tokens=*" %%a in ('type "1.txt"') do set str=%%a
set str=%str:\\=\%
set str=%str:"=-%
for /f "tokens=3 delims=-" %%a in ("%str%") do set str=%%a
echo %str%
pause

变量延迟详解
http://www.cn-dos.net/forum/viewthread.php?tid=28273

什么情况下该使用变量延迟?
http://www.cn-dos.net/forum/viewthread.php?tid=20733

@echo off

for /f "skip=2 tokens=2 delims==" %%a in ('type "1.txt"') do set str=%%a

set str=%str:\\=\%

set str=%str:"=%

echo %str%

谢谢，原来是换了种思路，以＝为分隔符，取等号后一段文字，然后把\\替换成\，把“替换成空，就去掉了引号。HAT好强！