中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net  论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客:  注册 | 登录 | 命令行 | 会员 | 搜索 | 上传 | 帮助 »
中国DOS联盟论坛 » DOS媒体世界 & 网络技术 （多媒体室） » 回复所有的DOS下联网问题的帖子
« [1] [2] » ›
作者:
标题: 回复所有的DOS下联网问题的帖子 上一主题 | 下一主题
lizhenduo
初级用户




积分 190
发帖 29
注册 2003-6-24
状态 离线
『楼 主』:  回复所有的DOS下联网问题的帖子

看了DOS下联网启动盘的帖子。有些问题如扫描多种网卡并加载驱动，输入ip地址等似乎没有很好地解决。我找到了一个renda的DOS下联网启动盘，用了一下，觉得不错。现把说明贴出来，供朋友们参考。
我在 autoexec.bat 里看不懂它的扫描多种网卡并加载驱动和输入ip地址的方法，期盼版主几各位大家给予分析。在此多多拜托。谢谢

来源 http://spaces.msn.com/davidrin/b ... 9.entry?_c=BlogPart

config.sys:
; DOSNETX/7 DOS CONFIG File for MSDOS 7.10
; (c) 2007, David Rin <rendaa@gmail.com>
; Rev. 6.70216

[DOSOPT]
DEVICE=\DOS\HIMEM.SYS /TESTMEM:OFF /SHADOWRAM:OFF
DEVICE=\DOS\EMM386.EXE NOEMS I=B000-B7FF VERBOSE
INCLUDE=DOSCFG

[DOSAPP]
DEVICEHIGH /s=\DOS\IFSHLP.SYS
DEVICEHIGH /s=\DOS\ELTORIT0.SYS /D:EMUCD$
INSTALL=\DOS\XMSDSK.EXE v: 16000 /t /y

[DOSCFG]
DOS=HIGH,UMB,AUTO
SHELL=COMMAND.COM /p /e:1024 /f
STACKSHIGH=9,256
BUFFERSHIGH=30,0
FILESHIGH=30
FCBSHIGH=4,0
LASTDRIVEHIGH=Z
SWITCHES=/F /N
INCLUDE=DOSAPP
SET PATH=\DOS

[MENU]
MENUITEM=DOSOPT,DOS only, with utilities cached to ramdisk
SUBMENU =DATDRV,Data Storage support (CDROM/USBHD/UDMA etc.)
MENUITEM=NETOPT,Network support only
SUBMENU =NETCD ,Network + IDE/USB/PCMCIA CDROM support
SUBMENU =NAKED ,Clean boot for update bios (edit.com available)
MENUDEFAULT=NETCD,5

[RAMFD]
DEVICEHIGH /s=\DOS\RAMFD.SYS

[IDE]
INCLUDE=DOSOPT
DEVICEHIGH /s=\DOS\IDECDROM.SYS /D:IDECD$
SET DSKDEV=IDE

[USB]
INCLUDE=DOSOPT
INCLUDE=RAMFD
DEVICEHIGH /s=\DOS\USBASPI.SYS /norst /w /r /v /f
DEVICEHIGH /s=\DOS\USBCD.SYS /D:USBCD$
DEVICEHIGH /s=\DOS\DI1000DD.SYS
DEVICEHIGH /s=\DOS\IDECDROM.SYS /D:IDECD$
SET DSKDEV=USB

[FW]
INCLUDE=DOSOPT
INCLUDE=RAMFD
DEVICEHIGH /s=\DOS\SBP2ASPI.SYS
DEVICEHIGH /s=\DOS\NJ32DISK.SYS
DEVICEHIGH /s=\DOS\CDSDMINI.SYS /D:FWCD$
DEVICEHIGH /s=\DOS\IDECDROM.SYS /D:IDECD$
SET DSKDEV=FW

