Board logo

标题: [推荐]3721等垃圾网站的免疫批处理程序 [打印本页]

作者: Climbing     时间: 2004-7-28 00:00    标题: [推荐]3721等垃圾网站的免疫批处理程序

在上网浏览的时候,经常会受到3721等垃圾网站的骚扰,十分不爽。
解决办法:运行本帖中提供的No_3721.bat,对于Windows 9x系统,请在运行完成后重新启动计算机以使设置生效。
原理:通过修改本机hosts文件(主机定义文件),将3721等网站的域名解析为本机,这样就不会再访问3721等网站了。你可以通过修改本程序,加入其它你想免疫的网站,例如新浪网。
No_3721.bat的内容:

@echo off
:: ===============================================================
:: No_3721.bat  3721等垃圾网站的免疫程序
:: 版本:1.0
:: 作者:Climbing ( xclimbing@msn.com )
:: 创建日期: 2004.07.28
:: 功能:自动检测当前系统是win9x系统还是NT系统,然后修改对应的hosts文件以实现3721等网站的免疫。
:: ===============================================================
if "%comspec%"=="" goto _quit
:: 通过检测comspec环境变量来判断当前系统是NT还是9x。
echo %comspec% | find /i "command" > nul
if errorlevel 1 goto _nt
if errorlevel 0 goto _9x
goto _quit
:_nt
echo 您的系统是Windows NT/2000/XP/2003。
set dst=%windir%\system32\drivers\etc\hosts
echo 准备修改的文件:%dst%
goto _chkhosts
:_9x
echo 您的系统是Windows 9x。
set dst=%windir%\hosts.sam
set NeedReboot=true
echo 准备修改的文件:%dst%
goto _chkhosts
:: 检测是否已经对hosts文件进行过修改。
:_chkhosts
find /i "www.3721.net" %dst% > nul
if errorlevel 1 goto _addhost
echo.
echo 经偶检查,您的系统已经对3721免疫了,无需再进行任何修改!
goto _quit
:_addhost
echo.
echo 正在修改...
>> %dst% echo 127.0.0.1 http://www.3721.net/
>> %dst% echo 127.0.0.1 3721.com
>> %dst% echo 127.0.0.1 3721.net
>> %dst% echo 127.0.0.1 cnsmin.3721.com
>> %dst% echo 127.0.0.1 cnsmin.3721.net
>> %dst% echo 127.0.0.1 download.3721.com
>> %dst% echo 127.0.0.1 download.3721.net
>> %dst% echo 127.0.0.1 www.3721.com
>> %dst% echo 127.0.0.1 www.3721.net
>> %dst% echo 127.0.0.1 bar.baidu.com
echo.
echo 恭喜!修改完成。您的系统已经对3721等垃圾网站免疫!
if not "%NeedReboot%"=="true" goto _quit
echo 不过由于您的系统是Windows 9x系统,请重新启动计算机使设置生效!
echo 按任意健返回Windows...
pause > nul
:_quit
set dst=
set NeedReboot=


作者: autoit     时间: 2004-7-28 00:00
恩,收下...[em05]
作者: 内酷     时间: 2004-7-30 00:00
我给大家介绍个软件,简单易用http://www1.arongsoft.com/soft/2437.htm同样也可以免疫的.
作者: Climbing     时间: 2004-7-30 00:00
谢谢楼上的软件,真的很不错,又让我学到了新东西。不过我的方法也很不错,因为不用改注册表,相当于绿色软件。
作者: windrate     时间: 2004-11-22 00:00
感谢楼主提供的免疫程序!
本人是菜鸟,在楼主程序基础上改了几行,实现卸载的功能,因为毕竟还是有小部分人用3721的!如有不正确的地方,请不吝赐教。
程序如下:

uninstall_No_3721.bat的内容:

@echo off
:: ===============================================================
:: 3721等垃圾网站的免疫程序卸载
:: 版本:1.0
:: 作者:Climbing ( xclimbing@msn.com )
:: 修改:windrate ( windrate@163.com )
:: 创建日期: 2004.11.22
:: 功能:卸载3721等垃圾网站的免疫程序
:: ===============================================================

