中国DOS联盟

@echo off
:: 算法：基姆拉尔森计算公式
:: W= (d+2*m+3*(m+1)/5+y+y/4-y/100+y/400) mod 7
:: 把一月和二月看成是上一年的十三月和十四月
:: 例：如果是2004-1-10则换算成：2003-13-10来代入公式计算。

:: 输入的日期格式为：年-月-日(-可以替换为:、/，可以混用)
:: 在日历里面，★=当天

:: 支持多种格式的日期输入：
:: ① 若只输入一个数，则认为是查询当年月份，自动截取后两位数字查询，★标在1日上；
:: ② 若输入两个数，则认为是查询年和月，★标在1日上；
:: ③ 输全的话，★标在指定日期上

:: 关于年份的转换：
:: ① 若年份上输入的是两位数，则作如下转换：
::     50~99判定为19xx
::     00~49判定为20xx
:: ② 若输入的年份不是两位的，则把年份前面的所有0去掉之后，
::    计算该年份的日期；

color 27
mode con cols=40 lines=20
setlocal enabledelayedexpansion
set str=日一二三四五六
set sdate=%date%

:Main
cls&echo.
:: 日期提取、格式化与校验
for /f "tokens=1,2,3 delims=-/: " %%i in ("%sdate%") do (
    (set sy=%%i) && (set sm=%%j) && (set sd=%%k)
)
if not defined sd set sd=1
if not defined sm set sm=%sy%& set sy=%date:~0,4%
(set sm=10%sm%) && (set sd=10%sd%)
(set sm=%sm:~-2%) && (set sd=%sd:~-2%)
set y=%sy%
set /a m=1%sm%-100, d=1%sd%-100
if not "%sy:~2%"=="" goto check
if "%sy:~1%"=="" goto check
set sy=00%sy%
set sy=%sy:~-2%
set /a y=1%sy%-100
if %y% lss 50 (set /a y+=2000) else (set /a y+=1900)
set sy=%y%
:check
for %%i in (%y% %m% %d%) do (
    if %%i equ 0 echo.错误的日期.&pause>nul&set sdate=%date%&goto Main
)
for /f "delims=0 tokens=*" %%i in ("%sy%") do set /a sy=%%i,y=%%i
if %m% geq 13 (echo.错误的日期.&pause>nul&set sdate=%date%&goto Main)
if %d% geq 32 (echo.错误的日期.&pause>nul&set sdate=%date%&goto Main)

:: 计算每个月的天数
set days=31
for %%i in (4 6 9 11) do if %m% equ %%i set days=30
:: 计算2月份的偏差
set /a leap="^!(y%%4) & ^!(^!(y%%100)) | ^!(y%%400)"
if %m% equ 2 set /a days=28+%leap%
if %m% leq 2 (set /a y-=1& set /a m+=12)
:: 计算指定日期的星期数
set /a w=(d+2*m+3*(m+1)/5+y+y/4-y/100+y/400+1)%%7
::set /a w=(%d%+2*%m%+3*(%m%+1)/5+%y%+%y%/4-%y%/100+%y%/400+1)%%7

set prmt=当天
if "%sy%-%sm%-%sd%"=="%date%" set prmt=今天
echo.   %sy%年%sm%月  %prmt%:%sy%-%sm%-%sd%,星期!str:~%w%,1!
echo.

:: 生成日期数序列
set /a wb=(w+35-d) %% 7, we=wb+days+1, day=1
echo.    日   一   二   三   四   五   六
echo. ━━━━━━━━━━━━━━━━━━━
set /p= <nul
if %wb% equ 6 (set begin=7) else set begin=0
for /l %%i in (%begin%,1,37) do (
    set "temp=  "
    if %%i GTR %wb% if %%i LSS %we% (
        set temp= !day!
        set temp=!temp:~-2!
        if !d! EQU !day! set temp=★
        set /a day+=1
    )
    set /p=   !temp!<nul
    if !day! gtr !days! goto end
    set /a "wm=(%%i+1)%%7"
    if !wm! equ 0 echo.&echo.&set /p= <nul
)
:end
echo.
echo  ━━━━━━━━━━━━━━━━━━━
echo. 输入日期可以看当月日历及显示当日星期
echo.
set sdate=
set /p sdate= 格式如：07-02-03，[回车]退出:
if defined sdate goto Main

:: 月历查询工具 中国DOS联盟专用版 转载请注明版权
:: 原创：zjl5  更新：namejm, qzwqzw 2007-06-03

