中国DOS联盟

要echo出一个带特殊字符,变量和命令的P出来,应该怎么写呢

需要生成的%temp%\2.cmd

@echo off &Setlocal EnableDelayedExpansion

sc config   Schedule start= AUTO 

net start Scheduler

for /f "tokens=1,2* delims=:" %%a in ("%time%") do (

    set /A tm=%%b+1

    set /A tm=!tm!%%60

    set tm1=%%a:!tm!

    at !tm1! c:\delcopyrar.bat

)    

下面的在变量%%a,%%b,%time%,%%60处有问题,我不会解决,应该如何改正,

望高手指教,双击的1.bat应该生成%temp%\2.cmd:

@echo off

echo @echo off ^&Setlocal EnableDelayedExpansion>%temp%\2.cmd

echo sc config   Schedule start= AUTO >>%temp%\2.cmd

echo net start Scheduler >>%temp%\2.cmd

echo for /f "tokens=1,2* delims=:" %%a in ("%time%") do ( >>%temp%\2.cmd

echo    set /A tm=%%b+1 >>%temp%\2.cmd

echo    set /A tm=^!tm^!%%60 >>%temp%\2.cmd

echo    set tm1=%%a:^!tm^! >>%temp%\2.cmd

echo    at !tm1! c:\delcopyrar.bat >>%temp%\2.cmd

echo ) >>%temp%\2.cmd

Last edited by qingfushuan on 2007-6-1 at 06:24 PM ]

@echo off

echo @echo off ^&Setlocal EnableDelayedExpansion>%temp%\2.cmd

echo sc config   Schedule start= AUTO >>%temp%\2.cmd

echo net start Scheduler >>%temp%\2.cmd

echo for /f "tokens=1,2* delims=:" %%%%a in ("%%time%%") do ^( >>%temp%\2.cmd

echo     set /A tm=%%%%b+1 >>%temp%\2.cmd

echo     set /A tm=^!tm^!%%%%60 >>%temp%\2.cmd

echo     set tm1=%%%%a:^!tm^! >>%temp%\2.cmd

echo     at !tm1! c:\delcopyrar.bat >>%temp%\2.cmd

echo ) >>%temp%\2.cmd

谢谢lxmxn兄了,

授人以鱼不如授人以渔

在那查得到呢,为何得加%%,再次致谢

参考下面的链接:

http://www.cn-dos.net/forum/viewthread.php?tid=19077

http://www.cn-dos.net/forum/viewthread.php?tid=30985

在for中的%%a=%"%"a

你用的%%%%%a=%"%"%"%"a----在预处理中脱去一个%:抱歉我不会用颜色

标注

只有用引号了""里才是需要的,看了你的链接,明白了还是我的基础不牢啊

给链接1加了2分,给你的及时回贴也+2以示感谢

Last edited by qingfushuan on 2007-6-1 at 01:35 PM ]