中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net  论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客:  注册 | 登录 | 命令行 | 搜索 | 上传 | 帮助 »
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 今儿啥也不说,就先发一张截图,大家一看就知道
English/Chinese Fix Translation
作者:
标题: 今儿啥也不说,就先发一张截图,大家一看就知道 上一主题 | 下一主题
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『楼 主』:  今儿啥也不说,就先发一张截图,大家一看就知道 使用 LLM 解释/回答一下

今儿啥也不说,就先发一张截图,大家一看就知道

Last edited by sl543001 on 2010-3-24 at 22:36 ]


附件 1: tsg.GIF (2010-3-24 22:38, 17.49 KiB,下载次数： 2)




SYBNQQ:354324773
2010-3-21 00:23
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
wangyc
新手上路





积分 13
发帖 11
注册 2007-2-24
状态 离线
『第 2 楼』:   使用 LLM 解释/回答一下

批处理是实现不了这个功能的,不可能同时显示三种颜色


2010-3-21 00:34
查看资料  发送邮件  发短消息  网志   编辑帖子  回复  引用回复
ZJHJ
高级用户





积分 609
发帖 374
注册 2006-8-2
状态 离线
『第 3 楼』:   使用 LLM 解释/回答一下

你看看 jxfa0086768 斗地主的作品就知道了http://bbs.verybat.org/viewthread.php?tid=20932


2010-3-21 09:17
查看资料  发短消息  网志   编辑帖子  回复  引用回复
HAT
版主





积分 9023
发帖 5017
注册 2007-5-31
状态 离线
『第 4 楼』:  Re 2 楼 使用 LLM 解释/回答一下

你已经变成奥特曼（Out Man）了^_^




2010-3-21 11:03
查看资料  发短消息  网志   编辑帖子  回复  引用回复
Hanyeguxing
银牌会员

正在学习中的菜鸟...


积分 1039
发帖 897
注册 2009-3-1
来自 在地狱中仰望天堂
状态 离线
『第 5 楼』:   使用 LLM 解释/回答一下

啥时候把代码放出来呀？




批处理之家 http://bbs.bathome.net/forum-5-1.html
2010-3-21 16:32
查看资料  发送邮件  发短消息  网志   编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 6 楼』:   使用 LLM 解释/回答一下

游戏才刚开头,遇到一点小困难,不过会解决的!
这在编写游戏设置,玩家可以自定义游戏色调,修改背景色边框色和标题色(不过遇到点小困难,暂时只能预览不能应用)


附件 1: tsg.GIF (2010-3-23 22:51, 9.45 KiB)




SYBNQQ:354324773
2010-3-23 22:51
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 7 楼』:  既然大家喜欢代码,那就先发点 使用 LLM 解释/回答一下

目前已经写了12K代码,不过这才只是可开头而已.没啥可玩价值,喜欢的可以拿去研究!

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION&(CHCP 437 &GRAFTABL 936)>NUL

::生成sybc 变量SYBCOM保存SYBC 1.1.31的16进制数据 V保存DEBUG代码 最后通过管道交由DEBUG执行

