Board logo

标题: 批量修改文件名,只保留前6位 [打印本页]
作者: liuwang123     时间: 2007-5-4 13:44    标题: 批量修改文件名,只保留前6位

我一个文件夹内有几千张如下名称的图片： 006025_9485.jpg 006078_9fv5d.jpg 200032_9cv5f.jpg 006076_9143.jpg 000043_2350.jpg ... ... 其中， _号之前是6位数字,没有必然的固定规律;_号后的位数不固定,更没有规律. 我想要实现的改名效果是将上述文件名改为： 006025.jpg 006078.jpg 200032.jpg 006076.jpg 000043.jpg ... ... 简单点说，就是把所有文件名称的前六位保留就可以了。不知道批处理命令是怎样的？ (注：本人没太多基础知识，慕名而来，望各位详细指点下，谢谢！)
作者: ccwan     时间: 2007-5-4 14:18
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir/b *.jpg') do (
    set var=%%i
    set var=!var:~0,6!
    ren %%i !var!.jpg
)
pause
作者: caiyiqun     时间: 2007-5-4 14:23
一看就知道你是下载漫画的吧！！呵呵
作者: slore     时间: 2007-5-4 14:37
按_分割取%%i最后加上.jpg
作者: liuwang123     时间: 2007-5-4 14:53
Originally posted by ccwan at 2007-5-4 01:18 AM:
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir/b *.jpg') do (
    set var=%%i
    set var=!var:~0,6!
    ren %%i !var!.jpg
)
pause
试试看。
作者: liuwang123     时间: 2007-5-4 16:26
感谢二楼的帮助，执行效率很高！
作者: lxmxn     时间: 2007-5-4 16:56
for /f "delims=_ tokens=1*" %%a in ('dir /b *.jpg') do ren %%a_%%b %%a.jpg
作者: yeke     时间: 2007-5-4 20:54
真好玩呵 ───────────────────　版务记录　──────────────────── 执行人：bjsh 说明：灌水 处罚：因属论坛新人，暂时不予处罚；再予发现必重罚 ───────────────────　版务记录　──────────────────── [ Last edited by bjsh on 2007-5-4 at 12:04 PM ]
作者: lpk130     时间: 2007-5-5 19:38
@echo off
setlocal enabledelayedexpansion
for %%i in (*) do (
set name=%%~ni
set name=!name:~0,6!
ren %%i !name!%%~xi
)
文件名短于6个字符的，不会被重命名 不区分扩展名
作者: foreverlrf     时间: 2007-8-20 12:31    标题: 版主提供的办法好，代码简短执行效率高

版主提供的办法好，代码简短执行效率高！
作者: Billunique     时间: 2007-9-18 16:50
正好沿着请教： 假如我的前缀没有规则，而我只要只要最后一个_后面的内容来重命名，该怎么做？假设我的文件是这样的： 复件 复件 魂牵梦萦_fdsl_fds_111_adb.mp3 复件 魂牵梦萦_fdsl_fds_adc.mp3 魂牵梦萦_fdsl_fds_ade.mp3 ..... 而我的目的是，可以得到： adb.mp3 adc.mp3 ade.mp3 ..... [ Last edited by Billunique on 2007-9-18 at 06:00 PM ]
作者: wudixin96     时间: 2007-9-18 17:42
adb.mp3 adc.mp3 adb.mp3 文件名不是重名了？
作者: jmz573515     时间: 2007-9-18 17:47
@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b *.mp3') do (
    set name=%%~ni
    set name=!name:~-3,3!
    ren %%i !name!.mp3
)
pause
作者: wudixin96     时间: 2007-9-18 17:51
楼上的，_的最后不定是3位的吧？
作者: Billunique     时间: 2007-9-18 18:04
嗯，感谢wudixin96的提醒，感谢jmz573515的解答：） 抱歉我没有表达清楚。 1._后的名字是不确定的，不定是3位 2._后的名字不会有重复的情况。
作者: Billunique     时间: 2007-9-18 18:14
有没有方法将最后一个_前面的所有内容作为一个token，而_后的作为另一个token，请教......
作者: wudixin96     时间: 2007-9-18 18:59
@echo off
for /r %%i in (*.mp3) do (
  set nm=%%~ni
  call :js
  call ren "%%i" "%%nm%%.mp3"
)
pause

