@echo OFF
Title=安装XPE硬盘版
:begin
cls
COLOR 2F
echo.
echo.
echo XPE硬盘安装版
echo ==============================================
echo.
echo 即将安装“小型XPE 硬盘版”到您的系统！
echo 本安装程序不会修改系统 MBR 及分区表等信息。
echo.
Echo 请按任意键开始安装......
PAUSE >NUL
Set RP=RP
For %%I In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If Exist %%I:\BOOT.INI Set RP=%%I
If %RP%==RP Goto Exit
FIND "Avldr.xpe" %RP%:\BOOT.INI >NUL
If %Errorlevel%==0 Goto Err1
:Install
If Exist %RP%:\AVLDR.XPE ATTRIB -S -H -R %RP%:\AVLDR.XPE
If Exist %RP%:\LDRXPE ATTRIB -S -H -R %RP%:\LDRXPE
Echo.
Echo 正在复制文件，请稍候 ......
Copy AVLDR.XPE %RP%:\ /Y>NUL
Copy LDRXPE %RP%:\ /Y>NUL
if not exist %RP%:\MININT\nul md %RP%:\MININT>NUL 2>nul
xcopy /y /r /e /q /h ..\I386\*.* %RP%:\MININT\>NUL 2>nul
ATTRIB -S -H -R %RP%:\BOOT.INI
If Exist %RP%:\BOOT.BAK (
ATTRIB -S -H -R %RP%:\BOOT.BAK
Del %RP%:\BOOT.BAK /Q
)
Copy %RP%:\BOOT.INI %RP%:\BOOT.BAK>NUL
TYPE %RP%:\BOOT.BAK|FIND /V "Avldr">%RP%:\BOOT.INI
Echo C:\Avldr.xpe="启动WinPE系统">>%RP%:\BOOT.INI
if not exist %RP%:\PROGRAMS\nul md %RP%:\PROGRAMS>NUL 2>nul
xcopy /y /e /q /h ..\PROGRAMS\*.* %RP%:\PROGRAMS\>NUL 2>nul
ATTRIB +S +H +R %RP%:\AVLDR.XPE
ATTRIB +S +H +R %RP%:\LDRXPE
ATTRIB +S +H +R %RP%:\BOOT.INI
ATTRIB +S +H +R %RP%:\BOOT.BAK
ATTRIB +S +H +R %RP%:\PROGRAMS /D /S
ATTRIB +S +H +R %RP%:\MININT /D /S
Goto SUCCESS
:Err1
CLS
Echo 好像你的机器中已经安装了 WinPE 了，请选择以下操作选项。
Echo.
Echo 1.卸载原有的 WinPE，并且重新安装。
Echo 2.退出安装
Echo.
Set Choice=
Set /P Choice=请选择要进行的操作 (1/2) ，然后按回车：
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' GOTO Install
If /I '%Choice%'=='2' EXIT
Goto Err1
:Exit
CLS
Echo 好像你的机器中没有安装操作系统哦，请确认后再执行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE >NUL
Exit
:SUCCESS
CLS
Echo 已经成功将WinPE安装到你的 %RP%: 盘。
Echo.
Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
Echo.
Echo 请按任意键退出。。。
PAUSE >NUL
Exit
OK了,谢啦是路径问题.
请善用.\和..\
.\i386 表示当前目录下的I386
..\i386 表示上级目录下的I386
你没有说明目录结构，就一楼我提示一下，自己再掂量一下巴
批处理在光盘根目录的例子
..\文件夹名\xcopy.exe /y /r /e /q /h .\I386\*.* %RP%:\MININT\>NUL 2>nul
或者：
批处理和xcopy.exe在同目录的例子
xcopy.exe /y /r /e /q /h ..\I386\*.* %RP%:\MININT\>NUL 2>nul
学习....
Last edited by tclshx on 2006-9-18 at 10:46 ]