[PCM]
INCLUDE=DOSOPT
INCLUDE=RAMFD
;Read %RAMDRIVE%\NET\README.TXT for driver parameters.
DEVICEHIGH /s=\DOS\PCMI80CL.SYS /P1 /QA
DEVICEHIGH /s=\DOS\STATPCDM.SYS /D:PCMCD$
SET DSKDEV=PCM

[XDMA]
INCLUDE=DOSOPT
DEVICEHIGH /s=\DOS\XDMA.SYS

[DATDRV]
MENUITEM=IDE ,IDE CD
MENUITEM=USB ,USB CD/HD/FD + IDECD
MENUITEM=FW  ,1394/Firewire CD/HD + IDECD
MENUITEM=PCM ,PCMCIA CD + IDECD
MENUITEM=XDMA,UltraDMA HDD
SUBMENU =MENU,<<< Return
MENUDEFAULT=MENU

[NETOPT]
INCLUDE=DOSOPT
INCLUDE=MYNET

[NETCD]
MENUITEM=NIDE,IDE CD
MENUITEM=NUSB,USB CD/HD/FD
MENUITEM=NFW ,1394/Firewire CD/HD
MENUITEM=NPCM,PCMCIA CD
SUBMENU =MENU,<<< Return
MENUDEFAULT=NIDE,3

[NIDE]
INCLUDE=IDE
INCLUDE=MYNET

[NUSB]
INCLUDE=USB
INCLUDE=MYNET

[NFW]
INCLUDE=FW
INCLUDE=MYNET

[NPCM]
INCLUDE=PCM
INCLUDE=MYNET

[NAKED]
MENUITEM=DOSCMD,DOS in conventional memory
MENUITEM=NKDHIM,DOS + HIMEM
MENUITEM=NKDXMS,DOS + HIMEM + EMM386 (XMS only)
MENUITEM=NKDEMS,DOS + HIMEM + EMM386 (XMS/EMS)
SUBMENU =MENU,<<< Return
MENUDEFAULT=NKDXMS

[DOSCMD]

[NKDHIM]
DEVICE=\DOS\HIMEM.SYS /TESTMEM:OFF /SHADOWRAM:OFF
DOS=HIGH,UMB,AUTO
SET CONFIG=DOSCMD

[NKDXMS]
DEVICE=\DOS\HIMEM.SYS /TESTMEM:OFF /SHADOWRAM:OFF
DEVICE=\DOS\EMM386.EXE NOEMS VERBOSE
DOS=HIGH,UMB,AUTO
SET CONFIG=DOSCMD

[NKDEMS]
DEVICE=\DOS\HIMEM.SYS /TESTMEM:OFF /SHADOWRAM:OFF
DEVICE=\DOS\EMM386.EXE RAM VERBOSE
DOS=HIGH,UMB,AUTO
SET CONFIG=DOSCMD

[MYNET]
;Read %RAMDRIVE%\NET\README.TXT for details of customization.
;Of couse, you won't find it there in clean-boot modes.
SET MODS=ASK

autoexec.bat:
: DOSNETX/7 DOS AUTOEXEC Batch File
: (c) 1997-2007, David Rin <rendaa@gmail.com>
: Rev 6.70216
:
@if .%debug%==. echo off
if .%rtd%==. set rtd=C:
for %%f in (A: A:\DOS) do if .%comspec%==.%%f\COMMAND.COM set rtd=A:
if .%0==. if exist \DOS\DOSKEY.* lh /s \DOS\DOSKEY /insert /b:2048
if .%0==. if exist %rtd%\dos\nul path %rtd%\DOS
if not .%0==. goto _bat_chain
if not .%config%==.DOSCMD goto _normal
if exist \DOS\DOSMACRO.BAT call \DOS\DOSMACRO.BAT
goto _end

:_normal
if exist EMMQXXX0 set lh=lh /s
set bootstage=yes
if .%debug%==. ctty nul
if .%ramdrive%==. if exist \DOS\DOSDRIVE.BAT call \DOS\DOSDRIVE.BAT
ctty con
if not .%ramdrive%==. goto _ramd_ok
echo RAMDRIVE is not available!
goto _eof