if "%comspec%"=="" goto _quit

:: 通过检测comspec环境变量来判断当前系统是NT还是9x。
echo %comspec% | find /i "command" > nul
if errorlevel 1 goto _nt
if errorlevel 0 goto _9x
goto _quit

:_nt
echo 您的系统是Windows NT/2000/XP/2003。
set dst=%windir%\system32\drivers\etc\hosts
echo 准备修改的文件:%dst%
goto _chkhosts

:_9x
echo 您的系统是Windows 9x。
set dst=%windir%\hosts.sam
set NeedReboot=true
echo 准备修改的文件:%dst%
goto _chkhosts

:: 检测是否已经对hosts文件进行过修改。
:_chkhosts
find /i "www.3721.net" %dst% > nul
if errorlevel 1 goto _noneed
goto _delhost

:_noneed
echo.
echo 您的系统没有对3721免疫,无需进行卸载!
goto _quit

:_delhost
echo.
echo 正在修改...
> %dst% echo # Copyright (c) 1993-1999 Microsoft Corp.
>> %dst% echo #
>> %dst% echo # This is a sample HOSTS file used by Microsoft TCP/IP for Windows.
>> %dst% echo #
>> %dst% echo # This file contains the mappings of IP addresses to host names. Each
>> %dst% echo # entry should be kept on an individual line. The IP address should
>> %dst% echo # be placed in the first column followed by the corresponding host name.
>> %dst% echo # The IP address and the host name should be separated by at least one
>> %dst% echo # space.
>> %dst% echo #
>> %dst% echo # Additionally, comments (such as these) may be inserted on individual
>> %dst% echo # lines or following the machine name denoted by a '#' symbol.
>> %dst% echo #
>> %dst% echo # For example:
>> %dst% echo #
>> %dst% echo #     102.54.94.97    rhino.acme.com          #source server
>> %dst% echo #      38.25.63.10    x.acme.com             # x client host
>> %dst% echo #
>> %dst% echo 127.0.0.1       localhost

echo.
echo 卸载完成!您的系统不再对3721等垃圾网站免疫!
if not "%NeedReboot%"=="true" goto _quit
echo 由于您的系统是Windows 9x系统,请重新启动计算机使设置生效!
echo 按任意健返回Windows...
pause > nul

:_quit
pause
set dst=
set NeedReboot=


作者: defrag     时间: 2004-12-31 00:00
为什么你们都吧重定向字符写在前面,而命令再后面啊?更正一下
no_3721.bat

  Quote:
@echo off
:: ===============================================================
:: No_3721.bat  3721等垃圾网站的免疫程序
:: 版本:1.0
:: 作者:Climbing ( xclimbing@msn.com )
:: 创建日期: 2004.07.28
:: 功能:自动检测当前系统是win9x系统还是NT系统,然后修改对应的hosts文件以实现3721等网站的免疫。
:: ===============================================================
if "%comspec%"=="" goto _quit
:: 通过检测comspec环境变量来判断当前系统是NT还是9x。
echo %comspec% | find /i "command" > nul
if errorlevel 1 goto _nt
if errorlevel 0 goto _9x
goto _quit
:_nt
echo 您的系统是Windows NT/2000/XP/2003。
set dst=%windir%\system32\drivers\etc\hosts
echo 准备修改的文件:%dst%
PAUSE>NUL
goto _chkhosts
:_9x
echo 您的系统是Windows 9x。
set dst=%windir%\hosts.sam
set NeedReboot=true
echo 准备修改的文件:%dst%
PAUSE>NUL
goto _chkhosts
:: 检测是否已经对hosts文件进行过修改。
:_chkhosts
find /i "www.3721.net" %dst% > nul
if errorlevel 1 goto _addhost
echo.
echo 经偶检查,您的系统已经对3721免疫了,无需再进行任何修改!
goto _quit
:_addhost
echo.
echo 正在修改...
echo 127.0.0.1 http://www.3721.net/ >> %dst%
echo 127.0.0.1 3721.com >> %dst%
echo 127.0.0.1 3721.net >> %dst%
echo 127.0.0.1 cnsmin.3721.com >> %dst%
echo 127.0.0.1 cnsmin.3721.net >> %dst%
echo 127.0.0.1 download.3721.com >> %dst%
echo 127.0.0.1 download.3721.net >> %dst%
echo 127.0.0.1 www.3721.com >> %dst%
echo 127.0.0.1 www.3721.net >> %dst%
echo 127.0.0.1 bar.baidu.com >> %dst%
echo.
echo 恭喜!修改完成。您的系统已经对3721等垃圾网站免疫!
if not "%NeedReboot%"=="true" goto _quit
echo 不过由于您的系统是Windows 9x系统,请重新启动计算机使设置生效!
echo 按任意健重起Windows...
pause > nul
rundll32.exe user.exe exitwindowsexec