SET SYBCOM=A100`80BE AC00 3C 375 83E9 3C00 ACFF 4275`2CBE AC00 E08A 86AC 50C4 BE1F 0 3CAC`7553 ACFB 593C F675 3CAC 7542 ACF1 433C`EC75 3CAC 7553 ACE7 3D3C E275 14EB 3CAC`743A 3C0F 740D 3C4D 7400 8349 1EE 48EB`54B4 E8AC 93 ADE8 3C00 7F18 8A37 E8F0`87 A1E8 3C00 7F4F 8A2B B0D0 F602 50E2`A0B0 E6F6 35F 57F8 3CAC 7424 E80A 6A`49E8 8A00 EBCA E817 3F CA8A 10EB B0`16CD C48A 4CB4 21CD 815F A0C7 5700 B850`B800 750 2B5A 8AEE ACD1 243C D974 3B3C`8C74 D3C DE74 3C DA74 233C 575 D783`EB01 AA01 C28A EBAA E8E0 1D 3C93 7E39`402 8009 39FB 37E C380 2409 800F FE3`10B2 E2F6 C302 D08A ACC3 203C FB74 D3C`A274 3C 9E74 D88A 3CAC 7420 3CEC 740D`3C93 7400 C38F 2C93 8030 30EB AB4 E4F6`C302 C3`

SET V=`A80`DB 00``RCX`120`n SYBC.com`w`Q

(ECHO.%SYBCOM:`=&ECHO.DW %&ECHO.%V:`=&ECHO.%)|DEBUG>nul

::初始化变量列表

::变量A-Z用于临时变量,随时使用随时初始化

::c_JM主界面背景色

set c_JM=3

::c_JM1主界面边框色

set c_JM1=F

::c_JM2主界面字符色

set c_JM2=A

::c_JM3主界面标题字符色

set c_JM3=E

::c_JM3主界面着重字符色

set c_JM4=C

::$JM0主界面边框色(反色)

set $JM0=$%c_JM1%%c_JM%

::$JM1主界面边框/主字符色

set $JM1=$%c_JM%%c_JM1%

::$JM2主界面标签字符色

set $JM2=$%c_JM%%c_JM2%

::$JM3主界面标题字符色

set $JM3=$%c_JM%%c_JM3%

::$JM3主界面着重字符色

set $JM4=$%c_JM%%c_JM4%

::c_TS提示框背景色

set c_TS=3

::c_TS1提示框边框色

set c_TS1=B

::$TS0提示框边框色(反色)

set $TS0=$%c_TS1%%c_TS%

::$TS1提示框边框色

set $TS1=$%c_TS%%c_TS1%

::默认提示框种类(0-细 1-粗)

set TSn=TS1

::RWS当前主线ID

set RWS=1

::table左侧标签位置

set table=6

::显示初始信息,代码未压缩(压缩代码可以提高执行效率,但会降低可读性)

color 3e

echo         ┃

echo         ┃

echo         ┃       太空探索者 {测试版} SYBN 2010-3-20  

echo         ┃

echo         ┃   初期开发中.还见不得人呢...

echo         ┃

echo         ┃   目前可用按键及其功能:

echo         ┃   

echo         ┃   主界面      通过Tab键切换

echo         ┃   2个新手任务 通过提示完成

echo         ┃   

echo         ┃   

echo         ┃   

echo         ┃   

echo         ┃   由于本游戏所使用的脚本默认不支持彩色输出,

echo         ┃   为了达到更好的显示效果,使用了自行汇编的3方工具SYBC.

echo         ┃   因为技术原因,SYBC无法在windows 2003以后的系统使用.

echo         ┃

echo         ┃                  如果你使用win Xp及更早的系统 请按任意键开始游戏...

echo         ╬                          否则,请等待技术困难被解决后的新版本发布...

echo ━━━╬╬╬━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━

echo         ╬        本脚本将支持记录功能,如果顺利还将支持网络功能,请大家共同期待

echo         ┃        本脚本将自带自动更新模块,建议打开自动更新功能以获得最新版本.

echo         ┃        由于俺的虚拟主机因没备案被和谐了,网络及更新要等一上阵子才行.

sybc

call :RW

call :SD

pause

exit

:RW

cls

color 31

call :JM

:RW0

call :JM0

call :JM%table%

sybc

::下一行,显示所按的键

::title sybc-%errorlevel%-

::根据不同的按键执行相应的操作

::  左右键移动光标

if %errorlevel% == 15 (

        set /a table+=1

        CALL :JM0

)

if %errorlevel% == 41 (

        title 调试代码

        set /p c=调试:

        %c%

)

if %errorlevel% == 59 (

        title 帮助信息

        call :JMH

)

if %errorlevel% == 60 (

        title 选项设置

        call :JMS

)

if %errorlevel% == 63 (

        call :JM

)



goto :RW0

:JM

::主界面,为了提高速度进行里优化,打乱了字符界面输出顺序

sybc 10276%$JM1%╲  ;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;  ▏;╱  

sybc 10200%$JM0%▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;▉;█

sybc 10000%$JM1%    ▁▁▁▁▁▁▁▁                                                            

sybc 10100%$JM1%  ╱▏公民: %$JM2%54300144%$JM1%╲▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁▁    

sybc 12400%$JM1%    %$JM0%▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇▇%$JM1%    

:JM0

if %table% gtr 7 set table=1

set /a w=table*3+99

IF %RWS% == 2 if %table% == 2 (

        set RW2=OK

        set TS=10054%$JM2%任务已完成，请返回任务栏！

        SYBC !TS!

)

IF %RWS% == 3 if %table% == 3 (

        set RW3=OK

        set TS=10054%$JM2%任务已完成，请返回任务栏！

        SYBC !TS!

)

sybc 10000%$JM1%    ▁▁▁▁▁▁▁▁                                                            

sybc 10204%$JM1%▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;▏;:%TS%

sybc 10202%$JM1%╳;%$JM2%职;业;%$JM1%╳;%$JM2%太;空;%$JM1%╳;%$JM2%探;索;%$JM1%╳;%$JM2%货;舱

sybc 11402%$JM1%╳;%$JM2%交;易;%$JM1%╳;%$JM2%任;务;%$JM1%╳;%$JM2%其;他;%$JM1%╲;

sybc %w%02%$JM1%╱  ;%$JM3%##  ;##  ;%$JM1%╲  

::call :NQ

goto :EOF

:JM1

call :FK 职业信息 %$JM1%%MYZY%

sybc 10612%$JM3%晋级条件:%$JM1%正式拥有太空站

sybc 10812%$JM3%职业技能:

if "%JN1%" GTR "0" sybc 11012%$JM3%探查技术%$JM1% LV:%JN1%  %JN1JY%/100;    可以小幅提高探查效率.

if "%JN2%" GTR "0" sybc 11312%$JM3%动力技术%$JM1% LV:%JN2%  %JN2JY%/100;    可以小幅提高动力效率.

if "%JN3%" GTR "0" sybc 11612%$JM3%提炼技术%$JM1% LV:%JN3%  %JN3JY%/100;    可以小幅提高提炼效率.

if "%JN4%" GTR "0" sybc 11912%$JM3%储存技术%$JM1% LV:%JN4%  %JN4JY%/100;    可以小幅提高储存效率.

if "%JN5%" GTR "0" sybc 11044%$JM3%搜索技术%$JM1% LV:%JN5%  %JN5JY%/100;    可以大幅提高探查效率.

goto :EOF

:JM2

call :FK 太空站 %$JM1%

call :FK1

set c_TK=0

set a=%c_TK%%c_JM1%

set DEBUGQK2=478 4EB 20 %a%;518 58B 20 %a%;5B8 62B 20 %a%;658 6CB 20 %a%;6F8 76B 20 %a%;798 80B 20 %a%;838 8AB 20 %a%;8D8 94B 20 %a%;978 9EB 20 %a%;A18 A8B 20 %a%;AB8 B2B 20 %a%;

(ECHO.fB800:%DEBUGQK2:;=&ECHO.fB800:%&ECHO.q)|DEBUG>NUL

SYBC 10824$%c_TK%%c_JM1%    $9f□□□□□□□□$%c_TK%%c_JM1%  

sybc 10924$%c_TK%%c_JM1%    $9f□□□□□□□□$%c_TK%%c_JM1%      ╭╮

SYBC 11024$%c_TK%%c_JM1%╭──╮╭┴┴╮╭──╮╭╯╰╮

SYBC 11124$%c_TK%%c_JM1%│维护├┤能源├┤ 货 ├┤探索│

SYBC 11224$%c_TK%%c_JM1%│ 舱 ├┤ 舱 ├┤ 舱 ├┤飞船│

SYBC 11324$%c_TK%%c_JM1%╰──╯╰┬┬╯╰──╯├┬┬┤

SYBC 11424$%c_TK%%c_JM1%    $9f□□□□□□□□$%c_TK%%c_JM1%  

sybc 11524$%c_TK%%c_JM1%    $9f□□□□□□□□$%c_TK%%c_JM1%  

sybc 11712$%c_TK%%c_JM3%荣誉:      太空币:         能源:         矿产:    /     

sybc 11717$%c_TK%%c_JM1%0;:11730$%c_TK%%c_JM1%1000;:11744$%c_TK%%c_JM1%1000;:11758$%c_TK%%c_JM1%0;:11763$%c_TK%%c_JM1%100

sybc 11910%$JM3%太空站信息:%$JM1%由联邦赠送的微型空间站,小而全能但升级空间有限.位于

sybc 12010%$JM1%地月平衡点,安全但收获有限.等拥有足够资源后,可以到火星基地去购

sybc 12110%$JM1%买更好的空间站.                  %$JM2%您可以用方向键查看您的空间站

goto :EOF



:JM3

call :FK 太空探索

sybc 10712%$JM3%请选择您要探索的地区:

sybc 10812%$JM2%地区           距离    往返消耗  

sybc 10912%$JM1%地月平衡点     1       1         

sybc 11012%$JM1%地月平衡点附近 2       4         

sybc 11112%$JM1%地月平衡点远处 5       25        

sybc 11212%$JM1%地月之间的太空 20      400       

sybc 11312%$JM1%月球远处       50      2500      

sybc 11412%$JM1%月球附近       80      6400      

sybc 11512%$JM1%月球轨道       99      10000     

sybc 11612%$JM1%月球表面(登月) 100     20000     

goto :EOF



:JM4

call :FK 太空货仓

sybc 10712%$JM3%-_-你还没有太空货仓！

goto :EOF



:JM5

call :FK 宇航交易

sybc 10712%$JM3%-_-你还不等进行交易！

goto :EOF



:JM6

call :FK 任务信息

call :RWS%RWS%

goto :EOF



:JM7

call :FK 其他

sybc 10712%$JM3%-_-预留空位,内容暂无！

goto :EOF



:JMH

call :FK 帮助信息

sybc 10612%$JM3%简介;%$JM1%SYBN 于 5010年3月20日 开始开发;QQ:354324773

sybc 11012%$JM3%操作简介;%$JM1%Tab 键 切换左侧标签;F1  键 查看帮助;F2  键 游戏设置;F5  键 刷新屏幕;方向键 控制

sybc 12010%$JM1%在游戏中出现的选项时%$JM2%空格%$JM1%和%$JM2%回车%$JM1%等同于Y,表示执行同意操作.

sybc 12110%$JM3%如果在出现游戏反应迟钝,那可能是按键过快所致,请稍后或重启游戏.

sybc

goto :EOF



:JMS

call :FK 游戏设置

set JMS=0123456789ABCDEF

set C_SZ0=%c_JM%

set s=0

sybc 10612%$JM3%ID设置:%$JM1% 54300144   %$JM2%(用去网络功能,相当于网络账号)

sybc 10812%$JM3%颜色设置:

for /l %%a in (0,1,15) do if "!jMs:~%%a,1!" == "%c_JM%" set C_SZ0=%%a

for /l %%a in (0,1,15) do if "!jMs:~%%a,1!" == "%c_JM1%" set C_SZ1=%%a

for /l %%a in (0,1,15) do if "!jMs:~%%a,1!" == "%c_JM3%" set C_SZ2=%%a

for /l %%a in (0,1,15) do if "!jMs:~%%a,1!" == "%c_TS1%" set C_SZ3=%%a

:JMS.1

set /a a=10920+C_SZ0*2,b=11020+C_SZ1*2,c=11120+C_SZ2*2,d=11220+C_SZ3*2,r=10910+s*100

sybc 10910%$JM1%背景色:   0 1 2 3 4 5 6 7 8 9 A B C D E F;边框色:   0 1 2 3 4 5 6 7 8 9 A B C D E F

sybc 11110%$JM1%标题色:   0 1 2 3 4 5 6 7 8 9 A B C D E F;提示框:   0 1 2 3 4 5 6 7 8 9 A B C D E F

SYBC %a%%$JM3%#;:%b%%$JM3%#;:%c%%$JM3%#;:%d%%$JM3%#;:%r%%$JM3%#######=}

SYBC 10754$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!╔━━━━━━━╗

SYBC 10854$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃$!JMS:~%C_SZ3%,1!!JMS:~%C_SZ1%,1! $!JMS:~%C_SZ3%,1!!JMS:~%C_SZ0%,1!▄▄▄▄▄▄$!JMS:~%C_SZ3%,1!!JMS:~%C_SZ1%,1! $!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃

SYBC 10954$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃$!JMS:~%C_SZ3%,1!!JMS:~%C_SZ1%,1! $!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1! -颜$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ2%,1!色$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!示例- $!JMS:~%C_SZ3%,1!!JMS:~%C_SZ1%,1! $!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃

SYBC 11054$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃$!JMS:~%C_SZ3%,1!!JMS:~%C_SZ1%,1! $!JMS:~%C_SZ0%,1!!JMS:~%C_SZ3%,1!▄▄▄▄▄▄$!JMS:~%C_SZ3%,1!!JMS:~%C_SZ1%,1! $!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃

SYBC 11154$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃ $!JMS:~%C_SZ0%,1!CQQ:$!JMS:~%C_SZ0%,1!A345324773 $!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!┃

SYBC 11254$!JMS:~%C_SZ0%,1!!JMS:~%C_SZ1%,1!╚━━━━━━━╝

SYBC 12130%$JM3%用方向键更改您的设施,空格键确认,ESC键退出

SYBC

title %errorlevel%

if %errorlevel% == 75 set /a C_SZ%s%-=1

if %errorlevel% == 77 set /a C_SZ%s%+=1

if %errorlevel% == 72 set /a s-=1

if %errorlevel% == 80 set /a s+=1

if %errorlevel% == 1 goto :EOF

if %errorlevel% == 57 (

        set c_JM=!JMS:~%C_SZ0%,1!

        set c_JM1=!JMS:~%C_SZ1%,1!

        set c_JM3=!JMS:~%C_SZ2%,1!

        set c_TS=!JMS:~%C_SZ0%,1!

        set c_TS1=!JMS:~%C_SZ3%,1!

        set $JM0=$!c_JM1!!c_JM!

        set $JM1=$!c_JM!!c_JM1!

        set $JM2=$!c_JM!!c_JM2!

        set $JM3=$!c_JM!!c_JM3!

        set $JM4=$!c_JM!!c_JM4!

        set $TS0=$!c_TS1!!c_TS!

        set $TS1=$!c_TS!!c_TS1!

        call :JM

        goto :EOF

)

if !C_SZ%s%! lss 0 set C_SZ%s%=15

if !C_SZ%s%! gtr 15 set C_SZ%s%=0

if %s% lss 0 set s=15

if %s% gtr 3 set s=0

goto :JMS.1



:YS

SYBC 10050$                             

:NQ

::保存刷新块坐标 游戏界面中间部分,每次需要局部刷新,变量DEBUGQK保存要刷新的内存地址起止点

set DEBUGQK=14C 1D7 20 %c_JM%%c_JM1%;1EC 277 20 %c_JM%%c_JM1%;28C 317 20 %c_JM%%c_JM1%;32C 3B7 20 %c_JM%%c_JM1%;3CC 457 20 %c_JM%%c_JM1%;46C 4F7 20 %c_JM%%c_JM1%;50C 597 20 %c_JM%%c_JM1%;5AC 637 20 %c_JM%%c_JM1%;64C 6D7 20 %c_JM%%c_JM1%;6EC 777 20 %c_JM%%c_JM1%;78C 817 20 %c_JM%%c_JM1%;82C 8B7 20 %c_JM%%c_JM1%;8CC 957 20 %c_JM%%c_JM1%;96C 9F7 20 %c_JM%%c_JM1%;A0C A97 20 %c_JM%%c_JM1%;AAC B37 20 %c_JM%%c_JM1%;B4C BD7 20 %c_JM%%c_JM1%;BEC C77 20 %c_JM%%c_JM1%;C8C D17 20 %c_JM%%c_JM1%;D2C DB7 20 %c_JM%%c_JM1%;DCC E57 20 %c_JM%%c_JM1%;;E6C EF7 20 %c_JM%%c_JM1%;

(ECHO.fB800:%DEBUGQK:;=&ECHO.fB800:%&ECHO.q)|DEBUG>NUL

goto :EOF

:FK

::显示提示框

call :NQ

sybc 10308%$JM1%╔━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━╗

sybc 10408%$JM1%┃;╟;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃

sybc 10472%$JM1%┃;╢;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃

sybc 10508%$JM1%╟───────────────────────────────╢

sybc 12208%$JM1%╚━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━╝

sybc 10412%$JM3%%1 %2 

goto :EOF

:FK1

::显示小提示框

sybc 10610%$JM1%╔━━━━━━━━━━━━━━━━━━━━━━━━━━━━━╗

sybc 10710%$JM1%┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃

sybc 10770%$JM1%┃;┃;┃;┃;┃;┃;┃;┃;┃;┃;┃

sybc 11810%$JM1%╚━━━━━━━━━━━━━━━━━━━━━━━━━━━━━╝

goto :EOF

:TS0

::显示小提示框

sybc 11122%$JM1%╔━━━━━━━━━━━━━━━━╗;%$JM1%┃                                ┃

sybc 11322%$JM1%┃                                ┃;%$JM1%┃                                ┃

sybc 11522%$JM1%╚━━━━━━━━━━━━━━━━╝

sybc 11224%$JM3%%1;%$JM1%%2;%$JM2%%3

goto :EOF

:TS1

::显示小提示框

sybc 11122%$TS0% ▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄ ;%$TS0% %$TS1%                                  %$TS0% 

sybc 11322%$TS0% %$TS1%                                  %$TS0% ;%$TS0% %$TS1%                                  %$TS0% 

sybc 11522%$TS0% %$TS1%▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄%$TS0% 

sybc 11224%$JM3%%1;%$JM1%%2;%$JM2%%3

goto :EOF

:choice

sybc

if %errorlevel% == 21 exit /B 21

if %errorlevel% == 57 exit /B 21

if %errorlevel% == 28 exit /B 21

if %errorlevel% == 49 exit /B 49

exit /B %errorlevel%

:RWS1

::主线任务1

SYBC 10610%$JM3%中华联邦招募您参与外太空探索实习

SYBC 10810%$JM1%    由于联邦内大学生就业形势严峻,以及联邦外太空探索任务人手不

SYBC 10910%$JM1%足现招募您到中华联邦外太空探索中心参与外太空探索实习．

SYBC 11110%$JM3%工作内容

SYBC 11310%$JM1%    探索并开采外太空资源,发展外太空空间站．

SYBC 11510%$JM3%工作奖励

SYBC 11710%$JM1%    您将拥有一个单舱太空空间站,当您开采足够资源后,您需要上交

SYBC 11810%$JM1%50％的太空所得税,其余所得将属于您私人所有．如果您积攒足够的资;源,您还可以购买和升级更好的太空站.

SYBC 12150%$JM3%是否接受这项任务 %$JM1%

:RWS1.1

call :choice

if %errorlevel% == 49 (

        call :%TSn% $CF╳%$JM3%操作被拒绝 您无权拒绝国家，您必须同意.

        goto :RWS1.1

)

if %errorlevel% == 21 (

        call :%TSn% $AF√%$JM3%操作成功 恭喜您，成为太空探索实习者！

        set MYzy=太空探索者

        set /a JN1=1,JN1JY=0,JN2=1,JN2JY=0,JN3=1,JN3JY=0,JN4=1,JN4JY=0

        SYBC

        set RWS=2

        goto :RWS2

)

call :%TSn% $CF╳%$JM3%操作被拒绝 请立刻做出您的决定，这很重要！

goto :RWS1.1

:RWS2

::主线任务2

call :NQ

call :FK 主线任务

SYBC 10610%$JM3%太空探索实习指南-1

SYBC 10810%$JM1%    您可以在任意时候按%$JM3%Tab键%$JM1%切换左侧标签栏

SYBC 11010%$JM1%    您现在需要到太空栏查看您得到的太空站

SYBC 11210%$JM1%    在那里，您可以开始您的外太空地之旅

SYBC 11410%$JM3%    现在，请按Tab键直到切换到太空栏

if "!RW%RWS%!" == "OK" (

        SYBC 12158%$JM2%任务已完成！  

        call :%TSn% $AF√%$JM3%任务完成 恭喜您，首次完成了任务！ 奖励:%$JM3%太空币1000

        SYBC

        set /a RWS+=1

        goto :RWS!RWS!

)

SYBC 12158%$JM2%任务进行中...

set TS=10054%$JM3% 请按Tab键直到切换到太空栏

SYBC %TS%

goto :EOF

:RWS3

::主线任务3

call :NQ

call :FK 主线任务

SYBC 10610%$JM3%太空探索实习指南-2

SYBC 10810%$JM1%    现在您可以用您的太空探索器到周围转转,也许会有收获！

SYBC 11010%$JM1%    您现在需要到探索栏开始您的探索

SYBC 11210%$JM1%    注意,距离您的太空站越近的区域越安全,但收获也越少！

SYBC 11410%$JM3%    现在，请按Tab键切换到探索栏

if "!RW%RWS%!" == "OK" (

        SYBC 12158%$JM2%任务已完成！  

        call :%TSn% $AF√%$JM3%任务完成 恭喜您，再次完成了任务！ 奖励:%$JM3%太空币1000

        SYBC

        set /a RWS+=1

        goto :RWS!RWS!

)

SYBC 12158%$JM3%任务进行中...

set TS=10054%$JM3% 请按Tab键直到切换到探索栏

SYBC %TS%

goto :EOF

:RWS4

::主线任务4

call :NQ

call :FK 主线任务

SYBC 10610%$JM3%太空探索实习指南-3

SYBC 10810%$JM1%    编写中...

if "!RW%RWS%!" == "OK" (

        SYBC 12158%$JM2%任务已完成！  

        call :%TSn% $AF√%$JM3%任务完成 恭喜您，完成了任务！ 奖励:%$JM3%太空币1000

        SYBC

        set /a RWS+=1

        goto :RWS!RWS!

)

SYBC 12158%$JM3%任务进行中...

set TS=10054%$JM3% 暂无任务,请等待新版本完善

SYBC %TS%

goto :EOF


Last edited by sl543001 on 2010-4-5 at 20:43 ]




SYBNQQ:354324773
2010-3-23 22:56
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 8 楼』:   使用 LLM 解释/回答一下

F1 -帮助
F2 -设置




SYBNQQ:354324773
2010-3-23 22:57
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 9 楼』:   使用 LLM 解释/回答一下

大体搞定了颜色设置(7楼代码已更新)
按F2进入设置界面,方向键修改颜色(右侧有预览),空格键应用

Last edited by sl543001 on 2010-3-24 at 22:18 ]


附件 1: tsg.GIF (2010-3-24 22:17, 12.29 KiB,下载次数： 1)




SYBNQQ:354324773
2010-3-24 22:13
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
doslike
版主

系统收藏家


积分 326
发帖 285
注册 2010-2-22
来自 黑龙江省
状态 离线
『第 10 楼』:   使用 LLM 解释/回答一下

玩不了


2010-4-2 19:29
查看资料  发送邮件  发短消息  网志   编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 11 楼』:   使用 LLM 解释/回答一下

是打不开还是咋的?
(注意:本游戏不支持2003以后系统)




SYBNQQ:354324773
2010-4-2 20:55
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
ZJHJ
高级用户





积分 609
发帖 374
注册 2006-8-2
状态 离线
『第 12 楼』:   使用 LLM 解释/回答一下

XP 也是 系统无法执行指定程序


2010-4-2 23:05
查看资料  发短消息  网志   编辑帖子  回复  引用回复
Hanyeguxing
银牌会员

正在学习中的菜鸟...


积分 1039
发帖 897
注册 2009-3-1
来自 在地狱中仰望天堂
状态 离线
『第 13 楼』:   使用 LLM 解释/回答一下

系统xp sp3，测试运行正常
就是玩不明白。。。
关闭程序时出现无响应。




批处理之家 http://bbs.bathome.net/forum-5-1.html
2010-4-3 01:15
查看资料  发送邮件  发短消息  网志   编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 14 楼』:   使用 LLM 解释/回答一下

玩不明白是必然的,只做了游戏界面还啥也没有呢!
关闭程序时出现无响应,这是windows的BUG,与我无关,等一会就好了




SYBNQQ:354324773
2010-4-3 03:14
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复
sl543001
中级用户




积分 499
发帖 225
注册 2008-12-30
状态 离线
『第 15 楼』:   使用 LLM 解释/回答一下

生成SYBC.COM文件了没?
=====================
不过不要紧,SYBC1.1.31开始就不用生成SYBC.COM文件了




SYBNQQ:354324773
2010-4-3 03:16
查看资料  发送邮件  发短消息  网志  OICQ (354324773)  编辑帖子  回复  引用回复

请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。


可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题



论坛跳转:  



[ 联系联盟系统管理团队 - 中国DOS联盟 ]

Sponsored by ifanr Inc | © 2001-2023