:~apath
if .%3==. goto _eof
if not exist %3\nul goto _eof
set @@=%path%
set path=%3
set @=%path%
set path=%@@%
set @@=
for %%f in (%path%) do if .%%f==.%@% goto ~0_apath
path %path%;%@%
:~0_apath
set @=
goto _eof

:~expand
if .%3==. goto _eof
if not exist %3 goto _eof
copy %3 $.exe>nul
echo A|$.exe>nul
del $.exe>nul
goto _eof

:~extract
if .%3==. goto _eof
if not exist %3 goto _eof
for %%f in (%path% .) do if exist %%f\extract.exe goto ~extr1
goto _eof
:~extr1
extract /y /a /e %3 >nul
goto _eof

:_ramd_ok
if .%bootstage%==. goto _end
if .%debug%==. ctty nul
if exist %rtd%\AUTOEXEC.BAT copy %rtd%\AUTOEXEC.BAT %ramdrive%\ /y>nul
ctty con
if exist %ramdrive%\AUTOEXEC.BAT %ramdrive%\AUTOEXEC.BAT

:_bat_chain
if .%1==.: if not .%2==. goto %2
if .%debug%==. ctty nul
\DOS\FINDRAMD
if not .%RAMDRIVE%==. set temp=%RAMDRIVE%\
if exist EMMQXXX0 if exist %ramdrive%\dos\peruse.* %lh% peruse /x384
set netdir=%rtd%\NET
goto _dont_cache_netdir

set netdir=%ramdrive%\_
if exist %netdir%\*.* echo y|del %netdir%>nul
if not exist %netdir%\nul goto _mk_tmp
echo y|del %netdir%>nul
:_mk_tmp
if not exist %netdir%\nul md %netdir%
if exist %rtd%\net\nul copy %rtd%\net %netdir% /y>nul

:_dont_cache_netdir
ctty con
set DOSTSR=DO MD MC
if exist %ramdrive%\DOS\DOSDRIVE.BAT call %ramdrive%\DOS\DOSDRIVE.BAT : ~dostsr
%ramdrive%
if not exist \net\nul md\net
path %ramdrive%\dos;%ramdrive%\net
set temp=%ramdrive%\NET
if .%rtd%==.C: for %%f in (dos net) do call %0 : ~apath %rtd%\%%f
set netdrive=O:
if exist %netdrive%\nul subst %netdrive% /D>nul
subst %netdrive% %ramdrive%\>nul
%netdrive%
cd \net
if .%debug%==. ctty nul
for %%f in (%netdir%\DOSNETX!.exe %netdir%\DRVP*.exe) do call %0 : ~expand %%f
for %%f in (%netdir%\DOSNETX!.cab %netdir%\DRVP*.cab) do call %0 : ~extract %%f
set apcd=
if .%cdrom%==. goto _drv_cd_not_ready
for %%f in (%cdrom%) do call %0 : ~apcd_ck %%f
:_drv_cd_not_ready
for %%f in (.DOS .COM .EXE .BAT .INI .SYS .CFG .IN_ .PWL .CAB .) do if exist %netdir%\*%%f copy %netdir%\*%%f . /y>nul
if .%netdir%==.%rtd%\NET goto _no_tmp
if not exist %netdir%\nul goto _no_tmp
echo y|del %netdir%>nul
if exist %netdir%\nul rd %netdir%>nul
:_no_tmp
set netdir=
for %%f in (DOSNETX!.* DRVP*.EXE DRVP*.CAB) do if exist %%f del %%f
ctty con
:call %0 : ~remap
if .%MODS%==. goto _no_net
set _err=
if exist MSNET.BAT call MSNET.BAT
goto _exit