:_quit
set dst=
set NeedReboot=

------------------------------
uninstall_no_3721.bat

  Quote:
@echo off
:: ===============================================================
:: 3721等垃圾网站的免疫程序卸载
:: 版本:1.0
:: 作者:Climbing ( xclimbing@msn.com )
:: 修改:windrate ( windrate@163.com )
:: 创建日期: 2004.11.22
:: 功能:卸载3721等垃圾网站的免疫程序
:: ===============================================================
if "%comspec%"=="" goto _quit
:: 通过检测comspec环境变量来判断当前系统是NT还是9x。
echo %comspec% | find /i "command" > nul
if errorlevel 1 goto _nt
if errorlevel 0 goto _9x
goto _quit
:_nt
echo 您的系统是Windows NT/2000/XP/2003。
set dst=%windir%\system32\drivers\etc\hosts
echo 准备修改的文件:%dst%
PAUSE>NUL
goto _chkhosts
:_9x
echo 您的系统是Windows 9x。
set dst=%windir%\hosts.sam
set NeedReboot=true
echo 准备修改的文件:%dst%
PAUSE>NUL
goto _chkhosts
:: 检测是否已经对hosts文件进行过修改。
:_chkhosts
find /i "www.3721.net" %dst% > nul
if errorlevel 1 goto _noneed
goto _delhost
:_noneed
echo.
echo 您的系统没有对3721免疫,无需进行卸载!
PAUSE>NUL
goto _quit
:_delhost
echo.
echo 正在修改...
echo # Copyright (c) 1993-1999 Microsoft Corp. > %dst%
echo # >> %dst%
echo # This is a sample HOSTS file used by Microsoft TCP/IP for Windows. >> %dst%
echo # >> %dst%
echo # This file contains the mappings of IP addresses to host names. Each >> %dst%
echo # entry should be kept on an individual line. The IP address should >> %dst%
echo # be placed in the first column followed by the corresponding host name. >> %dst%
echo # The IP address and the host name should be separated by at least one >> %dst%
echo # space. >> %dst%
echo # >> %dst%
echo # Additionally, comments (such as these) may be inserted on individual >> %dst%
echo # lines or following the machine name denoted by a '#' symbol. >> %dst%
echo # >> %dst%
echo # For example: >> %dst%
echo # >> %dst%
echo #     102.54.94.97    rhino.acme.com          #source server >> %dst%
echo #      38.25.63.10    x.acme.com             # x client host >> %dst%
echo # >> %dst%
echo 127.0.0.1       localhost >> %dst%
echo.
echo 卸载完成!您的系统不再对3721等垃圾网站免疫!
if not "%NeedReboot%"=="true" goto _quit
echo 由于您的系统是Windows 9x系统,请重新启动计算机使设置生效!
echo 按任意健返回Windows...
pause > nul
rundll32.exe user.exe,exitwindowsexec
:_quit
pause
set dst=
set NeedReboot=

[此贴子已经被作者于2004-12-31 21:57:26编辑过]