:js
set nm=%nm:*_=%
echo %nm%|find "_">nul 2>nul&&goto js||goto :eof
能达到效果，只是效率太低
作者: lxmxn     时间: 2007-9-18 19:22
试试下面这个，如果文件名中最后一个_字符后面的字符串中含有空格，会将空格替换成"#"：
@echo off & setlocal EnableDelayedExpansion
for %%a in (*.mp3) do (
	set file_name=%%a
	set file_rname=!file_name: =#!
	set file_rname=!file_rname:_=;!
	for %%b in (!file_rname!) do set new_file_name=%%b
	rename "!file_name!" "!new_file_name!"
)
作者: lxmxn     时间: 2007-9-18 19:27
改进一下也可以不用替换空格:
@echo off & setlocal EnableDelayedExpansion
for %%a in (*.mp3) do (
	set file_name=%%a
	set file_rname=!file_name: =#!
	set file_rname=!file_rname:_=;!
	for %%b in (!file_rname!) do set new_file_name=%%b
	set new_file_name=!new_file_name:#= !
	rename "!file_name!" "!new_file_name!"
)
作者: Billunique     时间: 2007-9-19 10:09
哈，感谢二位，经测试都达到了效果！ 　　to wudixin96：在下粗浅，兄的招法过高，对echo %nm%|find "_">nul 2>nul&&goto js不是很明白。 　　to lxmxn：这样的思路你都能想出来，人才啊，PF！
作者: wudixin96     时间: 2007-9-19 10:38
lxmxn 兄的效率很高，比偶的强多了，只是如果最后一个_后面的字符里包含#的话， 就会被替换为空格了。
作者: lxmxn     时间: 2007-9-19 11:25
Originally posted by wudixin96 at 2007-9-19 10:38: lxmxn 兄的效率很高，比偶的强多了，只是如果最后一个_后面的字符里包含#的话， 就会被替换为空格了。
再改进一下:
@echo off & setlocal EnableDelayedExpansion
for %%a in (*.mp3) do (
	set file_name=%%a
	set file_rname=!file_name: =\!
	set file_rname=!file_rname:_=;!
	for %%b in (!file_rname!) do set new_file_name=%%b
	set new_file_name=!new_file_name:\= !
	echo rename "!file_name!" "!new_file_name!"
)
作者: wudixin96     时间: 2007-9-19 11:48
那如果字符中还带;号呢，不是又把分好当成分隔符了？？
作者: lxmxn     时间: 2007-9-19 12:02
嗯，程序总有点bug的，只有尽可能多的排除一些特殊情况，根据情况来修改代码了。
作者: wudixin96     时间: 2007-9-19 12:05
o(∩_∩)o...哈哈，没见你上QQ嘛
作者: lxmxn     时间: 2007-9-19 12:10
或者借助外部工具了.
@echo off
for %%a in (*.mp3) do (
for /f "delims=" %%b in ('echo\%%a^|sed "s/.*_\(.*\.mp3\)/\1/"') do echo rename "%%a" "%%b"
)
pause
ps:QQ常年隐身了.. [ Last edited by lxmxn on 2007-9-19 at 12:11 PM ]
作者: jmz573515     时间: 2007-9-20 10:10
set fso=createobject("scripting.filesystemobject")
set folder=fso.getfolder(".")
for each file in folder.files
    if ucase(right(file,3))="MP3" and instr(file,"_")<>0 then 
        set wj=fso.getfile(file)
        wj.name=cl(file) & ".mp3"
    end if
next
msgbox "操作成功！",4096,"提示"
function cl(filename)
    filename=fso.getbasename(filename)
    n=instrrev(filename,"_")
    cl=mid(filename,n+1)
end function
作者: bush     时间: 2007-12-29 23:59
很難說有沒有重名~ 不如來更直接的： ren ??????*.jpg ??????.jpg 還是可以啊
作者: everest79     时间: 2007-12-30 00:05
ren *.txt ??????.txt
作者: bush     时间: 2007-12-30 00:25    标题: re:『第 29 楼』:

兄弟所言正解! 我把注意力都集中在六位數上了^-^
作者: zhangmin     时间: 2009-6-5 00:29
可否请教各位大侠 那可否把100个不规则的文件名（比如有带符号或有中文名）都改成001~099.jpg呢？
作者: step2step     时间: 2009-6-6 08:05
@echo off for %%i in (.) do ren *.jpg ??????.jpg pause 来个简单点的，我是初学者，哈哈