中国DOS联盟论坛 - Powered by Discuz! Board

标题: 写一个文件，把多个REG合并成一个 [打印本页]

作者: nvflash 时间: 2006-9-29 19:24 标题: 写一个文件，把多个REG合并成一个

比如，有十个REG文件，分别为1.reg到10.reg 要把2-9的内容追加到1.reg里面，怎么弄？

作者: NaturalJ0 时间: 2006-9-29 20:15

copy 1.reg+2.reg+3.reg+......+10.reg 0.reg 这样行么？

作者: 9527 时间: 2006-9-29 21:34

不太明白楼主什么意思？是10个REG文件中的2.reg到9.reg内容合并啊？还是每个文件的2-9行中的内容合并成一个啊？题意没说清楚！！！

作者: chainliq 时间: 2006-9-29 21:36

copy 呀！

作者: chainliq 时间: 2006-9-29 21:39

这样也行： @echo off regedit /s 路径\1.reg regedit /s 路径\2.reg regedit /s 路径\3.reg **************

作者: nvflash 时间: 2006-9-29 22:05

Originally posted by NaturalJ0 at 2006-9-29 20:15: copy 1.reg+2.reg+3.reg+......+10.reg 0.reg 这样行么？

这样是可以了，但合并后是这种的格式,并不能直接导入注册表： Windows Registry Editor Version 5.00 [HKEY_CLASSES_ROOT\.3gp] "KureeBak"="dsafs" @="mplayerc.3gp" Windows Registry Editor Version 5.00 [HKEY_CLASSES_ROOT\.ace] @="WinRAR" 有两个文件头了可以在word里面查找^P,替换成就行了那么有没有办法直接就把文件头给去了？

作者: zh159 时间: 2006-9-29 22:26

试试：

>Tmp.reg echo Windows Registry Editor Version 5.00
>>Tmp.reg echo.
for /f "delims=" %%i in ('dir/b *.reg') do (
    for /f "skip=1 delims=" %%n in (%%i) do if not "%%i"=="Tmp.reg" >>Tmp.reg echo %%n)

作者: pengfei 时间: 2006-9-29 23:57

2楼的copy +..+不错~~~!

@echo off
copy /b /y 1.txt+2.txt+3.txt+4.txt+5.txt+6.txt+7.txt+8.txt+9.txt+10.txt temp.txt
for /l %%i in (1,1,10) do del %%i.txt
ren temp.txt 1.txt
pause

不过似乎有更好的办法...

@@echo off
for /l %%i in (2,1,10) do type %%i.txt>>1.txt
for /l %%i in (2,1,10) do del %%i.txt
pause

作者: namejm 时间: 2006-9-30 01:01

　　通行的方案是：在for语句中用 mor +1 跳过2～10.reg文件的首行，然后再把剩余行的内容echo到1.reg文件内容的后面。代码如下：

@echo off
echo.>>1.reg
for /l %%i in (2,1,10) do (
    echo.>>1.reg
    for /f "tokens=*" %%j in ('more +1 %%i.reg') do (
        >>1.reg echo %%j
    )
)
start notepad 1.reg

作者: zh159 时间: 2006-9-30 01:17

改正一下我 7 楼的，只要把 reg 文件放在同一目录

@echo off
>Tmp.reg echo Windows Registry Editor Version 5.00
for /f "delims=" %%i in ('dir/on/b *.reg') do (
    >>Tmp.reg echo.
    for /f "skip=1 delims=" %%n in (%%i) do if not "%%i"=="Tmp.reg" >>Tmp.reg echo %%n
)

作者: nvflash 时间: 2006-9-30 02:03

Originally posted by namejm at 2006-9-30 01:01: 　　通行的方案是：在for语句中用 mor +1 跳过2～10.reg文件的首行，然后再把剩余行的内容echo到1.reg文件内容的后面。代码如下： [code] @echo off echo.> ...

真是个高手！

作者: pengfei 时间: 2006-9-30 02:12

namejm兄的去头行显示再重定向很好... Windows Registry Editor Version 5.00 而1.reg中反复出现这句不会对导入造成影响. [ Last edited by pengfei on 2006-9-30 at 02:18 ]

作者: 3742668 时间: 2006-9-30 13:01

@echo off
    set filter=Windows Registry Editor Version 5.00
    if "%1" == "" (set file=*.reg) else (set file=%*)

    (echo %filter%) >xxx.txt
    (type %file% | findstr /ixvc:"%filter%") >>xxx.txt

    del %file%
    ren xxx.txt xxx.reg

1.若没有在参数中指定要合并的reg文件，默认合并当前目录下所有的reg文件。 2.代码未测试。