作者: oracleweb     时间: 2006-9-5 22:11
没效果啊
作者: electronixtar     时间: 2006-9-6 05:27
因为>在论坛转换前是>
作者: IceCrack     时间: 2006-9-6 15:14
俺发一个免疫流氓软件的批处理

  Quote:

  1. @Goto start
  2. ==============================================================
  3. 名称:流氓软件免疫程序
  4. 功能:阻止流氓软件进入系统
  5. 原理:设置文件夹的访问权限列表(ACL),由于FAT32的格式没有(ACL)
  6.       所以此文件只能在NTFS格式下才能使用.FAT32格式的用户若想使用此文件
  7.       须把系统先转换成NTFS格式,具体命令convent(欲转分区)/fs:ntfs
  8. 作者: IceCrack http://icecrack.ys168.com
  9. 日期: 2006-8-14 12:10:16 Monday      
  10. ==============================================================
  11. :start
  12. @Echo Off
  13. color 0e
  14. title 流氓软件免疫程序        
  15. setlocal enabledelayedexpansion
  16. Set choice=
  17. Echo.
  18. Echo.
  19. Echo                   请输入以下选项前面的数字
  20. Echo.
  21. Echo                   1:   安装流氓软件免疫程序
  22. Echo                   2:   删除流氓软件免费程序
  23. Echo                   3:   查看技术信息
  24. Echo                   4:   退出
  25. Echo.
  26. Echo.
  27. Set /p choice=                 输入你的选择:
  28. Echo.
  29. If "%choice%"=="1" Goto install
  30. If "%choice%"=="2" Goto unin
  31. If "%choice%"=="3" Goto view
  32. If "%choice%"=="4" Goto quit
  33. cls
  34. Goto start
  35. :view
  36. cls
  37. Echo ===========================================================================
  38. Echo.
  39. Echo.
  40. Echo                       欢迎使用流氓软件免疫程序
  41. Echo                                                      IceCrack
  42. Echo.
  43. Echo     功能:
  44. Echo          本软件通过访问控制列表(ACL)来免疫一些当前的流氓软件,
  45. Echo.
  46. Echo     注意:
  47. Echo          本程序只能在NTFS系统下才能使用,因为FAT32系统是没有ACL的
  48. Echo          若真要使用本软件可以先把系统转换成NTFS格式.
  49. Echo          具体命令convert "欲转分区" /fs:ntfs
  50. Echo          (注: 一是没有引号,二是分区后面要有一个: 如"c:")            
  51. Echo ============================================================================
  52. Echo.
  53. Echo  按任意键,返回操作
  54. pause >nul 2>nul
  55. cls
  56. Goto start
  57. :install
  58. Echo 安装中,请耐心等待
  59. For /f "delims=" %%a In (lmrj.txt) Do ( Set b=%%a
  60.     Set "b=!b:programfiles=%programfiles%!"
  61.     Set "b=!b:SystemDrive=%SystemDrive%!"
  62.     Set "b=!b:SystemRoot=%SystemRoot%!"
  63.     @md "!b!">nul 2>nul&&attrib +s +h "!b!" >nul 2>nul&&@setacl "!b!" /dir /deny everyone /full /p:no_dont_copy >nul 2>nul)
  64. Goto finished
  65. :unin
  66. Echo 删除中,请耐心等待
  67. For /f "delims=" %%a In (lmrj.txt) Do (Set b=%%a
  68.     Set "b=!b:programfiles=%programfiles%!"
  69.     Set "b=!b:SystemDrive=%SystemDrive%!"
  70.     Set "b=!b:SystemRoot=%SystemRoot%!"
  71.     setacl "!b!" /dir /grant everyone /full /p:yes >nul 2>nul&&@rd /q "!b!" >nul 2>nul)
  72. Goto finished

  73. :finished
  74. Echo 操作完成
  75. Echo.
  76. Echo.
  77. Echo        按任意键退出
  78. pause >nul 2>nul
  79. :quit
  80. endlocal
  81. Del lmrj.txt
  82. Del setacl.exe
  83. Del %0
  84. Exit
  85.                

        IceCrack发表于:  2006-09-06  03:15

附件 1: 流氓软件免疫程序.rar (2006-9-6 15:14, 166.82 K, 下载附件所需积分 1点 ,下载次数: 45)

作者: yjf2006     时间: 2006-9-12 12:33    标题: 谢谢各位了

好的   收下先  在试试看!谢谢啦!本人还是菜鸟