:: 算法：基姆拉尔森计算公式
:: W= (d+2*m+3*(m+1)/5+y+y/4-y/100+y/400) mod 7
:: 把一月和二月看成是上一年的十三月和十四月
:: 例：如果是2004-1-10则换算成：2003-13-10来代入公式计算。

:: 输入的日期格式为：年-月-日(-可以替换为:、/，可以混用)
:: 在日历里面，★=当天

:: 支持多种格式的日期输入：
:: ① 若只输入一个数，则认为是查询当年月份，自动截取后两位数字查询，★标在1日上；
:: ② 若输入两个数，则认为是查询年和月，★标在1日上；
:: ③ 输全的话，★标在指定日期上

:: 关于年份的转换：
:: ① 若年份上输入的数字少于三位，则作如下转换：
::     50~99判定为19xx
::     0~49判定为20xx
:: ② 若输入的年份数字超过两位，则截取后四位字符(不足部分在高位补0)，
::    按 ① 的规则计算该年份的日期；

@echo off
color 3F
mode con cols=40 lines=20
setlocal enabledelayedexpansion
set str=日一二三四五六
set sdate=%date%

:Main
cls&echo.
:: 日期提取、格式化与校验
for /f "tokens=1,2,3 delims=-/: " %%i in ("%sdate%") do (
    (set sy=%%i) && (set sm=%%j) && (set sd=%%k)
)
if not defined sd set sd=1
if not defined sm set sm=%sy%& set sy=%date:~0,4%

(set sy=0000%sy%) && (set sm=00%sm%) && (set sd=00%sd%)
(set sy=%sy:~-4%) && (set sm=%sm:~-2%) && (set sd=%sd:~-2%)
cd.
set /a y=1%sy%-10000, m=1%sm%-100, d=1%sd%-100 2>nul
if errorlevel 1 goto Error
if %y% lss 100 (
    if %y% lss 50 (set /a y+=2000) else (set /a y+=1900)
    set sy=!y!
)
if %m% lss 13 if %d% lss 32 goto Calc

:Error
echo.错误的日期.
pause>nul
set sdate=%date%
goto Main

:Calc
:: 计算每个月的天数
set days=31
for %%i in (4 6 9 11) do if %m% equ %%i set days=30
:: 计算2月份的偏差
set /a leap="^!(y%%4) & ^!(^!(y%%100)) | ^!(y%%400)"
if %m% equ 2 set /a days=28+%leap%
if %m% leq 2 (set /a y-=1& set /a m+=12)
:: 计算指定日期的星期数
set /a w=(d+2*m+3*(m+1)/5+y+y/4-y/100+y/400+1)%%7

echo.  %sy%年%sm%月  查询日:%sy%-%sm%-%sd%,星期!str:~%w%,1!
echo.
:: 生成月历
set /a wb=(w+35-d) %% 7, we=wb+days+1, day=1
echo.    日   一   二   三   四   五   六
echo. ━━━━━━━━━━━━━━━━━━━
set /p= <nul
for /l %%i in (0,1,37) do (
    set "temp=  "
    if %%i GTR %wb% if %%i LSS %we% (
        set temp= !day!
        set temp=!temp:~-2!
        if !d! EQU !day! set temp=★
        set /a day+=1
    )
    set /p=   !temp!<nul
    set /a "wm=(%%i+1)%%7"
    if !wm! equ 0 echo.&echo.&set /p= <nul
)
echo.
echo  ━━━━━━━━━━━━━━━━━━━
echo.  输入日期可查询当日星期并显示当月月历
echo.
set sdate=
set /p sdate=  格式如：07-02-03，[回车]退出:
if defined sdate goto Main

@echo off&setlocal enabledelayedexpansion
set sx=猴鸡狗猪鼠牛虎兔龙蛇马羊
set tg=庚辛壬癸甲乙丙丁戊己
set dz=申酉戌亥子丑寅卯辰巳午未
set /p year=请输入农历年:
set /a sxnum=%year% %% 12
set /a tgnum=%year:~-1%
echo/&echo %year%年生肖是:!sx:~%sxnum%,1!    农历 !tg:~%tgnum%,1!!dz:~%sxnum%,1! 年
echo/&echo 按任意键算出从1800-2500年中属!sx:~%sxnum%,1!的年份.
pause>nul&set n=1799&echo/
:a
set /a n+=1
set /a ynum=!n! %% 12
set /a tgnum=!n:~-1!
if !n! equ 2500 ECHO -结束,按任意键退出.&pause>nul&exit
if !ynum! equ !sxnum! (echo 属!sx:~%sxnum%,1!的年份还有 !n! 年    农历 !tg:~%tgnum%,1!!dz:~%ynum%,1! 年&goto :a) else (goto :a)