:~apcd_ck
if .%3==. goto _eof
if not .%apcd%==. goto _eof
dready %3
if errorlevel 2 goto _eof
%comspec% /F /C if not exist %3\NDISDRV\DRVPAK.bat if not exist %3\NDISDRV\DRVP*.EXE goto _eof
set apcd=%3
for %%f in (%apcd%\NDISDRV\DRVP*.exe) do call %0 : ~expand %%f
for %%f in (%apcd%\NDISDRV\DRVP*.cab) do call %0 : ~extract %%f
if exist %apcd%\NDISDRV\DRVPAK.BAT call %apcd%\NDISDRV\DRVPAK.BAT
goto _eof

:_no_net
if exist %ramdrive%\DOS\SMARTDRV.* %ramdrive%\DOS\SMARTDRV /q

:_exit
cd %rtd%\
cd %ramdrive%\
cd %netdrive%\
%ramdrive%
set bootstage=
dready c:
if not errorlevel 2 for %%f in (DOS NET) do call %0 : ~apath c:\%%f
if .%rtd%==. goto _end
if not .%_err%==. goto _end
if not errorlevel 2 if exist %rtd%\AUTORUN.BAT %rtd%\AUTORUN.BAT
if not %rtd%==C: goto _apcd_chain
dready d:
if not errorlevel 2 if exist D:\AUTORUN.BAT D:\AUTORUN.BAT
goto _end

:~remap
if .%rfd%==. set rfd=A:
if not exist $RAMFDD$ goto _eof
if not .%rfd%==.A: goto _eof
if exist %ramdrive%\DOS\REMAPFDD.* %lh% %ramdrive%\DOS\REMAPFDD B: /D:0
for %%f in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call %0 : ~setrfd %%f:
goto _eof

:~setrfd
if .%3==. goto _eof
if .%rfd%==.+ echo Remap logical drive %3 to floppy drive %rtd%...
if .%rfd%==.+ set rfd=%3
if not .%rfd%==%3 if %3==%ramdrive% set rfd=+
goto _eof

:~apcd_chain
if .%3==. goto _eof
dready %3
if not errorlevel 2 if exist %3\AUTORUN.BAT %3\AUTORUN.BAT
goto _eof

:_apcd_chain
if not .%apcd%==. call %0 : ~apcd_chain %apcd%
if not .%apcd%==. goto _end
for %%f in (%cdrom%) do call %0 : ~apcd_chain %%f

:_end
set _err=
set bootstage=

:_eof

2007-5-24 14:17
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
xugaohui
高级用户




积分 774
发帖 293
注册 2003-4-16
来自 湖北仙桃
状态 离线
『第 2 楼』:  

早就解决这个问题了：
只需要一个图形操作界面，支持鼠标操作，自动检测网卡，也可以手动选择网卡，当主板有两块相同的网卡也可以分别驱动其中一块网卡。可自由使用一种或多种网络协议 ms的 tcp/ip ipx netbeui三种，并特别支持ibm tcip/ip，可设置每种协议的具体参数，可启动文件共享和打印功能。支持网卡数远远超过同类软件。



   此帖被 +1 点积分    点击查看详情   
评分人：【 BC 】分数： +1  时间：2008-7-5 10:41




下载
09年7月7日 更新
感谢网友 囧HQY 提供空间
2007-5-29 20:53
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
lizhenduo
初级用户




积分 190
发帖 29
注册 2003-6-24
状态 离线
『第 3 楼』:  



  Quote:
Originally posted by xugaohui at 2007-5-29 08:53 PM:
早就解决这个问题了：
只需要一个图形操作界面，支持鼠标操作，自动检测网卡，也可以手动选择网卡，当主板有两块相同的网卡也可以分别驱动其 ...

谢谢,我真是孤陋寡闻.
能发个镜像吗?我真的很需要. 谢谢!
烦请能说一下自动搜索网卡并加载驱动和输入ip地址等的原理方法吧.谢谢

2007-5-30 14:54
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
john12900
初级用户





积分 95
发帖 40
注册 2007-5-2
状态 离线
『第 4 楼』:  yyy

那个网站的镜像文件怎么下不下来，能发一个吗？

2007-6-8 08:14
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
john12900
初级用户





积分 95
发帖 40
注册 2007-5-2
状态 离线
『第 5 楼』:  yyy

终于下载下来了，谁能把那些搜索驱动之类的东东提取出来，就是可以集成到自己启动盘里那种？？
谢谢了

2007-6-13 08:33
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
xbbin
初级用户





积分 20
发帖 10
注册 2007-6-20
状态 离线
『第 6 楼』:  

没看明白，我还是不知道怎么玩

2007-6-20 13:55
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
zyroy000
初级用户





积分 30
发帖 13
注册 2005-12-6
状态 离线
『第 7 楼』:  

收藏

2008-5-18 18:04
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
fly2sky
新手上路





积分 4
发帖 2
注册 2006-1-13
状态 离线
『第 8 楼』:  

2楼的那个软件真是太好了，没想到DOS下还有那么好的工具

2008-6-1 18:14
查看资料  发短消息 网志   编辑帖子  回复  引用回复
jpcainiao
新手上路





积分 14
发帖 5
注册 2008-4-7
状态 离线
『第 9 楼』:  

请问二楼的朋友,你的这个软件我试用了一下,不过每次都默认选择MS的TCP/IP协议及自动为动态IP,图上所示的默认参数在那个文件上可以设定?
还有想请教一下,在DOS下如何使用批处理加载ms的 tcp/ip ipx netbeui和ibm tcip/ip协议,如果我只是想在DOS下查看一下WINDOWS2003的共享(局域网内),应该加载上面四种协议中的那一种才更好些?其分别对应或必需加载的网卡驱动类型又是哪一种?
望能解答一下.不胜感激!!

2008-6-30 22:07
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
xugaohui
高级用户




积分 774
发帖 293
注册 2003-4-16
来自 湖北仙桃
状态 离线
『第 10 楼』:  

回楼上的：
参数在runnet.bat文件中设置。
最好是采用ibm tcp/ip.
都是使用ndis2驱动。



下载
09年7月7日 更新
感谢网友 囧HQY 提供空间
2008-7-2 04:54
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
wangtk1982
新手上路





积分 12
发帖 6
注册 2008-7-3
状态 离线
『第 11 楼』:  

xugaohui:
你好！现在这个img下载不了了，请大侠给一份吧 我需要在纯dos下telnet进入终端设备

原站说的那个支持telnet的img不知道大侠有没有，先谢过了

我的邮箱：wangtk1982@sohu.com

2008-7-3 22:57
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
snowground
新手上路





积分 8
发帖 4
注册 2006-8-23
状态 离线
『第 12 楼』:  

牛人真多 ,

2008-7-4 21:49
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
netwinxp
高级用户





积分 741
发帖 366
注册 2007-7-25
状态 离线
『第 13 楼』:  

嘿嘿俺有纯DOS下用硬MODEM拨号上BBS的PPPD.EXE

[ Last edited by netwinxp on 2008-7-8 at 05:16 PM ]

2008-7-8 17:12
查看资料  发短消息 网志   编辑帖子  回复  引用回复
bsfmig
新手上路





积分 7
发帖 4
注册 2008-7-31
状态 离线
『第 14 楼』:  

无法下载是因为Google Pages被墙了，请使用代理服务器。

2008-8-1 23:12
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
GOTOmsdos
铂金会员

C++启程者


积分 5154
发帖 1827
注册 2003-7-18
状态 离线
『第 15 楼』:  



  Quote:
Originally posted by xugaohui at 2007-5-29 08:53 PM:
早就解决这个问题了：
只需要一个图形操作界面，支持鼠标操作，自动检测网卡，也可以手动选择网卡，当主板有两块相同的网卡也可以分别驱动其 ...

嗯，看起来非常强大，我来试试。。。。。

2008-8-21 13:53
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
« [1] [2] » ›
请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。


可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题



论坛跳转:  



[ 联系联盟系统管理团队 - 中国DOS联盟 ]

Sponsored by ifanr Inc | © 2001-2023